src/io/netcdf/IcGrid_ncWriter_mod.f90

Go to the documentation of this file.

module IcGrid_ncWriter_mod

  ! モジュール引用 ; Use statements
  !

  ! 種類型パラメタ
  ! Kind type parameter
  !
  use dc_types, only: DP, &        ! 倍精度実数型. Double precision.
    &                 TOKEN


  ! 正二十面体格子データの管理
  ! Manager of icosahedral grid data
  !
  use IcGrid2D_FVM_Manager, only: &
    & IcGrid2D_FVM, &
    & paste_margin_width, &
    & get_EffSize_Min, get_EffSize_Max, get_IcRadius, get_glevel, &
    & RC_REGIONS_NUM


  ! 正二十面体格子上の物理場データの管理
  ! Manager of the physical field data on icosahedral grid
  !
  use Field_IcGrid2D_Manager, only: &
    & Field_IcGrid2D, &
    & get_field2D_name, get_long_field2D_name, get_field2D_units, get_Physical_Field


  ! 非構造格子データモデルの構造型の提供
  ! Providing the derived types for unstructured grid data model
  !
  use IcGrid_ncStream_helper, only: &
    & Mesh2_ncInfo, Mesh2_ncInfo_Init, &
    & Mesh_dim_element, &
    & Mesh_coord_element, &
    & check_nf90_status

  ! NetCDF
  !
  !
  use netcdf

  ! 宣言文 ; Declaration statements
  !
  implicit none
  private

  type, public :: IcGrid_ncWriter
    ! 公開メンバ変数
    ! Public member varables

    integer :: ncID

    type(Mesh2_ncInfo) :: mesh2Info

    type(IcGrid2D_FVM), pointer :: icgrid

    integer :: rec_dimid

    integer :: rec_counter

  end type IcGrid_ncWriter

  ! 公開手続き
  ! Public procedures
  !
  public :: IcGrid_ncWriter_Init
  public :: open_ncFile, close_ncFile
  public :: end_ncdef, ncdef_GridData, ncdef_FieldData, ncdef_Simulation_Parameter, &
    &        write_GridData, write_FieldData, increase_recorde_counter

  ! interface 文; interface statements
  !
  !
  interface IcGrid_ncWriter_Init
    module procedure IcGrid2D_ncWriter_Init
  end interface IcGrid_ncWriter_Init

  interface ncdef_FieldData
    module procedure ncdef_Field2D_Data
  end interface ncdef_FieldData

  interface write_FieldData
    module procedure write_Field2D_Data
  end interface write_FieldData

  ! 非公開変数
  ! Private variables
  !

  character(TOKEN), parameter :: RECODE_NAME = 'time'

contains

!
subroutine IcGrid2D_ncWriter_Init(self, ref_icgrid)

  ! 宣言文 ; Declaration statements
  !

  type(IcGrid_ncWriter), intent(inout) :: self
  type(IcGrid2D_FVM), intent(in), target :: ref_icgrid

  ! 作業変数
  ! Work variables
  !

  ! 実行文 ; Executable statements
  !

  self%icgrid => ref_icgrid

  !
  self%rec_counter = 1

  ! 正二十面体格子のメッシュ情報を保持する Mesh2_ncInfo クラスのインスタンスを初期化
  call Mesh2_ncInfo_Init(self%mesh2Info, self%icgrid)


end subroutine IcGrid2D_ncWriter_Init

!
subroutine open_ncFile(self, file_name)

  ! 宣言文 ; Declaration statement
  !
  type(IcGrid_ncWriter), intent(inout) :: self
  character(*), intent(in) :: file_name

  ! 実行文 ; Execuatble statement
  !

  ! netCDF ファイルの作成
  call check_nf90_status( &
    & nf90_create(file_name, NF90_CLOBBER, self%ncID) )

end subroutine open_ncFile

!
subroutine ncdef_GridData(self)

  ! 宣言文 ; Declaration statement
  !
  type(IcGrid_ncWriter), intent(inout) :: self

  ! 実行文 ; Executable statement
  !

  ! NetCDF ファイルに次元要素 node を定義する.
  call ncdef_dimension(self, self%Mesh2Info%node )

  ! NetCDF ファイルに座標要素 : node_x, node_y を定義する.
  call ncdef_mesh_coordinate(self, self%mesh2Info%node_x )
  call ncdef_mesh_coordinate(self, self%mesh2Info%node_y )

  ! NetCDF ファイルに時間座標を定義する.
  call check_nf90_status( &
    & nf90_def_dim(self%ncID, RECODE_NAME, NF90_UNLIMITED, self%rec_dimid), &
    message='define dimension.'  &
    & )

  ! 正二十面格子の水平解像度を NetCDF のグローバル領域に書きこむ.
  call check_nf90_status( nf90_put_att( self%ncID, NF90_GLOBAL, 'glevel', get_glevel(self%icgrid)) )

end subroutine ncdef_GridData

!
function ncdef_Field2D_Data(self, field_Rank1) result(varid)

  ! 宣言文 ; Declaration statements
  !
  type(IcGrid_ncWriter), intent(in) :: self
  type(Field_IcGrid2D), intent(in) :: field_Rank1
  integer varid

  ! 作業変数
  ! Work variables
  !
  integer :: dimids(2)

  ! 実行文 ; Executable statement
  !

  !
  dimids = (/ self%Mesh2Info%node%dimid, self%rec_dimid /)

  ! NetCDF ファイルに, 後に物理場のデータを書き込むことになる物理場の情報を定義する.
  call check_nf90_status( &
    & nf90_def_var(self%ncID, get_field2D_name(field_Rank1), NF90_DOUBLE, dimids, varid), &
    message='Define the field `' // trim(get_field2D_name(field_Rank1)) // '`.' &
    & )

  ! 物理場の long_name を設定.
  call check_nf90_status( &
    & nf90_put_att( self%ncID, varid, 'long_name', get_long_field2D_name(field_Rank1) ) &
    & )

  ! 物理場の単位の設定.
  call check_nf90_status( &
    & nf90_put_att( self%ncID, varid, 'units', get_field2D_units(field_Rank1) ) &
    & )

end function ncdef_Field2D_Data

!
subroutine ncdef_Simulation_Parameter( &
   & self,                             &
   & integration_time, time_step, output_tick &
   )
  ! 宣言文 ; Declaration statements
  !
  type(IcGrid_ncWriter), intent(in) :: self
  real(DP), intent(in) :: integration_time
  real(DP), intent(in) :: time_step
  real(DP), intent(in) :: output_tick

  ! 実行文 ; Executable statement
  !

  ! 積分時間, 時間ステップ, 出力間隔の情報を NetCDF のグローバル領域に書きこむ.
  call check_nf90_status( nf90_put_att( self%ncID, NF90_GLOBAL, 'integration_time', integration_time) )
  call check_nf90_status( nf90_put_att( self%ncID, NF90_GLOBAL, 'time_step', time_step) )
  call check_nf90_status( nf90_put_att( self%ncID, NF90_GLOBAL, 'output_tick', output_tick) )

end subroutine ncdef_Simulation_Parameter

!
subroutine end_ncdef(self)

  ! 宣言文 ; Declaration statements
  !
  type(IcGrid_ncWriter), intent(in) :: self

  ! 実行文 ; Executable statement
  !

  call check_nf90_status( nf90_enddef( self%ncID ) )

end subroutine end_ncdef

!
subroutine write_GridData(self)

  use igmcore_coordinate_conversion, only: orth_to_geo_pos

  ! 宣言文 ; Declaration statements
  !
  type(IcGrid_ncWriter), intent(in) :: self

  ! 作業変数
  ! Work variables
  !
  integer rcID, i, j
  integer EMin, EMax
  real(DP), allocatable :: s_rcs_node_x(:), s_rcs_node_y(:)
  real(DP), allocatable :: s_rcs_AGrid(:,:,:,:)

  ! 実行文 ; Executable statements
  !

  EMin = get_EffSize_Min(self%icgrid)
  EMax = get_EffSize_Max(self%icgrid)

  ! 作業変数のメモリを確保する.
  allocate( s_rcs_AGrid(RC_REGIONS_NUM, EMin:EMax, EMin:EMax, 3) )
  allocate( s_rcs_node_x(self%Mesh2Info%node%num) )
  allocate( s_rcs_node_y(self%Mesh2Info%node%num) )

  ! 直交座標系で表現されている格子座標データを, 地理座標系での座標データに変換する.
  !

  do rcID=1,RC_REGIONS_NUM
    do j=EMin, EMax
      do i=EMin, EMax
        s_rcs_AGrid(rcID,i,j,:) = orth_to_geo_pos(self%icgrid%rcs_AGrid(rcID,i,j,:))
      end do
    end do
  end do

  ! 3 次元配列を 1 次元化する.
  !

  ! 各格子の経度の情報を一次元配列に格納する.
  s_rcs_node_x(:) = reshape( s_rcs_AGrid(:,:,:,1), shape(s_rcs_node_x) )
  ! 各格子の緯度の情報を一次元配列に格納する.
  s_rcs_node_y(:) = reshape( s_rcs_AGrid(:,:,:,2), shape(s_rcs_node_y) )

  ! 格子座標データの緯度・経度成分を, それぞれ Mesh2_node_x, Mesh2_node_y として,
  ! netCDF ファイルに書き込む.
  !

  call check_nf90_status( &
    & nf90_put_var( self%ncID, self%Mesh2Info%node_x%varID, s_rcs_node_x ) &
    & )
  call check_nf90_status( &
    & nf90_put_var( self%ncID, self%Mesh2Info%node_y%varID, s_rcs_node_y ) &
    & )

end subroutine write_GridData

!
subroutine write_Field2D_Data(self, varid, field_Rank1)

  ! 宣言文 ; Declaration statements
  !
  type(IcGrid_ncWriter), intent(in) :: self
  integer, intent(in) :: varid
  type(Field_IcGrid2D), intent(in) :: field_Rank1

  ! 作業変数
  ! Work variables
  !
  integer :: EMin, EMax
  real(DP), allocatable :: writed_field(:)
  integer :: start(2), count(2)

  ! 実行文 ; Executable statement
  !

  !
  EMin = get_EffSize_Min(self%icgrid)
  EMax = get_EffSize_Max(self%icgrid)

  !
  allocate(writed_field(self%Mesh2Info%node%num))
  writed_field(:) = reshape( field_Rank1%val(:,EMin:EMax,EMin:EMax,1), shape(writed_field) )

  !
  count = (/ self%Mesh2Info%node%num, 1 /)
  start = (/ 1, self%rec_counter /)

  !
  call check_nf90_status( &
    & nf90_put_var( self%ncID, varID, writed_field, start=start, count=count ) &
    & )


end subroutine write_Field2D_Data

!
subroutine increase_recorde_counter(self)

  ! 宣言文 ; Declaration statements
  !
  type(IcGrid_ncWriter), intent(inout) :: self

  ! 実行文 ; Executable statement
  !

  self%rec_counter = self%rec_counter + 1

end subroutine increase_recorde_counter

!
subroutine close_ncFile(self)

  ! 宣言文 ; Declaration statements
  !
  type(IcGrid_ncWriter), intent(in) :: self

  ! 実行文 ; Executable statement
  !

  ! netCDF ファイルを閉じる.
  call check_nf90_status( nf90_close(self%ncID) )

end subroutine close_ncFile

!!!!!!!!!!!!!!!!!!!!
!
! 非公開手続き
!
!!!!!!!!!!!!!!!!!!!

!
subroutine ncdef_dimension(self, dim_element)

  ! 宣言文 ; Declaration statements
  !
  type(IcGrid_ncWriter), intent(in) :: self
  type(Mesh_dim_element), intent(inout) :: dim_element

  ! 実行文 ; Executable statments
  !

  call check_nf90_status( &
    & nf90_def_dim(self%ncID, dim_element%element_name, dim_element%num, dim_element%dimID), &
    message='define dimension. ' // trim(dim_element%element_name) &
    & )

end subroutine ncdef_dimension

!
subroutine ncdef_mesh_coordinate(self, coordinate_element)

  ! 宣言文 ; Declaration statements
  !
  type(IcGrid_ncWriter), intent(in) :: self
  type(Mesh_coord_element), intent(inout) :: coordinate_element

  ! 作業変数
  ! Work variables
  !
  integer :: ret_status

  ! 実行文 ; Executable statements
  !

  !
  ret_status = &
    & nf90_def_var( &
       & self%ncID, &
       & coordinate_element%element_name, NF90_DOUBLE, &
       & coordinate_element%dimension_element%dimID, coordinate_element%varID &
       & )

  call check_nf90_status(ret_status)

end subroutine ncdef_mesh_coordinate

end module IcGrid_ncWriter_mod