src/core/math/igmcore_linear_algebra.f90

Go to the documentation of this file.

module igmcore_linear_algebra
  
  ! モジュール引用 ; Use statements
  !

  ! 種類型パラメタ
  ! Kind type parameter
  !
  use dc_types, only: DP  ! 倍精度実数型. Double precision
  
  ! 宣言文 ; Declaration statements
  !
  implicit none
  private

  ! 公開手続き
  ! Public procedure
  !
  public :: vec_length, vec_normarize
  public :: dot, cross
  public :: rotateX, rotateY, rotateZ

contains

  !
  function rotateX(     &
    & vec, angle        & ! (in) 
    & ) result(rel_vec)

    ! 宣言文 ; Declaration statements
    !
    real(DP), intent(in) :: vec(3)   ! 回転行列を作用させるベクトル(A_x, A_y, A_z)
    real(DP), intent(in) :: angle    ! 回転させる角度
    real(DP) rel_vec(3)              ! 回転行列を作用させた後のベクトル

    ! 実行文 ; Executable statements
    !
    
    ! 3次元ベクトル vec を X 軸回りに角度 angle だけ回転させ,
    ! その結果を rel_vec に格納する.
    rel_vec(1) = vec(1)
    rel_vec(2) = cos(angle) * vec(2) - sin(angle) * vec(3)
    rel_vec(3) = sin(angle) * vec(2) + cos(angle) * vec(3)
  end function rotateX

  !
  function rotateY(      &
    & vec, angle         & ! (in)
    & ) result(rel_vec)

    ! 宣言文 ; Declaration statements
    !
    real(DP), intent(in) :: vec(3)      ! 回転行列を作用させるベクトル\f$(A_x, A_y, A_z)\f$.
    real(DP), intent(in) :: angle       ! 回転させる角度
    real(DP) rel_vec(3)                 ! 回転行列を作用させた後のベクトル

    ! 実行文 ; Executable statements
    !
    
    ! 3次元ベクトル vec を Y 軸回りに角度 angle だけ回転させ,
    ! その結果を rel_vec に格納する.
    rel_vec(1) = cos(angle) * vec(1) + sin(angle) * vec(3)
    rel_vec(2) = vec(2)
    rel_vec(3) = - sin(angle) * vec(1) + cos(angle) * vec(3)

  end function rotateY

  !
  function rotateZ( &
    & vec, angle    & ! (in) 
    & ) result(rel_vec)

    ! 宣言文 ; Declaration statements 
    !

    real(DP), intent(in) :: vec(3)      ! 回転行列を作用させるベクトル\f$(A_x, A_y, A_z)\f$
    real(DP), intent(in) :: angle       ! 回転させる角度
    real(DP) rel_vec(3)                 ! 回転行列を作用させた後のベクトル

    ! 実行文 ; Executable statements 
    !

    ! 3次元ベクトル vec をZ 軸回りに角度 angle だけ回転させ,
    ! その結果を rel_vec に格納する.
    rel_vec(1) = cos(angle) * vec(1) - sin(angle) * vec(2)
    rel_vec(2) = sin(angle) * vec(1) + cos(angle) * vec(2)
    rel_vec(3) = vec(3)

  end function rotateZ

  !
  function vec_length( &
    & vec              &   ! (in)
    & ) result(length)

    ! 宣言文 ; Declaration statements
    !

    real(DP), intent(in) :: vec(3)  ! 長さを取得したいベクトル
    real(DP) length                 ! ベクトルの長さ

    ! 実行文 ; Executable statements
    !

    length = sqrt(vec(1)**2 + vec(2)**2 + vec(3)**2)

  end function vec_length

  !
  subroutine vec_normarize( &
    & vec                   &   ! (inout)
    & )

    ! 宣言文 ; Declaration statements
    !
    real(DP), intent(inout) :: vec(3)    ! 規格化したいベクトル

    ! 実行文 ; Executable statements
    !

    vec(1:3) = vec(1:3) / vec_length(vec)

  end subroutine

  !
  function cross( &
    & v1, v2    &     ! (in)
    & ) result(v)

    ! 宣言文 ; Declaration statements
    !
    real(DP), intent(in) :: v1(3)   ! ベクトル\f$\Dvect{v}_1\f$. 
    real(DP), intent(in) :: v2(3)   ! ベクトル\f$\Dvect{v}_2\f$. 
    real(DP) v(3)                   ! \f$\Dvect{v}_1 \times \Dvect{v}_2\f$の計算結果を格納したベクトル

    ! 実行文 ; Executable statements
    !

    v(1) = v1(2)*v2(3) - v1(3)*v2(2)
    v(2) = v1(3)*v2(1) - v1(1)*v2(3)
    v(3) = v1(1)*v2(2) - v1(2)*v2(1)
  end function cross

  !
  function dot( &
    & v1, v2    &    ! (in)
    &) result(val)


    ! 宣言文 ; Declaration statements
    !
    real(DP), intent(in) :: v1(3)  ! ベクトル\f$\Dvect{v}_1\f$
    real(DP), intent(in) :: v2(3)  ! ベクトル\f$\Dvect{v}_2\f$
    real(DP) val                   ! \f$\Dvect{v}_1 \cdot \Dvect{v}_2\f$の計算結果

    ! 実行文 ; Executable statements
    !

    val = v1(1)*v2(1) + v1(2)*v2(2) + v1(3)*v2(3)

  end function dot

end module igmcore_linear_algebra