src/io/netcdf/IcGrid_ncStream_helper.f90

Go to the documentation of this file.

module IcGrid_ncStream_helper
  
  ! モジュール引用 ; Use statements
  !

  ! 種類型パラメタ 
  ! Kind type parameter
  !
  use dc_types, only: DP, &        ! 倍精度実数型. Double precision.
    &                 TOKEN, &
    &                 STRING

  ! メッセージ出力
  ! Message dump
  !
  use dc_message, only: &
    & MessageNotify

  ! NetCDF
  !
  !
  use netcdf
  
  ! 宣言文 ; Declaration statements
  !
  implicit none
  private

  ! 公開変数
  ! Public variables
  !

  !
  type, public :: Mesh_dim_element

    character(TOKEN) :: element_name

    integer :: num

    integer :: dimID

  end type Mesh_dim_element

  !
  type, public :: Mesh_coord_element

    type(Mesh_dim_element), pointer :: dimension_element

    character(TOKEN) :: element_name

    character(TOKEN) :: standard_name

    character(STRING) :: long_name

    character(STRING) :: units

    integer :: varID

  end type Mesh_coord_element
  
  type, public :: Mesh2_ncInfo

    type(Mesh_dim_element) :: node

    type(Mesh_dim_element) :: face

    type(Mesh_dim_element) :: edge

    type(Mesh_dim_element) :: face_links
    
    type(Mesh_coord_element) :: node_x

    type(Mesh_coord_element) :: node_y

    type(Mesh_coord_element) :: face_x, face_y

    type(Mesh_coord_element) :: edge_x, edge_y
    
  end type Mesh2_ncInfo

  ! 公開手続き
  ! Public procedure
  !
  public :: Mesh_coord_element_Init, Mesh2_ncInfo_Init, check_nf90_status

contains

!
subroutine Mesh_coord_element_Init( &
  & self,                             &  ! (inout)
  & dimension_element,                &  ! (inout)
  & element_name, standard_name, long_name, units &  ! (in)
  & )

  ! 宣言文 ; Declaration statement
  !
  type(Mesh_coord_element), intent(inout) :: self
  type(Mesh_dim_element), intent(inout), target :: dimension_element
  character(*), intent(in) :: element_name
  character(*), intent(in) :: standard_name
  character(*), intent(in) :: long_name
  character(*), intent(in) :: units

  ! 実行文 ; Execuatble statement
  !
  self%dimension_element => dimension_element
  self%element_name = element_name
  self%standard_name = standard_name
  self%long_name = long_name
  self%units = units

end subroutine Mesh_coord_element_Init

!
subroutine Mesh2_ncInfo_Init( &
  & self, icgrid2D &  ! (inout)
  & )
  
  ! モジュール引用 ; Use statements
  !
  
  ! 正二十面格子データの管理
  ! Manager of icosahedral grid data
  !
  use IcGrid2D_FVM_Manager, only: &
    & IcGrid2D_FVM, &
    & get_EffSize_Min, get_EffSize_Max, &
    & RC_REGIONS_NUM

  ! 宣言文 ; Declaration statements
  !
  type(Mesh2_ncInfo), intent(inout) :: self
  type(IcGrid2D_FVM), intent(inout) :: icgrid2D

  ! 作業変数
  ! Work variables
  !
  integer :: EMin, Emax
  character(TOKEN), parameter :: LAT = "latitude"
  character(TOKEN), parameter :: LON = "longitude"
  character(TOKEN), parameter :: LAT_UNITS = "degrees_north"
  character(TOKEN), parameter :: LON_UNITS = "degrees_east"

  ! 実行文 ; Executable statement
  !

  !
  EMin = get_EffSize_Min(icgrid2D)
  EMax = get_EffSize_Max(icgrid2D)

  !
  self%node%element_name = 'nMesh2_node'
  ! dimension: Mesh2_node 個数の設定
  self%node%num = RC_REGIONS_NUM * ( EMax - EMin + 1)**2

  ! Mesh2_node_x の初期化
  call Mesh_coord_element_Init( &
    & self%node_x, dimension_element=self%node, &
    & element_name='Mesh2_node_x', standard_name=LON, &
    & long_name='Latiude of 2D mesh node', units=LON_UNITS &
    & )

  ! Mesh2_node_y の初期化
  call  Mesh_coord_element_Init( &
    & self%node_y, dimension_element=self%node, &
    & element_name='Mesh2_node_y', standard_name=LAT, &
    & long_name='Latiude of 2D mesh node', units=LAT_UNITS &
    & )

end subroutine Mesh2_ncInfo_Init

!
subroutine check_nf90_status( &
  & status, message &  ! (in)
  & )
  
  ! 宣言文 ; Declaration statement
  !
  integer, intent(in) :: status 
  character(*), intent(in), optional :: message

  ! 作業変数
  ! Work varibles
  !
  
  character(STRING) :: output_str
  character(STRING) :: netCDF_error 
 
  ! 実行文 ; Execuatble statements
  !

  if ( status /= nf90_noerr ) then
    ! ステータスを解析し, エラーの原因を取得する. 
    netCDF_error = '(netCDF error status:' // trim(nf90_strerror(status)) // ')'
 
    if ( present(message) ) then
      output_str = trim(message) // netCDF_error
    else
      output_str = netCDF_error
    end if

    ! エラー出力を行い, プログラムを停止する. 
!    write(*,*) trim(output_str)
    call MessageNotify( 'E', 'IGMBaseLib IO:IcGrid_ncStream_helper:', trim(output_str) ) 
    stop

  end if

end subroutine check_nf90_status

end module IcGrid_ncStream_helper