src/io/netcdf/IcGrid_ncReader_mod.f90

Go to the documentation of this file.

module IcGrid_ncReader_mod

  ! モジュール引用 ; Use statements
  !

  ! 種類型パラメタ
  ! Kind type parameter
  !
  use dc_types, only: DP, &        ! 倍精度実数型. Double precision.
    &                 TOKEN, &
    &                 STRING

  ! メッセージ出力
  ! Message dump
  !
  use dc_message, only: &
    & MessageNotify

  ! 正二十面体格子データの管理
  ! Manager of icosahedral grid data
  !
  use IcGrid2D_FVM_Manager, only: &
    & IcGrid2D_FVM, &
    & paste_margin_width, &
    & get_EffSize_Min, get_EffSize_Max, get_IcRadius, &
    & RC_REGIONS_NUM


  ! 正二十面体格子上の物理場データの管理
  ! Manager of the physical field data on icosahedral grid
  !
  use Field_IcGrid2D_Manager, only: &
    & Field_IcGrid2D, paste_field_margin, &
    & set_long_field2D_name, set_field2D_units


  ! 非構造格子データモデルの構造型の提供
  ! Providing the derived types for unstructured grid data model
  !
  use IcGrid_ncStream_helper, only: &
    & Mesh2_ncInfo, Mesh2_ncInfo_Init, &
    & Mesh_dim_element, &
    & Mesh_coord_element, Mesh_coord_element_Init, &
    & check_nf90_status

  ! NetCDF
  !
  !
  use netcdf

  ! 宣言文 ; Declaration statements
  !
  implicit none
  private

  !
  type, public :: IcGrid_ncReader
    ! 公開メンバー変数
    ! Public member variable
    !

    integer :: ncID

    type(Mesh2_ncInfo) :: mesh2Info

    type(IcGrid2D_FVM), pointer :: icgrid

  end type IcGrid_ncReader

  ! 公開手続き
  ! Public procedures
  !
  public :: IcGrid_ncReader_Init
  public :: open_ncFile, read_Simulation_Parameter, read_GridData, read_FieldData, close_ncFile

  ! interface 文; interface statements
  !
  !
  interface IcGrid_ncReader_Init
    module procedure IcGrid2D_ncReader_Init
  end interface IcGrid_ncReader_Init

  interface read_FieldData
    module procedure read_Field2D_Data
  end interface read_FieldData

contains

!
subroutine IcGrid2D_ncReader_Init( &
  & self,                        & ! (inout)
  & ref_icgrid )                   ! (in)

  ! 宣言文 ; Declaration statements
  !

  type(IcGrid_ncReader), intent(inout) :: self
  type(IcGrid2D_FVM), intent(in), target :: ref_icgrid

  ! 作業変数
  ! Work variables
  !

  ! 実行文 ; Executable statements
  !

  self%icgrid => ref_icgrid

  ! 構造型 Mesh2_Info の変数を初期化する.
  call Mesh2_ncInfo_Init(self%mesh2Info, self%icgrid)

end subroutine IcGrid2D_ncReader_Init

!
subroutine open_ncFile( &
  & self,               & ! (inout)
  & file_name )           ! (in)

  ! 宣言文 ; Declaration statements
  !
  type(IcGrid_ncReader), intent(inout) :: self
  character(*), intent(in) :: file_name

  ! 実行文 ; Executable statement
  !

  ! netCDF ファイルの作成
  call check_nf90_status( &
    & nf90_open(file_name, NF90_NOWRITE, self%ncID),  &
    & message='open netCDF file `' // trim(file_name) //  '`' )

  ! Mesh2 の次元要素である node (節) に対応する次元 ID を netCDF ファイルから取得する.
  call check_nf90_status( &
    & nf90_inq_dimid(self%ncID, self%mesh2Info%node%element_name, self%mesh2Info%node%dimID), &
    & message='read dimension information from netCDF file' )

  ! Mesh2 の次元要素である node (節) の総数を netCDF ファイルから取得する.
  call check_nf90_status( &
    & nf90_inquire_dimension(self%ncID, self%mesh2Info%node%dimID, len=self%mesh2Info%node%num) &
    & )

end subroutine open_ncFile

!
subroutine read_Simulation_Parameter( &
  & self,                                    &  ! (inout)
  & integration_time, time_step, output_tick &  ! (in)
  & )

  ! 宣言文 ; Declaration statements
  !
  type(IcGrid_ncReader), intent(inout) :: self
  real(DP), intent(out) :: integration_time
  real(DP), intent(out) :: time_step
  real(DP), intent(out) :: output_tick

  ! 実行文 ; Executable statements
  !

  ! 各シミュレーションパラメータのデータを, NetCDF のグローバル領域から読み込む.
  call check_nf90_status( &
    & nf90_get_att(self%ncID, NF90_GLOBAL, 'integration_time', integration_time) &
    & )

  call check_nf90_status( &
    & nf90_get_att(self%ncID, NF90_GLOBAL, 'time_step', time_step) &
    & )

  call check_nf90_status( &
    & nf90_get_att(self%ncID, NF90_GLOBAL, 'output_tick', output_tick) &
    & )


end subroutine read_Simulation_Parameter

!
subroutine read_GridData( &
  & self )                  ! (inout)

  ! モジュール引用 ; Use statement
  !

  ! 座標変換
  ! Coordinate conversion
  !
  use igmcore_coordinate_conversion, only: &
    & geo_to_orth_pos

  ! 宣言文 ; Declaration statements
  !
  type(IcGrid_ncReader), intent(inout) :: self

  ! 作業変数
  ! Work variable
  !
  real(DP), allocatable :: s_rcs_node_x(:), s_rcs_node_y(:)
  integer :: rcs_AGrid_shape(3)
  integer :: rcID, i,j
  real(DP) :: radius
  integer :: EMax, EMin, EffSize

  ! 実行文 ; Executable statements
  !

  ! 正二十面格子の矩形領域の配列のインデックス情報を取得する.
  EMin = get_EffSize_Min(self%icgrid)
  EMax = get_EffSize_Max(self%icgrid)
  EffSize = EMax - EMin + 1

  ! 格子の経度・緯度についての情報を保持している Mesh2_node_x, Mesh2_node_y を読み込み,
  ! 緯度経度座標データのままひとまず構造体 IcGrid2D_FVM の変数に保存する.
  !

  allocate( s_rcs_node_x(self%Mesh2Info%node%num) )
  allocate( s_rcs_node_y(self%Mesh2Info%node%num) )

!  write(*,*) 'reading mesh coordinate data from netCDF...'

  ! Mesh2_node_x, Mesh2_node_y の変数 ID を取得する.
  call check_nf90_status( &
    & nf90_inq_varid(self%ncID, self%mesh2Info%node_x%element_name, self%mesh2Info%node_x%varID) &
    & )
  call check_nf90_status( &
    & nf90_inq_varid(self%ncID, self%mesh2Info%node_y%element_name, self%mesh2Info%node_y%varID) &
    & )

  ! Mesh2_node_x, Mesh2_node_y のデータを読み込み, 作業用の 1 次元配列に取り込む
  call check_nf90_status( &
    & nf90_get_var(self%ncID, self%mesh2Info%node_x%varID, s_rcs_node_x) &
    & )

  call check_nf90_status( &
    & nf90_get_var(self%ncID, self%mesh2Info%node_y%varID, s_rcs_node_y) &
    & )

  ! 1 次元配列に格納した格子の経度・緯度の座標データを, 構造体 IcGrid2D_FVM の成分 rcs_AGrid に格納する.
  ! この際, 読み込んだ配列データの形状を変換する.
  radius = get_IcRadius(self%icgrid)
  rcs_AGrid_shape = shape(self%icgrid%rcs_AGrid(:,EMin:EMax,EMin:EMax,1))
  self%icgrid%rcs_AGrid(:,EMin:EMax,EMin:EMax,1) = reshape( s_rcs_node_x, rcs_AGrid_shape )
  self%icgrid%rcs_AGrid(:,EMin:EMax,EMin:EMax,2) = reshape( s_rcs_node_y, rcs_AGrid_shape )
  self%icgrid%rcs_AGrid(:,EMin:EMax,EMin:EMax,3) = radius

  ! rcs_AGrid に格納した格子位置に関する緯度経度座標データを, デカルト座標データに変換する.
  !

  do rcID=1, RC_REGIONS_NUM
    do j=EMin, EMax
      do i=EMin, EMax
        !
        if ( rcID <= 5 .and. i==EMin .and. j==EMin ) then
          self%icgrid%rcs_AGrid(rcID, i,j, :) = (/ 0.0d0, 0.0d0, radius /)

        else if( rcID > 5 .and. i==EMax .and. j==EMax ) then
          self%icgrid%rcs_AGrid(rcID, i,j, :) = (/ 0.0d0, 0.0d0, -radius /)

        else
          self%icgrid%rcs_AGrid(rcID, i,j, :) = geo_to_orth_pos( self%icgrid%rcs_AGrid(rcID,i,j,:) )
        end if

      end do
    end do
  end do

  ! のりしろを貼り合わせる
  call paste_margin_width(self%icgrid)

end subroutine read_GridData

!
subroutine read_Field2D_Data(&
  & self,                 & ! (in)
  & name,                 & ! (in)
  & field,                & ! (inout)
  & time_level )            ! (in)

  ! 宣言文 ; Declaration statements
  !
  type(IcGrid_ncReader), intent(in) :: self
  character(*), intent(in) :: name
  type(Field_IcGrid2D), intent(inout) :: field
  integer, intent(in) :: time_level

  ! 作業変数
  ! Work variables
  !
  integer :: field_shape(3)
  integer :: varID

  integer :: EMax, EMin
  real(DP), allocatable :: field_temp(:)
  character(STRING) :: long_name
  character(TOKEN) :: units


  ! 実行文 ; Executable statement
  !

  ! 正二十面格子の矩形領域の配列のインデックス情報を取得する.
  EMin = get_EffSize_Min(self%icgrid)
  EMax = get_EffSize_Max(self%icgrid)

  ! 一次元化された二次元物理場データを NetCDF から読み込むときに,
  ! 一時的にそのデータを格納するための作業配列のメモリを確保する.
  allocate( field_temp(self%Mesh2Info%node%num) )

  ! 読み出す物理場変数に対応する NetCDF における変数 ID を取得する.
  call check_nf90_status( &
    & nf90_inq_varid(self%ncID, name, varID), &
    & message='inqure variable ID: ' //  trim(name) )

  ! 時間レベル time_level の一次元化された二次元物理場データを読み込み, 作業配列に取り込む.
  call check_nf90_status( &
    & nf90_get_var(self%ncID, varID, field_temp, &
        & start=(/ 1, time_level /), count=(/ self%Mesh2Info%node%num, 1 /) ), &
    & message='get variable: ' // trim(name) )

  ! 物理場の長い名前を取得する.
  call check_nf90_status( &
    & nf90_get_att(self%ncID, varID, "long_name", long_name), &
    & message = 'get attribute: long_name' )

  ! 物理場の長い単位を取得する.
  call check_nf90_status( &
    & nf90_get_att(self%ncID, varID, "units", units), &
    & message = 'get attribute: units' )

  ! 一次元化された二次元物理場データを, 2 次元に戻す.
  field_shape = shape(self%icgrid%rcs_AGrid(:,EMin:EMax,EMin:EMax,1))
  field%val(:,EMin:EMax,EMin:EMax,1) = reshape( field_temp, field_shape )

  ! 読み込んだ物理場の長い名前・単位を Field_IcGrid2D の変数に設定する.
  call set_long_field2D_name(field, long_name)
  call set_field2D_units(field, units)

  ! 各矩形領域の袖領域部分を隣の矩形領域端のデータで埋める.
  call paste_field_margin(field)

end subroutine read_Field2D_Data

!
subroutine close_ncFile(self)

  ! 宣言文 ; Declaration statements
  !
  type(IcGrid_ncReader), intent(in) :: self

  ! 実行文 ; Executable statement
  !
  call check_nf90_status( nf90_close(self%ncID) )

end subroutine close_ncFile

!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!
!
! 非公開手続き
!
!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!

end module IcGrid_ncReader_mod