src/core/field/Field_IcGrid2D_Manager.f90

Go to the documentation of this file.

module Field_IcGrid2D_Manager

  ! モジュール引用; Use statement
  !

  ! 種類型パラメータ
  ! Kind type parameter
  !
  use dc_types, only: DP,    &  ! 倍精度実数型. Double precision.
    &                 TOKEN, &
    &                 STRING

  ! メッセージ出力
  ! Messgae dump
  !
  use dc_message, only: MessageNotify

  ! 数学
  ! Mathematic
  !
  use igmcore_math, only: PI

  ! 正二十面体格子データの管理
  ! Manager of Icosahedral grid data
  !
  use IcGrid2D_FVM_Manager, only: &
    & IcGrid2D_FVM, &
    & get_idMin, get_idMax, get_EffSize_Min, get_EffSize_Max, get_IcRadius, &
    & RC_REGIONS_NUM

  ! 物理場データを管理する構造体のための基底モジュール
  ! Base module for some derived types to manage the physical field data
  !
  use Physical_Field_Manager, only: &
    & Physical_Field, &
    & Physical_Field_Init, &
    & get_name_ => get_field_name, &
    & get_long_name_ => get_long_field_name, &
    & get_dimension_ => get_field_rank, &
    & get_units_ => get_field_units, &
    & set_name_ => set_field_name, &
    & set_long_name_ => set_long_field_name, &
    & set_units_ => set_field_units

  ! 宣言文 ; Declaration statement
  !
  implicit none
  private

  !
  type, public :: Field_IcGrid2D

    real(DP), pointer :: val(:,:,:,:) => null()
    ! f2003: real(DP), allocatable :: val(:,:,:,:)

    ! 非公開メンバ変数
    ! Private memeber variables
    !

    type(Physical_Field) ::  base
    ! f2003: type(Physical_Field), private ::  base

    type(IcGrid2D_FVM), pointer :: icgrid
    ! f2003: type(IcGrid2D_FVM), pointer, private :: icgrid

  end type Field_IcGrid2D

  ! interface 文 ; interface statements
  !
  interface Field_IcGrid2D_Init
    module procedure init_Field_IcGrid2D1
    module procedure init_Field_IcGrid2D2
  end interface Field_IcGrid2D_Init

  ! 公開手続き
  ! Public procedures
  !

  public :: Field_IcGrid2D_Init, Field_IcGrid2D_Final
  public :: paste_field_margin, global_mean
  public :: get_icgrid, get_Physical_Field

  public :: get_field2D_name, get_long_field2D_name, get_field2D_rank, get_field2D_units
  public :: set_field2D_name, set_long_field2D_name, set_field2D_units

contains

!
subroutine init_Field_IcGrid2D0( &
  & self,                     &  ! (inout)
  & icgrid, name, field_rank, &  ! (in)
  & long_name, units          &  ! (in)
  & )

  ! 宣言文 ; Declaration statement
  !
  type(Field_IcGrid2D), intent(inout) :: self
  type(IcGrid2D_FVM), pointer :: icgrid
  character(*), intent(in) :: name
  integer, intent(in) :: field_rank
  character(*), intent(in) :: long_name
  character(*), intent(in) :: units

  ! 作業変数
  ! Work variables
  !
  integer :: idMin, idMax

  ! 実行文 ; Executable statement
  !
!  write(*,*) 'Field_IcGrid2D initialize, name=', trim(name)

  self%icgrid => icgrid

  idMin = get_IdMin(self%icgrid)
  idMax = get_IdMax(self%icgrid)

  ! 物理場データを格納する配列のメモリを確保する.
  allocate(self%val(RC_REGIONS_NUM, idMin:idMax, idMin:idMax, 1:field_rank))

  ! 基底構造体の初期化関数を呼び出す.
  call Physical_Field_Init(self%base, name, field_rank, long_name, units)

end subroutine init_Field_IcGrid2D0

!
subroutine init_Field_IcGrid2D1( &
  & self,                                &  ! (inout)
  & icgrid, name, rank, long_name, units &  ! (in)
  & )

  ! 宣言文 ; Declaration statement
  !
  type(Field_IcGrid2D), intent(inout) :: self
  type(IcGrid2D_FVM), intent(in), target :: icgrid
  character(*), intent(in) :: name
  integer, intent(in) :: rank
  character(*), intent(in) :: long_name
  character(*), intent(in) :: units

  ! 作業変数
  ! Work variables
  !
  integer :: idMin, idMax
  type(IcGrid2D_FVM), pointer :: icgrid_ptr

  ! 実行文 ; Executable statement
  !

  !  write(*,*) 'Field_IcGrid2D initialize, name=', trim(name)

  !
  icgrid_ptr => icgrid
  call init_Field_IcGrid2D0(self, icgrid_ptr, name, rank, long_name, units)

end subroutine init_Field_IcGrid2D1

!
subroutine init_Field_IcGrid2D2( &
  & self,              &  ! (inout)
  & icgrid, name, rank &  ! (in)
  & )

  ! 宣言文 ; Declaration statement
  !
  type(Field_IcGrid2D), intent(inout) :: self
  type(IcGrid2D_FVM), intent(in), target :: icgrid
  character(*), intent(in) :: name
  integer, intent(in) :: rank

  ! 作業変数
  ! Work variables
  !

  ! 実行文 ; Executable statement
  !

  call init_Field_IcGrid2D1(self, icgrid, name, rank, '', '')

end subroutine init_Field_IcGrid2D2

!
subroutine Field_IcGrid2D_Final( &
  & self &  ! (inout)
  & )

  ! 宣言文 ; Declaration statement
  !
  type(Field_IcGrid2D), intent(inout) :: self

  ! 実行文　; Executable statement
  !

!  write(*,*) 'Field_IcGrid2D finalize, name=', trim(get_name(self))

  ! 物理場データを保持している配列のメモリを解放する.
  deallocate(self%val)

end subroutine Field_IcGrid2D_Final

!
function get_Physical_Field( &
  & self &  ! (inout)
  & ) result(val)

  ! 宣言文 ; Declaration statements
  !
  type(Field_IcGrid2D), intent(inout), target :: self
  type(Physical_Field), pointer :: val

  ! 実行文 ; Executable statements
  !
  val => self%base

end function get_Physical_Field

!
function get_icgrid( &
  & self &  ! (inout)
  & ) result(icgrid)

  ! 宣言文 ; Declaration statement
  !
  type(Field_IcGrid2D), intent(in) :: self       !
  type(IcGrid2D_FVM), pointer :: icgrid

  ! 実行文 ; Executable statement
  !

  icgrid => self%icgrid

end function get_icgrid

!
subroutine paste_field_margin( &
  & self &  ! (inout)
  & )

  ! 宣言文 ; Declaration statements
  !
  type(Field_IcGrid2D), intent(inout) :: self       !

  ! 作業変数
  ! Work variables
  !
  integer :: idlist1(7) = (/ 5, 1, 2, 3, 4, 5, 1 /)
  integer :: idlist2(7) = (/ 10, 6, 7, 8, 9, 10, 6 /)
  integer :: EMin, EMax, marginw, idMin
  integer i, k

  ! 実行文 ; Executable statements
  !

  EMin = get_EffSize_Min(self%icgrid)
  EMax = get_EffSize_Max(self%icgrid)

  ! ノリシロの幅を計算する.
  idMin = get_IdMin(self%icgrid)
  marginw = EMin - idMin

  do i=1, RC_REGIONS_NUM/2
    do k=1, marginw
      ! 北半球側の矩形領域ののりしろに値をコピーする.
      self%val(i, EMin:EMax, EMin-k, :) = self%val(idlist1(i), EMin+k, EMin:EMax, :)
      self%val(i, EMax+k, EMin:EMax, :) = self%val(idlist2(i), EMin+k, EMin:EMax, :)
      self%val(i, EMin:EMax, EMax+k, :) = self%val(idlist2(i+1), EMin:EMax, EMin+k, :)
      self%val(i, EMin-k, EMin:EMax, :) = self%val(idlist1(i+2), EMin:EMax, EMin+k, :)

      ! 南半球側の矩形領域ののりしろに値をコピーする.
      self%val(i+5, EMin:EMax, EMin-k, :) = self%val(idlist1(i+1), EMin:EMax, EMax-k, :)
      self%val(i+5, EMax+k, EMin:EMax, :) = self%val(idlist2(i), EMin:EMax, EMax-k, :)
      self%val(i+5, EMin:EMax, EMax+k, :) = self%val(idlist2(i+2), EMax-k, EMin:EMax, :)
      self%val(i+5, EMin-k, EMin:EMax, :) = self%val(idlist1(i+2), EMax-k, EMin:EMax, :)
    end do
  end do

end subroutine paste_field_margin

!
function global_mean( &
  & self &  ! (inout)
  & ) result(val)

  ! 宣言文 ; Declaration statement
  !
  type(Field_IcGrid2D), intent(inout) :: self       !
  real(DP)  val

  ! 作業変数
  ! Work variables
  !
  integer :: rcID, i, j
  integer :: EMin, EMax
  type(IcGrid2D_FVM), pointer :: icgrid

  ! 実行文 ; Executable statement
  !

  ! 物理場のランクが 1 次元(スカラー場)であることを確認する.
  if( get_field2D_rank(self) /= 1 ) then
    call MessageNotify( 'E', 'IGMBaseLib IO::Field_IcGrid2D::global_mean', &
      & "The rank of Field_IcGrid2D(=%d) is invalid.", i=(/ get_field2D_rank(self) /) )
    stop
    return
  end if

  EMin = get_EffSize_Min(self%icgrid)
  EMax = get_EffSize_Max(self%icgrid)
  icgrid => self%icgrid

  ! まず指定されたスカラー場の, 全球積分値を求める.
  val = self%val(1,EMin,EMin, 1) * icgrid%rcs_CVArea(1,EMin,EMin) &
        + self%val(10,EMax,EMax, 1)  * icgrid%rcs_CVArea(10,EMax,EMax)

  do rcID=1, RC_REGIONS_NUM
    do j=EMin, EMax-1
      do i=EMin+1, EMax
        val = val + self%val(rcID,i,j, 1) * icgrid%rcs_CVArea(rcID,i,j)
      end do
    end do
  end do

  ! 球の面積で規格化する.
  val = val / ( 4.0d0 * PI * get_IcRadius(icgrid)**2 )

end function global_mean

!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!
!
! Physical_Field_mod の手続きをオーバライド
!
!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!


!
function get_long_field2D_name(self) result(val)

  ! 宣言文 ; Declaration statement
  !
  type(Field_IcGrid2D), intent(in) :: self
  character(STRING) val

  ! 実行文 ; Executable statement
  !

  val = get_long_name_(self%base)

end function get_long_field2D_name

!
subroutine set_long_field2D_name(self, long_name)
  ! 宣言文 ; Declaration statement
  !
  type(Field_IcGrid2D), intent(inout) :: self
  character(*), intent(in) ::  long_name

  ! 実行文 ; Executable statement
  !

  call set_long_name_(self%base, long_name)

end subroutine set_long_field2D_name

!
function get_field2D_units(self) result(val)
  ! 宣言文 ; Declaration statement
  !
  type(Field_IcGrid2D), intent(in) :: self
  character(TOKEN) val

  ! 実行文 ; Executable statement
  !

  val = get_units_(self%base)

end function get_field2D_units

!
subroutine set_field2D_units(self, units)
  ! 宣言文 ; Declaration statement
  !
  type(Field_IcGrid2D), intent(inout) :: self
  character(*), intent(in) ::  units

  ! 実行文 ; Executable statement
  !

  call set_units_(self%base, units)

end subroutine set_field2D_units

!
function get_field2D_rank(self) result(val)
  ! 宣言文 ; Declaration statement
  !
  type(Field_IcGrid2D), intent(in) :: self
  integer val

  ! 実行文 ; Executable statement
  !

  val = get_dimension_(self%base)

end function get_field2D_rank


!
function get_field2D_name( &
  & self &
  & ) result(name)

  ! 宣言文 ; Declaration statement
  !
  type(Field_IcGrid2D), intent(in) :: self       !
  character(TOKEN) name

  ! 実行文 ; Executable statement
  !

  name = get_name_(self%base)

end function get_field2D_name

!
subroutine set_field2D_name( &
  & self, name )

  ! 宣言文 ; Declaration statement
  !
  type(Field_IcGrid2D), intent(inout) :: self
  character(*), intent(in) ::  name

  ! 実行文 ; Executable statement
  !

  call set_name_(self%base, name)

end subroutine set_field2D_name

end module Field_IcGrid2D_Manager