* PACKAGE P2INTG  !" 物理過程(2) 諸量の時間積分
*
*" 履歴 93/08/29 保坂征宏            p2misc.F より移動並びに大幅修正
**********************************************************************
      SUBROUTINE TGINTG      !" 地面温度の積分・地表面放射補正
     M         ( GDTG  , RFLUX , DRFLUX ,   
     I           GTTG  , DELTM    )
*
*   [PARAM] 
#ifdef SYS_IBMS
      INCLUDE   (ZCDIM)                      !" 格子点数，波数
#else
#include        "zcdim.F"                    !" 格子点数，波数
#endif
*
*   [MODIFY] 
      REAL       GDTG  ( IDIM*JDIM )          !" 地表面温度
      REAL       RFLUX ( IDIM*JDIM, KMAX+1 )  !" 長波放射
      REAL       DRFLUX( IDIM*JDIM, KMAX+1,0:1 )!" 地表長波フラックス補正係数 
*
*   [INPUT] 
      REAL       GTTG   ( IDIM*JDIM )      !" 地表温度変化率(単位時間当)
      REAL       DELTM                     !" 時間刻みΔt
*
*   [INTERNAL WORK] 
      INTEGER    IJ, K
*
      SAVE
*
*"    < 1. 長波フラックスの補正 ( 地表フラックス分の補正 ) > 
*
      DO 1100 K = 1, KMAX+1
         DO 1100 IJ = 1, IDIM*JDIM
            RFLUX ( IJ,K ) = RFLUX ( IJ,K )
     &                       + DRFLUX( IJ,K,0 ) * GTTG ( IJ ) * DELTM    
 1100 CONTINUE
*
*"    < 2. 補正項係数変更 地表面放射分 その1 >  
*
      DO 2100 K = 1, KMAX+1
         DO 2100 IJ = 1, IDIM*JDIM
            DRFLUX ( IJ,K,0 ) = DRFLUX ( IJ,K,0 )/ GDTG ( IJ )**3 
 2100 CONTINUE
*
*"    < 3. 地表面温度時間積分 >  
*
      DO 3100 IJ = 1, IDIM*JDIM
            GDTG( IJ ) = GDTG( IJ ) + GTTG( IJ ) * DELTM 
 3100 CONTINUE
*
*"    < 4. 補正項係数変更 地表面放射分 その2 >       
*
      DO 4100 K = 1, KMAX+1
         DO 4100 IJ = 1, IDIM*JDIM
            DRFLUX ( IJ,K,0 ) = DRFLUX ( IJ,K,0 ) * GDTG ( IJ )**3 
 4100 CONTINUE
*
      RETURN
      END
