* PACKAGE DSTRT  !" 力学 初期値作成
*
***********************************************************************
      SUBROUTINE STRTV      !" 格子データをスペクトル変換, 再作成
     M         ( GDU   , GDV   , GDT   , GDPS  , GDQ   ,
     O           GDVOR , GDDIV ,
     C           EDEL  , UVFACT,
     W           WDVOR , WDDIV , WDT   , WDPI  , WDQ    )
*
#ifdef SYS_IBMS
      INCLUDE   (ZCDIM)
#else
#include        "zcdim.F"
#endif
*
*   [MODIFY] 
      REAL       GDU   ( IDIM*JDIM, KMAX )   !" 西風  Ｕ
      REAL       GDV   ( IDIM*JDIM, KMAX )   !" 南風  Ｖ
      REAL       GDT   ( IDIM*JDIM, KMAX )   !" 温度  Ｔ
      REAL       GDPS  ( IDIM*JDIM       )   !" 地表気圧
      REAL       GDQ   ( IDIM*JDIM, KMAX )   !" 比湿  ｑ
*
*   [OUTPUT] 
      REAL       GDVOR ( IDIM*JDIM, KMAX )   !" 渦度  ζ
      REAL       GDDIV ( IDIM*JDIM, KMAX )   !" 発散  Ｄ
*
*   [INPUT] 
      REAL       EDEL  ( NMDIM  )            !" ζ,Ｄ→Ｕ,Ｖ
      REAL       UVFACT( IDIM*JDIM )         !" u→U のファクター
*
*   [WORK]
      REAL       WDVOR ( NMDIM , KMAX     )  !" 渦度  ζ
      REAL       WDDIV ( NMDIM , KMAX     )  !" 発散  Ｄ
      REAL       WDT   ( NMDIM , KMAX     )  !" 温度  Ｔ
      REAL       WDPI  ( NMDIM            )  !" log Ps ＝π
      REAL       WDQ   ( NMDIM , KMAX     )  !" 比湿  ｑ
*
*   [INTERNAL WORK] 
      INTEGER    IJ
*
*
*"         < 1. 渦度，発散スペクトル  >
*
      CALL GUV2VD
     O         ( WDVOR , WDDIV ,
     I           GDU   , GDV   ,
     C           UVFACT         )
*
*"         < 2. 温度 スペクトル  >
*
      CALL G2W
     O         ( WDT   ,
     I           GDT   ,
     I           '    ', 'POSO', KMAX )
*
*"         < 3. 気圧 スペクトル >
*
      DO 3100 IJ = 1, IDIM*JDIM
         GDPS ( IJ ) = LOG( GDPS( IJ ) )
 3100 CONTINUE
*
      CALL G2W
     O         ( WDPI  ,
     I           GDPS  ,
     I           '    ', 'POSO', 1    )
*
*"         < 4. 比湿 スペクトル  >
*
      CALL G2W
     O         ( WDQ   ,
     I           GDQ   ,
     I           '    ', 'POSO', KMAX  )
*
*"         < 5. 格子データ再作成 >
*
      CALL GENGD
     O         ( GDU   , GDV   , GDT   , GDPS  , GDQ   ,
     O           GDVOR , GDDIV ,
     I           WDVOR , WDDIV , WDT   , WDPI  , WDQ   ,
     C           EDEL  , UVFACT                         )
*
       RETURN
       END
