* PACKAGE DPIXY  !" 力学 地表気圧の傾度
*
****************************************************************
      SUBROUTINE PIXPIY                      !" 地表気圧傾度
     O         ( GDPIX , GDPIY ,
     I           GDPS            )
*
*   [PARAM]
#ifdef SYS_IBMS
      INCLUDE   (ZCDIM)                      !" 格子点数, 波数
#else
#include        "zcdim.F"                    !" 格子点数, 波数
#endif
*   [OUTPUT] 
      REAL       GDPIX ( IDIM*JDIM       )   !" πの東西微分
      REAL       GDPIY ( IDIM*JDIM       )   !" πの南北微分
*
*   [INPUT] 
      REAL       GDPS  ( IDIM*JDIM       )
*
*   [INTERNAL WORK]
      COMMON    /COMWRK/
     &           GDPI  , WDPI
      REAL       GDPI  ( IDIM*JDIM       )   !" π=ln 地表気圧
      REAL       WDPI  ( NMDIM           )   !" 同スペクトル
*
      INTEGER    IJ
*
      DO 1100 IJ = 1, IDIM*JDIM
         GDPI ( IJ ) = LOG( GDPS( IJ ) )
 1100 CONTINUE
*
      CALL G2W
     O         ( WDPI  ,
     I           GDPI  ,
     I           '    ', 'POSO', 1    )
*
      IF ( MMAX .GE. 1 ) THEN
         CALL W2G
     O         ( GDPIX ,
     I           WDPI  ,
     I           'XGRA', 'POSO', 1   )
      ELSE
         CALL RESET ( GDPIX , IDIM*JDIM )
      ENDIF
*
      CALL W2G
     O         ( GDPIY ,
     I           WDPI  ,
     I           'YGRA', 'POSO', 1   )
*
      RETURN
      END
