* PACKAGE  ATFIL !" 共通 時間フィルター  
*
*"  [HIS] 90/08/31(numaguti) 
*
*
***********************************************************************
      SUBROUTINE TFILT      !"  タイムフィルター 
     M         ( GBU   , GBV   , GBT   , GBPS  , GBQ   ,
     M           GBVOR , GBDIV ,
     I           GAU   , GAV   , GAT   , GAPS  , GAQ   ,
     I           GAVOR , GADIV ,
     C           TFIL                                   )
*
#ifdef SYS_IBMS
      INCLUDE   (ZCDIM)                      !" 格子点数，波数
#else
#include        "zcdim.F"                    !" 格子点数，波数
#endif
*
*    [MODIFY]
      REAL       GBU   ( IDIM*JDIM*KMAX )    !" 西風  ｕ(t-Δt)
      REAL       GBV   ( IDIM*JDIM*KMAX )    !" 南風  ｖ(t-Δt)
      REAL       GBT   ( IDIM*JDIM*KMAX )    !" 温度  Ｔ(t-Δt)
      REAL       GBPS  ( IDIM*JDIM      )    !" 地表気圧(t-Δt)
      REAL       GBQ   ( IDIM*JDIM*KMAX )    !" 比湿  ｑ(t-Δt)
      REAL       GBVOR ( IDIM*JDIM*KMAX )    !" 渦度  ζ(t-Δt)
      REAL       GBDIV ( IDIM*JDIM*KMAX )    !" 発散  Ｄ(t-Δt)
*
*    [INPUT]
      REAL       GAU   ( IDIM*JDIM*KMAX )    !" 西風  ｕ(t)
      REAL       GAV   ( IDIM*JDIM*KMAX )    !" 南風  ｖ(t)
      REAL       GAT   ( IDIM*JDIM*KMAX )    !" 温度  Ｔ(t)
      REAL       GAPS  ( IDIM*JDIM      )    !" 地表気圧(t)
      REAL       GAQ   ( IDIM*JDIM*KMAX )    !" 比湿  ｑ(t)
      REAL       GAVOR ( IDIM*JDIM*KMAX )    !" 渦度  ζ(t)
      REAL       GADIV ( IDIM*JDIM*KMAX )    !" 発散  Ｄ(t)
      REAL       TFIL                        !" 時間フィルター係数
*
*    [INTERNAL WORK]
      COMMON    /COMWRK/
     &           GBBU  , GBBV  , GBBT  ,
     &           GBBPS , GBBQ  ,
     &           GBBVOR, GBBDIV
      REAL       GBBU  ( IDIM*JDIM*KMAX )    !" 西風  ｕ セーブ値
      REAL       GBBV  ( IDIM*JDIM*KMAX )    !" 南風  ｖ セーブ値
      REAL       GBBT  ( IDIM*JDIM*KMAX )    !" 温度  Ｔ セーブ値
      REAL       GBBPS ( IDIM*JDIM      )    !" 地表気圧 セーブ値
      REAL       GBBQ  ( IDIM*JDIM*KMAX )    !" 比湿  ｑ セーブ値
      REAL       GBBVOR( IDIM*JDIM*KMAX )    !" 渦度  ζ セーブ値
      REAL       GBBDIV( IDIM*JDIM*KMAX )    !" 発散  Ｄ セーブ値
*
      REAL       TFIL1
      INTEGER    IJ, IJK
*
*"         < 1.  (t-Δt)のデータをロード >
*
      CALL LOADGB
     O         ( GBBU  , GBBV  , GBBT  , GBBPS , GBBQ  ,
     O           GBBVOR, GBBDIV                          )
*
*"         < 2. 時間フィルター >
*
      TFIL1 = 1. - 2. * TFIL
*
      DO 1100 IJK = 1, IDIM*JDIM*KMAX
         GBU  ( IJK ) = TFIL1 * GBU   ( IJK )
     &                + TFIL  * GAU   ( IJK )
     &                + TFIL  * GBBU  ( IJK )
         GBV  ( IJK ) = TFIL1 * GBV   ( IJK )
     &                + TFIL  * GAV   ( IJK )
     &                + TFIL  * GBBV  ( IJK )
         GBT  ( IJK ) = TFIL1 * GBT   ( IJK )
     &                + TFIL  * GAT   ( IJK )
     &                + TFIL  * GBBT  ( IJK )
         GBQ  ( IJK ) = TFIL1 * GBQ   ( IJK )
     &                + TFIL  * GAQ   ( IJK )
     &                + TFIL  * GBBQ  ( IJK )
         GBVOR( IJK ) = TFIL1 * GBVOR ( IJK )
     &                + TFIL  * GAVOR ( IJK )
     &                + TFIL  * GBBVOR( IJK )
         GBDIV( IJK ) = TFIL1 * GBDIV ( IJK )
     &                + TFIL  * GADIV ( IJK )
     &                + TFIL  * GBBDIV( IJK )
 1100 CONTINUE
*
      DO 1200 IJ = 1, IDIM*JDIM
         GBPS ( IJ  ) = TFIL1 * GBPS  ( IJ  )
     &                + TFIL  * GAPS  ( IJ  )
     &                + TFIL  * GBBPS ( IJ  )
 1200 CONTINUE
*
      RETURN
      END
