* PACKAGE APARM  !" 共通 パラメーター
*
*"  [HIS] 90/08/31(numaguti)
*
***********************************************************************
      SUBROUTINE SETPAR      !" パラメーターのセット
     O         ( ITSTRT, ITEND , IORSTR,
     O           IDELT , INISTY, TFILY   )
*
*   [PARAM] 
#ifdef SYS_IBMS
      INCLUDE   (ZCDIM)                      !" 格子点数，波数
      INCLUDE   (ZHDIM)                      !" 文字列文字数
      INCLUDE   (ZCCOM)                      !" 標準物理定数
#else
#include        "zcdim.F"                    !" 格子点数，波数
#include        "zhdim.F"                    !" 文字列文字数
#include        "zccom.F"                    !" 標準物理定数
#endif
*
*   [OUTPUT] 
      INTEGER    ITSTRT                      !" 計算開始時刻
      INTEGER    ITEND                       !" 計算終了時刻
      INTEGER    IORSTR                      !" 出力間隔：再出発
*
      INTEGER    IDELT                       !" 標準時間刻み
      INTEGER    INISTY                      !" 初期ステップ数
      REAL       TFILY                       !" 時間フィルター係数
*
*    [INTERNAL WORK]
      INTEGER    IFPAR, JFPAR
      REAL       VMISS
*
*   [INTERNAL PARM]       
      CHARACTER  RUN  *(NCC)                 !" 実験名
      CHARACTER  SIGN *(NCC)                 !" 実験者名
*
      CHARACTER  TUNIT  *4                   !" 時刻単位
      INTEGER    START                       !" 計算開始時刻
      INTEGER    END                         !" 計算終了時刻
      INTEGER    INTRST                      !" 出力間隔：再出発
      INTEGER    DELT                        !" 標準時間刻み
      INTEGER    INISTP                      !" 初期ステップ数
      REAL       TFIL                        !" 時間フィルター係数
*
      NAMELIST    /NMRUN/  RUN   , SIGN
      NAMELIST    /NMINTG/ TUNIT , DELT  , INISTP, TFIL
      NAMELIST    /NMTIME/ TUNIT , START , END   , INTRST
      NAMELIST    /NMFILE/ VMISS
      NAMELIST    /NMPCON/ CP    , EL    , ER    , GRAV  ,
     &                     RAIR  , RVAP  , EPSV  , ES0   , STB
*
*"         < 1. 実験名 >
*
      RUN  = 'TEST001'
      SIGN = 'GCM5'
*
      CALL   REWNML ( IFPAR , JFPAR )
      READ   ( IFPAR, NMRUN , END=1190 )
 1190 WRITE  ( JFPAR, NMRUN  )
*
      CALL GTCSET( 'DDSET' , RUN    )
      CALL GTCSET( 'MYSIGN', SIGN   )
*
*"         < 2. 時間積分 >
*
      TUNIT  = 'MIN'
      DELT   = 30.  
      INISTP = 3
      TFIL   = 0.05  
*
      CALL   REWNML ( IFPAR , JFPAR )
      READ   ( IFPAR, NMINTG, END=2190 )
 2190 WRITE  ( JFPAR, NMINTG )
*
      CALL GUCT2I
     I         ( DELT , TUNIT , 'SEC' , 1     ,
     O           IDELT                           )
      CALL ASUTIM
     I         ( TUNIT )
      CALL ASDELT
     I         ( IDELT )
*
*"         < 3. 時間制御 >
*
      TUNIT  = 'DAY'
      START  = 0
      END    = 1
      INTRST = 0
*
      CALL   REWNML ( IFPAR , JFPAR )
      READ   ( IFPAR, NMTIME, END=3190 )
 3190 WRITE  ( JFPAR, NMTIME )
*
      CALL ACTIME
     I         ( START , TUNIT  , '#'    ,
     O           ITSTRT                   )
      CALL ACTIME
     I         ( END   , TUNIT  , '#'    ,
     O           ITEND                    )
      CALL ACTIME
     I         ( INTRST, TUNIT  , '#'    ,
     O           IORSTR                   )
*
*"         < 4. ファイル >
*
      CALL GZDBGT( 'MISS', VMISS )
*
      CALL   REWNML ( IFPAR , JFPAR )
      READ   ( IFPAR, NMFILE, END=4190 )
 4190 CONTINUE
      WRITE  ( JFPAR, NMFILE )
*
      CALL GZDBST( 'MISS', VMISS )
*
*"         < 5. 物理定数 >
*
      CALL PCONST
*
      CALL   REWNML ( IFPAR , JFPAR )
      READ   ( IFPAR, NMPCON, END=5190 )
 5190 WRITE  ( JFPAR, NMPCON )
*
      INISTY = INISTP
      TFILY  = TFIL
*
      RETURN
      END
