dcdatetimesub.f90

Go to the documentation of this file.

! -*- mode: f90; coding: utf-8 -*-
!-----------------------------------------------------------------------
! Copyright (c) 2000-2026 Gtool Development Group. All rights reserved.
!-----------------------------------------------------------------------
 
function dcdatetime_sub_tf(time, diff) result(result)
 
  use dc_date_generic, only: eval, dcdatetimecreate
  use dc_date_types, only: dc_datetime, dc_difftime
  use dc_scaledsec, only: dc_scaled_sec, &
    & operator(<), operator(>), operator(<=), operator(>=), &
    & operator(+), operator(-), operator(*), operator(/), &
    & modulo, int, abs, sign
  implicit none
  type(dc_datetime):: result
  type(dc_datetime), intent(in):: time
  type(dc_difftime), intent(in):: diff
  type(dc_scaled_sec):: time_year, time_mon, time_day, time_sec
  integer:: time_caltype
  character(6):: time_zone
continue
  call eval(time, &
    & sclyear = time_year, sclmon = time_mon, sclday = time_day, &
    & sclsec = time_sec, caltype = time_caltype, zone = time_zone )
  call dcdatetimecreate(result, &
    & sclyear = time_year, &
    & sclmon = time_mon - diff % mon, &
    & sclday = time_day - diff % day, &
    & sclsec = time_sec - diff % sec, &
    & caltype = time_caltype, zone = time_zone)
end function dcdatetime_sub_tf
 
function dcdatetime_sub_tt(time1, time2) result(result)
 
  use dc_date_generic, only: evalsclsec, zonetodiff, operator(-)
  use dc_date_types, only: dc_datetime, dc_difftime
  use dc_date_internal, only: dcdate_normalize
  use dc_scaledsec, only: dc_scaled_sec, &
    & operator(<), operator(>), operator(<=), operator(>=), &
    & operator(+), operator(-), operator(*), operator(/), &
    & modulo, int, abs, sign
  implicit none
  type(dc_difftime):: result
  type(dc_datetime), intent(in):: time1, time2
continue
  result % day = time1 % day - time2 % day
  result % sec = time1 % sec - time2 % sec &
    & + evalsclsec(zonetodiff(time1 % zone) - zonetodiff(time2 % zone))
  result % day_seconds = time1 % day_seconds
  call dcdate_normalize(result % day, result % sec, result % day_seconds, result % nondim_flag)
end function dcdatetime_sub_tt
 
function dcdatetime_sub_ff(diff1, diff2) result(result)
 
  use dc_date_internal, only: dcdate_normalize, dcdate_nondimcheck
  use dc_date_types, only: dc_datetime, dc_difftime
  use dc_scaledsec, only: operator(-)
  implicit none
  type(dc_difftime):: result
  type(dc_difftime), intent(in):: diff1, diff2
continue
  result % mon = diff1 % mon - diff2 % mon
  result % day = diff1 % day - diff2 % day
  result % sec = diff1 % sec - diff2 % sec
  result % day_seconds = diff1 % day_seconds
  call dcdate_nondimcheck('dc_date#operator(-)', diff1, diff2, result)
  call dcdate_normalize(result % day, result % sec, result % day_seconds, result % nondim_flag)
end function dcdatetime_sub_ff
 
function dcdatetime_sub_fd(diff, sec) result(result)
 
  use dc_date_internal, only: dcdate_normalize
  use dc_date_types, only: dc_datetime, dc_difftime
  use dc_scaledsec, only: operator(-)
  use dc_types, only: dp
  implicit none
  type(dc_difftime):: result
  type(dc_difftime), intent(in):: diff
  real(dp), intent(in):: sec
continue
  result % mon = diff % mon
  result % day = diff % day
  result % sec = diff % sec - sec
  result % day_seconds = diff % day_seconds
  call dcdate_normalize(result % day, result % sec, result % day_seconds, result % nondim_flag)
end function dcdatetime_sub_fd
 
function dcdatetime_sub_fr(diff, sec) result(result)
 
  use dc_date_generic, only: operator(-)
  use dc_date_types, only: dc_datetime, dc_difftime
  use dc_scaledsec, only: operator(-)
  use dc_types, only: dp
  implicit none
  type(dc_difftime):: result
  type(dc_difftime), intent(in):: diff
  real, intent(in):: sec
continue
  result = diff - real( sec, dp )
end function dcdatetime_sub_fr
 
function dcdatetime_sub_fi(diff, sec) result(result)
 
  use dc_date_generic, only: operator(-)
  use dc_date_types, only: dc_datetime, dc_difftime
  use dc_scaledsec, only: operator(-)
  use dc_types, only: dp
  implicit none
  type(dc_difftime):: result
  type(dc_difftime), intent(in):: diff
  integer, intent(in):: sec
continue
  result = diff - real( sec, dp )
end function dcdatetime_sub_fi