dccalinquire.f90 File Reference

Go to the source code of this file.

Functions/Subroutines
subroutine	dccalinquire1 (cal_type, month_in_year, day_in_month, day_in_month_ptr, hour_in_day, min_in_hour, sec_in_min, cal, err)
	暦情報の問い合わせ

Function/Subroutine Documentation

dccalinquire1()

subroutine dccalinquire1	(	character(*), intent(out), optional	cal_type,
		integer, intent(out), optional	month_in_year,
		integer, dimension(:), intent(out), optional	day_in_month,
		integer, dimension(:), optional, pointer	day_in_month_ptr,
		integer, intent(out), optional	hour_in_day,
		integer, intent(out), optional	min_in_hour,
		real(dp), intent(out), optional	sec_in_min,
		type(dc_cal), intent(in), optional, target	cal,
		logical, intent(out), optional	err
	)

暦情報の問い合わせ

Author

Yasuhiro MORIKAWA

Copyright

Copyright (C) GFD Dennou Club, 2009-2026. All rights reserved.
License is BSD-2-Clause. see COPYRIGHT in detail

Definition at line 88 of file dccalinquire.f90.

 
  use dc_calendar_types, only: dc_cal
  use dc_calendar_internal, only: default_cal, default_cal_set, dccaltype_str
  use dc_message, only: messagenotify
  use dc_string, only: lchar
  use dc_trace, only: beginsub, endsub
  use dc_error, only: storeerror, dc_noerr, dc_enotinit
  use dc_types, only: string, dp
  implicit none
  character(*), intent(out), optional:: cal_type
  integer, intent(out), optional:: month_in_year
  integer, intent(out), optional:: day_in_month(:)
  integer, pointer, optional:: day_in_month_ptr(:)
  integer, intent(out), optional:: hour_in_day
  integer, intent(out), optional:: min_in_hour
  real(DP), intent(out), optional:: sec_in_min
  type(DC_CAL), intent(in), optional, target:: cal
  logical, intent(out), optional:: err
 
  ! 作業変数
  ! Work variables
  !
  type(DC_CAL), pointer:: calp =>null()
  integer:: siz_dm
  integer:: stat
  character(STRING):: cause_c
  character(*), parameter:: subname = 'DCCalInquire1'
continue
  call beginsub( subname )
  stat = dc_noerr
  cause_c = ''
 
  ! オブジェクトのポインタ割付
  ! Associate pointer of an object
  !
  if ( present( cal ) ) then
    calp => cal
  else
    calp => default_cal
    if ( .not. calp % initialized ) call default_cal_set
  end if
 
  ! 初期設定のチェック
  ! Check initialization
  !
  if ( .not. calp % initialized ) then
    stat = dc_enotinit
    cause_c = 'DC_CAL'
    goto 999
  end if
 
  ! 各要素への値の参照
  ! Refer elements
  !
  if ( present( cal_type      ) ) then
    cal_type = dccaltype_str( calp % cal_type )
  end if
  if ( present( month_in_year ) ) month_in_year = calp % month_in_year
  if ( present( hour_in_day   ) ) hour_in_day   = calp % hour_in_day
  if ( present( min_in_hour   ) ) min_in_hour   = calp % min_in_hour
  if ( present( sec_in_min    ) ) sec_in_min    = calp % sec_in_min
 
  if ( present( day_in_month     ) ) then
    if ( size( day_in_month ) > 0 ) then
      day_in_month = 0
      siz_dm = min( size( day_in_month ), size( calp % day_in_month ) )
      day_in_month(1:siz_dm) = calp % day_in_month(1:siz_dm)
    end if
  end if
 
  if ( present( day_in_month_ptr ) ) then
    siz_dm = size( calp % day_in_month )
    allocate( day_in_month_ptr(1:siz_dm) )
    day_in_month_ptr(1:siz_dm) = calp % day_in_month(1:siz_dm)
  end if
 
  ! 終了処理, 例外処理
  ! Termination and Exception handling
  !
999 continue
  nullify( calp )
  call storeerror( stat, subname, err, cause_c )
  call endsub( subname )

References dc_trace::beginsub(), dc_error::dc_enotinit, dc_error::dc_noerr, dc_calendar_internal::dccaltype_str(), dc_calendar_internal::default_cal, dc_calendar_internal::default_cal_set(), dc_types::dp, dc_trace::endsub(), dc_error::storeerror(), and dc_types::string.

Here is the call graph for this function: