dccaldatechkleapyear.f90

Go to the documentation of this file.

! -*- mode: f90; coding: utf-8 -*-
!-----------------------------------------------------------------------
! Copyright (c) 2000-2026 Gtool Development Group. All rights reserved.
!-----------------------------------------------------------------------
 
function dccaldatechkleapyear1( elapse_sec, date, cal ) result(result)
 
  use dc_calendar_types, only: dc_cal_date, dc_cal, &
    & cal_julian, cal_gregorian
  use dc_calendar_internal, only: default_cal, default_cal_set, default_date, &
    & dccaldate_normalize, dccaldate_ym2d
  use dc_calendar_generic, only: dccaldateinquire
  use dc_types, only: dp
  implicit none
  logical:: result
  real(dp), intent(in):: elapse_sec
  type(dc_cal_date), intent(in), optional, target:: date
  type(dc_cal), intent(in), optional, target:: cal
 
  ! 作業変数
  ! Work variables
  !
  type(dc_cal_date), pointer:: datep =>null()
  type(dc_cal), pointer:: calp =>null()
  integer:: year, month, day, hour, min
  real(dp):: sec
continue
 
  ! オブジェクトのポインタ割付
  ! Associate pointer of an object
  !
  if ( present( date ) ) then
    datep => date
  else
    datep => default_date
  end if
 
  if ( present( cal ) ) then
    calp => cal
  else
    calp => default_cal
    if ( .not. calp % initialized ) call default_cal_set
  end if
 
  ! 初期設定のチェック
  ! Check initialization
  !
  result = .false.
  if ( .not. datep % initialized ) return
  if ( .not. calp % initialized ) return
 
  ! 経過時間を与えた場合の日時を取得
  ! Inquire date and time when elapse time is given
  !
  call dccaldateinquire( year, month, day, hour, min, sec, & ! (out)
    & elapse_sec = elapse_sec, date = datep , cal = calp )   ! (in)
 
  ! 閏年の判定
  ! Judge leap year
  !
  select case( calp % cal_type )
  case( cal_julian )
    if ( mod( year, 4 ) == 0 ) then
      result = .true.
    else
      result = .false.
    end if
 
  case( cal_gregorian )
    if ( mod( year, 400 ) == 0 ) then
      result = .true.
    elseif ( mod( year, 100 ) == 0 ) then
      result = .false.
    elseif ( mod( year, 4 ) == 0 ) then
      result = .true.
    else
      result = .false.
    end if
 
  case default
    result = .false.
  end select
 
end function dccaldatechkleapyear1