dc_string::split Interface Reference

Public Member Functions
subroutine	split_cc (str, carray, sep, limit)

Detailed Description

Definition at line 170 of file dc_string.f90.

Member Function/Subroutine Documentation

split_cc()

subroutine dc_string::split::split_cc	(	character(*), intent(in)	str,
		character(*), dimension(:), pointer	carray,
		character(*), intent(in)	sep,
		integer, intent(in), optional	limit
	)

Split string by separator

Splits string str by separator sep and returns in pointer array carray. carray must be null when passed. Error is returned if already allocated. If limit is a positive number, splits into at most limit fields. If limit is negative or 0, same as omitting it. Trailing spaces of str are removed. If sep is empty string, splits by whitespace.

Parameters

[in]	str	String to split
[out]	carray	Result pointer array
[in]	sep	Separator string
[in]	limit	Maximum number of fields (optional)

Definition at line 1509 of file dc_string.f90.

    use dc_types, only: string
    implicit none
    character(*), intent(in):: str
    character(*), pointer:: carray(:) !(out)
    character(*), intent(in):: sep
    integer, intent(in), optional:: limit
    integer :: num, cur, i, limitnum
    character(STRING) :: substr
    logical :: end_flag
  continue
    if (present(limit)) then
      if (limit > 0) then
        limitnum = limit
      else
        limitnum = 0
      end if
    else
      limitnum = 0
    end if
    if (len(trim(sep)) == 0) then
      num = 1
      substr = str
      ! 重複して無駄だが carray を allocate するため, 何分割するか
      ! 調べ, num に格納する.
      do
        cur = index(trim(substr), ' ')
        if (cur == 0) exit
        num = num + 1
        substr = adjustl(substr(cur + len(sep) :len(substr)))
      end do
      if (limitnum /= 0 .and. num > limitnum) num = limitnum
      allocate(carray(num))
      substr = str
      end_flag = .false.
      do i = 1, num
        cur = index(trim(substr), ' ')
        if (cur == 0 .or. i == num) end_flag = .true.
        if (end_flag) then
          carray(i) = substr
          exit
        else
          carray(i) = substr(1:cur - 1)
        end if
        substr = adjustl(substr(cur + len(sep) :len(substr)))
      end do
    else
      num = 1
      substr = str
      ! 重複して無駄だが carray を allocate するため, 何分割するか
      ! 調べ, num に格納する.
      do
        cur = index(substr, trim(sep))
        if (cur == 0) exit
        num = num + 1
        substr = substr(cur + len(sep) :len(substr))
      end do
      if (limitnum /= 0 .and. num > limitnum) num = limitnum
      allocate(carray(num))
      substr = str
      end_flag = .false.
      do i = 1, num
        cur = index(substr, trim(sep))
        if (cur == 0 .or. i == num) end_flag = .true.
        if (end_flag) then
          carray(i) = substr
          exit
        else
          carray(i) = substr(1:cur - 1)
        end if
        substr = substr(cur + len(sep) :len(substr))
      end do
    end if
    return

References dc_types::string.

---

The documentation for this interface was generated from the following file:

• /build/gtool5-1.0.0~rc5/debian/build-parallel/src/dc_utils/dc_string.f90