gtool_historyauto_internal Module Reference

Data Types
type	gt_history_axis_data
	座標軸データ用の構造型. More...
type	gt_history_multi
	GT_HISTORY 型変数を指す構造体. More...
type	slice_info
	空間切り出し情報管理用の構造型. More...
type	axes_weight
	座標重み情報管理用の構造型. More...
type	space_avr_info
	空間平均情報管理用の構造型. More...
interface	hstvarsoutputcheck
interface	hstfilecreate
interface	averagereduce

Functions/Subroutines
subroutine, public	hstvarsoutputcheck (time, stime_index)
subroutine, public	hstfilecreate (gthist, varname, time)

Variables
integer, save, public	numdims
integer, save, public	numwgts = 0
character(*), parameter, public	wgtsuf = '_weight'
integer, save, public	numvars = 0
integer, parameter, public	max_dims_depended_by_var = 7
real(dp), parameter, public	max_remainder_range = 1.0e-3_DP
character(string), save, public	title_save
character(string), save, public	source_save
character(string), save, public	institution_save
character(string), save, public	conventions_save
character(token), save, public	gt_version_save
character(token), save, public	rank_save
integer, parameter, public	save_tstepnum = 1
real(dp), dimension(1:save_tstepnum), save, public	saved_time
integer, save, public	checked_tstepnum = 0
integer, save, public	checked_tstep_varnum = 0
integer, save, public	saved_tstep = 1
character(token), save, public	time_unit_bycreate = ''
character(string), save, public	time_unit_suffix = ''
type(gthst_nmlinfo), save, public	gthstnml
type(gt_history_axis), dimension(1:nf90_max_dims), target, save, public	gthst_axes
type(gt_history_axis_data), dimension(1:nf90_max_dims), target, save, public	data_axes
type(gt_history_axis_data), dimension(1:nf90_max_dims), target, save, public	data_axes_whole
type(gt_history_varinfo), dimension(1:nf90_max_dims), save, public	gthst_weights
type(gt_history_axis_data), dimension(1:nf90_max_dims), target, save, public	data_weights
logical, save, public	save_mpi_split = .false.
logical, save, public	save_mpi_gather = .false.
integer, parameter, public	max_vars = NF90_MAX_VARS
type(gt_history_varinfo), dimension(1:max_vars), save, public	gthst_vars
character(token), dimension(1:max_vars), save, public	varname_vars = ''
type(gt_history_multi), dimension(1:max_vars), save, public	gthst_history_vars
logical, dimension(1:max_vars), save, public	output_valid_vars = .false.
logical, dimension(1:max_vars, 1:save_tstepnum), save, public	create_timing_vars = .false.
logical, dimension(1:max_vars, 1:save_tstepnum), save, public	close_timing_vars = .false.
logical, dimension(1:max_vars, 1:save_tstepnum), save, public	renew_timing_vars = .false.
logical, dimension(1:max_vars, 1:save_tstepnum), save, public	output_timing_vars = .false.
logical, dimension(1:max_vars, 1:save_tstepnum), save, public	output_timing_avr_vars = .false.
real(dp), dimension(1:max_vars), save, public	interval_time_vars
integer, dimension(1:max_vars), save, public	interval_unitsym_vars
real(dp), dimension(1:max_vars), save, public	prev_outtime_vars
logical, dimension(1:max_vars), save, public	tavr_vars = .false.
real(dp), dimension(1:max_vars), save, public	origin_time_vars
real(dp), dimension(1:max_vars), save, public	terminus_time_vars
logical, dimension(1:max_vars), save, public	histaddvar_vars = .false.
real(dp), dimension(1:max_vars), save, public	newfile_inttime_vars
real(dp), dimension(1:max_vars), save, public	newfile_createtime_vars
logical, dimension(1:max_vars), save, public	flag_output_prev_vars = .false.
real(dp), save, public	zero_time
type(slice_info), dimension(1:max_vars), target, save, public	slice_vars
type(axes_weight), dimension(1:max_vars), target, save, public	weight_vars
type(space_avr_info), dimension(1:max_vars), target, save, public	space_avr_vars
logical, save, public	all_output_save = .false.
logical, save, public	flag_allvarfixed = .false.
type(dc_cal), save, public	cal_save
logical, save, public	initialized = .false.
character(*), parameter, public	sub_sname = "HistAuto"
character(*), parameter, public	version = '$Name: $' // '$Id: gtool_historyauto_internal.rb2f90,v 1.6 2010-07-04 22:01:51 morikawa Exp $'

Function/Subroutine Documentation

hstfilecreate()

subroutine, public gtool_historyauto_internal::hstfilecreate	(	type(gt_history), intent(inout)	gthist,
		character(*), intent(in)	varname,
		real(dp), intent(in)	time )

ファイル作成用内部サブルーチン.

Parameters

[in,out]	gthist	gtool_history モジュール用構造体.
[in]	varname	変数の名前.
[in]	time	現在時刻.

Definition at line 645 of file gtool_historyauto_internal.f90.

    use dc_trace, only: beginsub, endsub
    use dc_error, only: storeerror, dc_noerr, hst_ebadvarname, &
      & hst_ebadslice, hst_empinoaxisdata
    use dc_calendar, only: dccalconvertbyunit
    use dc_date_types, only: dc_difftime
    use dc_date, only: dcdifftimecreate, evalbyunit
    use dc_string, only: cprintf, strinclude, tochar, joinchar
    use dc_message, only: messagenotify
    use gtool_history_nmlinfo_generic, only: &
      & hstnmlinfooutputvalid, hstnmlinfoinquire, hstnmlinfoputline
    use gtool_history, only: gt_history, &
      & historycreate, historyaddvariable, historyaddattr, &
      & historyinitialized, historyput, historyputaxismpi, &
      & historyaxiscreate, historyaxisinquire, historyaxiscopy, &
      & historyvarinfoinquire, historyvarinfocreate, &
      & historyvarinfocopy, historyvarinfoinitialized, &
      & historyvarinfoclear
 
    implicit none
    type(GT_HISTORY), intent(inout):: gthist
                              ! gtool_history モジュール用構造体.
                              ! Derived type for "gtool_history" module
    character(*), intent(in):: varname
                              ! 変数の名前.
                              ! Variable name
    real(DP), intent(in):: time
                              ! 現在時刻. Current time
 
    character(TOKEN):: interval_unit
                              ! データの出力間隔の単位.
                              ! Unit for interval of history data output
    real(DP):: origin_value
                              ! データの出力開始時刻の数値.
                              ! Numerical value for start time of history data output
    character(TOKEN):: origin_unit
                              ! データの出力開始時刻の単位.
                              ! Unit for start time of history data output
 
    real(DP):: origin_sec
    integer:: newfile_intvalue
    real(DP):: newfile_intvalued
                              ! ファイル分割時間間隔.
                              ! Interval of time of separation of a file.
    character(TOKEN):: newfile_intunit
                              ! ファイル分割時間間隔の単位.
                              ! Unit of interval of time of separation of a file.
 
    character(STRING):: file, file_base, file_suffix, file_newfile_time, file_rank
                              ! 出力ファイル名.
                              ! Output file name.
    integer:: stat, i, j, k, vnum, numdims_slice, dim_size, cnt
    character(STRING):: name, units, longname, cause_c, wgt_name
    character(TOKEN):: xtype
    type(GT_HISTORY_AXIS):: gthst_axes_time
    type(GT_HISTORY_AXIS), pointer:: gthst_axes_slices(:) =>null()
    type(GT_HISTORY_AXIS_DATA), pointer:: data_axes_slices(:) =>null()
    type(GT_HISTORY_AXIS_DATA), pointer:: data_weights_slices(:) =>null()
    real(DP):: wgt_sum, wgt_sum_s
    logical:: slice_valid
    integer:: slice_start(1:numdims-1)
                              ! 空間方向の開始点.
                              ! Start points of spaces.
    integer:: slice_end(1:numdims-1)
                              ! 空間方向の終了点.
                              ! End points of spaces.
    integer:: slice_stride(1:numdims-1)
                              ! 空間方向の刻み幅.
                              ! Strides of spaces
 
    character(*), parameter:: subname = "HstFileCreate"
  continue
    call beginsub(subname, 'varname=%c', c1 = trim(varname) )
    stat = dc_noerr
    cause_c = ""
 
    ! varname から変数情報の探査
    ! Search information of a variable from "varname"
    !
    vnum = 0
    do i = 1, numvars
      call historyvarinfoinquire( &
        & varinfo = gthst_vars(i), &  ! (in)
        & name = name )               ! (out)
      if ( trim(varname) == trim(name) ) vnum = i
    end do
 
    if ( vnum == 0 ) then
      stat = hst_ebadvarname
      cause_c = varname
      goto 999
    end if
 
    ! 出力が有効かどうかを確認する
    ! Confirm whether the output is effective
    !
    if ( .not. hstnmlinfooutputvalid( gthstnml, varname ) ) then
      goto 999
    end if
 
    ! 出力間隔の単位に応じて時間座標情報の作り直し
    ! Remake time axis information correspond to units of output interval
    !
    call hstnmlinfoinquire( &
      & gthstnml = gthstnml, &                 ! (in)
      & name = varname, &                      ! (in)
      & file = file, &                         ! (out)
      & interval_unit  = interval_unit )       ! (out)
 
    call historyaxiscopy( &
      & gthst_axes_time, &     ! (out)
      & gthst_axes(numdims), & ! (in)
      & units = trim(interval_unit) // ' ' // &
      &         trim(time_unit_suffix) ) ! (in)
 
    ! 空間方向のスライスに対応して, 座標および座標重み情報の作り直し
    ! Remake axes and weights information correspond to spatial slices
    !
    call hstnmlinfoinquire( &
      & gthstnml = gthstnml, &         ! (in)
      & name = varname, &              ! (in)
      & slice_start = slice_start, &   ! (out)
      & slice_end = slice_end, &       ! (out)
      & slice_stride = slice_stride )  ! (out)
 
    ! ファイルが未作成の場合は, まずファイル作成
    ! At first, the file is created if the file is not created yet
    !
    if ( .not. historyinitialized( gthist ) ) then
 
      if (       all( slice_start  == (/ ( 1, i = 1, numdims -1 ) /) ) &
        &  .and. all( slice_end    <  (/ ( 1, i = 1, numdims -1 ) /) ) &
        &  .and. all( slice_stride == (/ ( 1, i = 1, numdims -1 ) /) )  ) then
 
        allocate( gthst_axes_slices(1:numdims) )
        gthst_axes_slices(1:numdims-1)     = gthst_axes(1:numdims-1)
        gthst_axes_slices(numdims:numdims) = gthst_axes_time
 
        data_axes_slices               => data_axes
        data_weights_slices            => data_weights
        slice_valid = .false.
 
      else
        allocate( gthst_axes_slices(1:numdims) )
        allocate( data_axes_slices(1:numdims) )
        allocate( data_weights_slices(1:numdims) )
 
        do i = 1, numdims-1
 
          ! スライス値の有効性をチェック
          ! Check validity of slices
          !
          if ( slice_start(i) < 1 ) then
            stat = hst_ebadslice
            cause_c = cprintf('slice_start=%d', &
              &         i = (/ slice_start(i) /) )
            goto 999
          end if
 
          if ( slice_stride(i) < 1 ) then
            stat = hst_ebadslice
            cause_c = cprintf('slice_stride=%d', &
              &         i = (/ slice_stride(i) /) )
            goto 999
          end if
 
          ! 再生成の必要性をチェック
          ! Check necessity of remaking
          !
          if (       ( slice_start(i)  == 1 ) &
            &  .and. ( slice_end(i)    <  1 ) &
            &  .and. ( slice_stride(i) == 1 )  ) then
 
            call historyaxiscopy( &
              & axis_dest = gthst_axes_slices(i) , &  ! (out)
              & axis_src  = gthst_axes(i) )           ! (in)
 
            data_axes_slices(i) = data_axes(i)
 
            cycle
          end if
 
          ! 座標情報の再生成
          ! Remake information of axis
          !
          call historyaxisinquire( &
            & axis = gthst_axes(i), &  ! (in)
            & name = name, &           ! (out)
            & size = dim_size, &       ! (out)
            & longname = longname, &   ! (out)
            & units = units, &         ! (out)
            & xtype = xtype )          ! (out)
 
          ! 終点のスライス値の補正 ; Correct end points of slices
          if ( slice_end(i) < 1 ) slice_end(i) = dim_size
          if ( slice_end(i) > dim_size ) then
            call messagenotify( 'W', subname, &
              & 'slice options to (%c) are undesirable ' // &
              & '(@slice_end=%d). @slice_end is corrected forcibly to (%d) ', &
              & c1 = trim(name), &
              & i = (/ slice_end(i), dim_size /) )
 
            slice_end(i) = dim_size
          end if
 
          ! スライス値の有効性をチェック ; Check validity of slices
          if ( slice_start(i) > slice_end(i) ) then
            stat = hst_ebadslice
            cause_c = cprintf('slice_start=%d, slice_end=%d', &
              &         i = (/ slice_start(i), slice_end(i) /) )
            goto 999
          end if
 
          numdims_slice = int( ( slice_end(i) - slice_start(i) + 1 ) / slice_stride(i) )
 
          ! スライス値の有効性をチェック ; Check validity of slices
          if ( numdims_slice < 1 ) then
            call messagenotify( 'W', subname, &
              & 'slice options to (%c) are invalid. ' // &
              & '(@slice_start=%d @slice_end=%d @slice_stride=%d)', &
              & c1 = trim(name), &
              & i = (/ slice_start(i), slice_end(i), slice_stride(i) /) )
            stat = hst_ebadslice
            cause_c = cprintf('slice_start=%d, slice_end=%d, slice_stride=%d', &
              &         i = (/ slice_start(i), slice_end(i), slice_stride(i) /) )
            goto 999
          end if
 
          call historyaxiscreate( &
            & axis = gthst_axes_slices(i), &  ! (out)
            & name = name, &                  ! (in)
            & size = numdims_slice, &         ! (in)
            & longname = longname, &          ! (in)
            & units = units, &                ! (in)
            & xtype = xtype )                 ! (in)
 
 
          ! 座標データの再生成
          ! Regenerate data of axis
          !
          allocate( data_axes_slices(i) % a_axis( numdims_slice ) )
          cnt = 1
          do j = slice_start(i), slice_end(i), slice_stride(i)
            data_axes_slices(i) % a_axis( cnt ) = data_axes(i) % a_axis( j )
            cnt = cnt + 1
          end do
 
          ! 座標重みデータの再生成
          ! Remake information of axis data
          !
          do j = 1, numwgts
            call historyvarinfoinquire( &
              & varinfo = gthst_weights(j), & ! (in)
              & name = wgt_name )             ! (out) optional
 
            if ( trim(name) // wgtsuf == trim(wgt_name) ) then
 
              ! 座標重みの計算は結構いい加減...
              ! Calculation about axis weight is irresponsible...
              !
              wgt_sum = sum( data_weights(j) % a_axis )
 
              allocate( data_weights_slices(j) % a_axis( numdims_slice ) )
              cnt = 1
              do k = slice_start(i), slice_end(i), slice_stride(i)
                data_weights_slices(j) % a_axis( cnt ) = data_weights(j) % a_axis( k )
                cnt = cnt + 1
              end do
 
              wgt_sum_s = sum( data_weights_slices(j) % a_axis )
              data_weights_slices(j) % a_axis = data_weights_slices(j) % a_axis * ( wgt_sum / wgt_sum_s )
 
            end if
 
          end do
 
        end do
 
        ! 空間切り出しされていない座標に関する座標重みデータを作成
        ! Make data of axis weight not sliced
        !
        do i = 1, numwgts
          if ( .not. associated( data_weights_slices(i) % a_axis ) ) then
            allocate( data_weights_slices(i) % a_axis( size(data_weights(i) % a_axis ) ) )
            data_weights_slices(i) % a_axis = data_weights(i) % a_axis
          end if
        end do
 
        ! 時刻次元のコピー
        ! Copy time dimension
        !
        gthst_axes_slices(numdims) = gthst_axes_time
 
        slice_valid = .true.
      end if
 
      ! HistoryCreate のための設定値の取得
      ! Get the settings for "HistoryCreate"
      !
      call hstnmlinfoinquire( &
        & gthstnml = gthstnml, &                 ! (in)
        & name = varname, &                      ! (in)
        & file = file, &                         ! (out)
        & origin_value   = origin_value, &       ! (out)
        & origin_unit    = origin_unit, &        ! (out)
        & interval_unit  = interval_unit, &      ! (out)
        & newfile_intvalue = newfile_intvalue, & ! (out)
        & newfile_intunit = newfile_intunit )    ! (out)
 
      ! データ出力時刻の設定
      ! Configure data output time
      !
      origin_sec = &
        & dccalconvertbyunit( &
        &   real( origin_value, dp ), origin_unit, 'sec', cal_save )
 
!!$      ! dc_date モジュール使用時
!!$      !
!!$      call DCDiffTimeCreate( &
!!$        & origin_sec, &           ! (out)
!!$        & origin_value, origin_unit )  ! (in)
 
      if ( newfile_intvalue < 1 ) then
 
        origin_value = dccalconvertbyunit( &
          & origin_sec, 'sec', interval_unit, cal_save )
 
!        origin_value = EvalbyUnit( origin_sec, interval_unit )
      else
 
        origin_value = &
          & dccalconvertbyunit( time, 'sec', interval_unit, cal_save )
 
!        origin_value = EvalbyUnit( time, interval_unit )
      end if
 
      ! ファイル名の設定
      ! Configure file name
      !
      if ( len_trim( file ) - index(file, '.nc', .true.) == 2 ) then
        file_base = file(1:len_trim( file ) - 3)
        file_suffix = '.nc'
      else
        file_base = file
        file_suffix = ''
      end if
      if ( trim(rank_save) == '' ) then
        file_rank = ''
      else
        file_rank = '_rank' // trim( adjustl(rank_save) )
      end if
      if ( newfile_intvalue > 0 ) then
        newfile_intvalued = &
          & dccalconvertbyunit( time, 'sec', newfile_intunit, cal_save )
 
        file_newfile_time = &
          & cprintf( '_time%08d', i = (/ int( newfile_intvalued ) /) )
!          &   i = (/ int( EvalbyUnit( time, newfile_intunit ) ) /) )
      else
        file_newfile_time = ''
      end if
 
      file = trim(file_base) // trim(file_rank) // trim(file_newfile_time) // trim(file_suffix)
 
      ! HistoryCreate によるファイル作成
      ! Files are created by "HistoryCreate"
      !
      call historycreate( &
        & history = gthist, &                                     ! (inout)
        & file = file, title = title_save, &                      ! (in)
        & source = source_save, institution = institution_save, & ! (in)
        & axes = gthst_axes_slices(1:numdims), &                  ! (in)
        & origind = origin_value, &                               ! (in)
        & conventions = conventions_save, &                       ! (in)
        & gt_version = gt_version_save, &                         ! (in)
        & flag_mpi_split = save_mpi_split, &                      ! (in)
        & flag_mpi_gather = save_mpi_gather )                     ! (in)
 
      ! 座標データを出力
      ! Output axes data
      !
      do i = 1, numdims - 1
        call historyaxisinquire( &
          & axis = gthst_axes_slices(i), &  ! (in)
          & name = name )                   ! (out)
        call historyput( &
          & history = gthist, &                    ! (inout) optional
          & varname = name, &                      ! (in)
          & array = data_axes_slices(i) % a_axis ) ! (in)
      end do
 
      ! MPI 用に領域全体の座標データを出力
      ! Output axes data in whole area for MPI
      !
      if ( save_mpi_gather ) then
        do i = 1, numdims - 1
          call historyaxisinquire( &
            & axis = gthst_axes_slices(i), &  ! (in)
            & name = name )                   ! (out)
 
          if ( .not. associated( data_axes_whole(i) % a_axis ) ) then
            call messagenotify('W', subname, &
              & 'data of axis (%c) in whole area is lack. ' // &
              & 'Specify the data by "HistoryAutoPutAxisMPI" explicitly.', &
              & c1 = trim(name) )
            stat = hst_empinoaxisdata
            cause_c = name
          end if
 
          call historyputaxismpi( &
            & history = gthist, &                   ! (inout) optional
            & varname = name, &                     ! (in)
            & array = data_axes_whole(i) % a_axis ) ! (in)
        end do
      end if
 
      ! 割付解除
      ! Deallocation
      !
      if ( slice_valid ) then
        deallocate( gthst_axes_slices )
        deallocate( data_axes_slices )
      else
        deallocate( gthst_axes_slices )
        nullify( data_axes_slices )
      end if
 
      ! 座標重みデータを追加
      ! Add axes weights data
      !
      do i = 1, numwgts
        call historyaddvariable( &
          & history = gthist, &           ! (inout)
          & varinfo = gthst_weights(i) )  ! (in)
        call historyvarinfoinquire( &
          & varinfo = gthst_weights(i), &  ! (in)
          & name = name )                  ! (out)
        call historyput( &
          & history = gthist, &                       ! (inout) optional
          & varname = name, &                         ! (in)
          & array = data_weights_slices(i) % a_axis ) ! (in)
      end do
 
      if ( slice_valid ) then
        deallocate( data_weights_slices )
      else
        nullify( data_weights_slices )
      end if
 
    ! ファイル作成おしまい; Creation of file is finished
    end if
 
 
    ! 変数情報を追加
    ! Add information of variables
    !
    call historyaddvariable( &
      & varinfo = gthst_vars(vnum), &  ! (in)
      & history = gthist )             ! (inout) optional
 
999 continue
    call storeerror(stat, subname, cause_c = cause_c)
    call endsub(subname)

hstvarsoutputcheck()

subroutine, public gtool_historyauto_internal::hstvarsoutputcheck	(	real(dp), intent(in)	time,
		integer, intent(out)	stime_index )

各変数の出力タイミングのチェック.

与えられた時刻 time が各変数にとって出力のタイミングかどうかを 調査して output_timing_vars, output_timing_avr_vars, create_timing_vars, close_timing_vars, renew_timing_vars へ反映し, time に対応する saved_time の配列添字を stime_index へ返します.

また, ファイルのオープンクローズのタイミングであれば, それらもこのサブルーチン内で行います.

Parameters

[in]	time	現在時刻.
[out]	stime_index	saved_time 配列の添字.

Definition at line 449 of file gtool_historyauto_internal.f90.

    use dc_trace, only: beginsub, endsub, dbgmessage
    use dc_error, only: storeerror, dc_noerr
    use gtool_history, only: historyinitialized, historyclose
    use dc_date_types, only: dc_difftime
    use dc_date, only: operator(==), operator(>), operator(<), &
      & operator(>=), operator(<=), operator(-), dcdifftimeputline, &
      & evalsec
    implicit none
    real(DP), intent(in):: time
                              ! 現在時刻. Current time
    integer, intent(out):: stime_index
 
    integer:: tstep
    integer:: stat, i, startnum, endnum
    character(STRING):: cause_c
    character(*), parameter:: subname = "HstVarsOutputCheck"
    real(DP), parameter:: time_eps = epsilon(1.0_dp)
  continue
    call beginsub(subname)
    stat = dc_noerr
    cause_c = ""
 
    ! 与えられた時刻がチェック済みかどうかを調べる
    ! Examine whether given time is already checked or not
    !
    timestepsearch: do
      do i = saved_tstep, checked_tstepnum
        if ( abs(saved_time(i) - time) <= &
          & time_eps * max(1.0_dp, abs(time), abs(saved_time(i))) ) then
          tstep = i
          exit timestepsearch
        end if
      end do
      do i = 1, saved_tstep - 1
        if ( abs(saved_time(i) - time) <= &
          & time_eps * max(1.0_dp, abs(time), abs(saved_time(i))) ) then
          tstep = i
          exit timestepsearch
        end if
      end do
 
      tstep = 0
      exit timestepsearch
    end do timestepsearch
 
    saved_tstep = tstep
 
    if ( saved_tstep /= 0 .and. checked_tstep_varnum == numvars ) then
      ! * output_timing_vars(:,saved_tstep) を使う.
      ! * saved_tstep を stime_index として返す.
 
      stime_index = saved_tstep
      call dbgmessage( 'saved_tstep=<%d> is already checked.', &
        & i =(/ saved_tstep /) )
      goto 999
    end if
 
    ! チェックする時間ステップと, 変数 ID の設定
    ! Configure checked time step, and variable ID
    !
    if ( saved_tstep /= 0 ) then
      startnum = checked_tstep_varnum + 1
      endnum   = numvars
 
      stime_index = saved_tstep
    else
      startnum = 1
      endnum   = numvars
 
      if ( save_tstepnum < 2 ) then
        checked_tstepnum = 1
        saved_time(checked_tstepnum) = time
 
        saved_tstep = checked_tstepnum
        stime_index = saved_tstep
 
      elseif ( .not. checked_tstepnum < save_tstepnum ) then
        create_timing_vars(:,1:checked_tstepnum-1) = create_timing_vars(:,2:checked_tstepnum)
        close_timing_vars(:,1:checked_tstepnum-1) = close_timing_vars(:,2:checked_tstepnum)
        renew_timing_vars(:,1:checked_tstepnum-1) = renew_timing_vars(:,2:checked_tstepnum)
        output_timing_vars(:,1:checked_tstepnum-1) = output_timing_vars(:,2:checked_tstepnum)
        output_timing_avr_vars(:,1:checked_tstepnum-1) = output_timing_avr_vars(:,2:checked_tstepnum)
 
        saved_time(1:checked_tstepnum-1) = saved_time(2:checked_tstepnum)
        saved_time(checked_tstepnum) = time
 
        saved_tstep = checked_tstepnum
        stime_index = saved_tstep
 
      else
        checked_tstepnum = checked_tstepnum + 1
        saved_time(checked_tstepnum) = time
 
        saved_tstep = checked_tstepnum
        stime_index = saved_tstep
      end if
    end if
 
    call dbgmessage( 'numvar=<%d:%d> in saved_tstep=<%d> will be checked from now.', &
      & i =(/ startnum, endnum, saved_tstep /) )
 
 
    ! それぞれのタイミングをチェックして各変数に格納
    !
    ! * ファイルオープン:      create_timing_vars
    ! * ファイルクローズ:      close_timing_vars
    ! * ファイルクローズ/作成: renew_timing_vars
    ! * データ出力:            output_timing_vars
    ! * データ平均化:          output_avr_timing_vars
 
    create_timing_vars(startnum:endnum, checked_tstepnum:checked_tstepnum) = .false.
    close_timing_vars(startnum:endnum, checked_tstepnum:checked_tstepnum) = .false.
    renew_timing_vars(startnum:endnum, checked_tstepnum:checked_tstepnum) = .false.
    output_timing_vars(startnum:endnum, checked_tstepnum:checked_tstepnum) = .false.
    output_timing_avr_vars(startnum:endnum, checked_tstepnum:checked_tstepnum) = .false.
 
    do i = startnum, endnum
 
      if ( .not. output_valid_vars(i) ) cycle
 
      if ( origin_time_vars(i) > time ) cycle
 
      if (             origin_time_vars(i) <= time &
        &  .and.       (      terminus_time_vars(i) < zero_time &
        &                .or. terminus_time_vars(i) >= time      ) &
        &  .and. .not. histaddvar_vars(i)            ) then
 
        create_timing_vars(i,checked_tstepnum) = .true.
 
        if ( newfile_inttime_vars(i) > zero_time ) then
          newfile_createtime_vars(i) = time
        end if
 
        output_timing_vars(i,checked_tstepnum) = .true.
        output_timing_avr_vars(i,checked_tstepnum) = tavr_vars(i)
        cycle
      end if
 
      if ( terminus_time_vars(i) > zero_time .and. terminus_time_vars(i) < time ) then
        close_timing_vars(i,checked_tstepnum) = .true.
        output_timing_vars(i,checked_tstepnum) = .false.
        output_timing_avr_vars(i,checked_tstepnum) = .false.
        cycle
      end if
 
      ! * newfile_inttime_vars だけでは, ぴったり一致しないとうまく行かない.
      !   * そこで...
      !     * 前回に出力した時刻を記憶しておく.
      !     * 前回の時刻と今回の時刻の差が newfile_inttime_vars
      !       よりも大きい場合には現ファイルを閉じ, 新ファイルを作成する.
 
      if ( newfile_inttime_vars(i) > zero_time ) then
        if ( time - newfile_createtime_vars(i) >= newfile_inttime_vars(i) ) then
          renew_timing_vars(i,checked_tstepnum) = .true.
 
          output_timing_vars(i,checked_tstepnum) = .true.
          output_timing_avr_vars(i,checked_tstepnum) = tavr_vars(i)
 
          cycle
        end if
      end if
 
      if ( time - prev_outtime_vars(i) >= interval_time_vars(i) ) then
        output_timing_vars(i,checked_tstepnum) = .true.
        output_timing_avr_vars(i,checked_tstepnum) = tavr_vars(i)
        cycle
      end if
 
      output_timing_vars(i,checked_tstepnum) = .false.
      output_timing_avr_vars(i,checked_tstepnum) = tavr_vars(i)
 
    end do
 
    checked_tstep_varnum = numvars
 
999 continue
    call storeerror(stat, subname, cause_c = cause_c)
    call endsub(subname)

Variable Documentation

all_output_save

logical, save, public gtool_historyauto_internal::all_output_save = .false.

Definition at line 303 of file gtool_historyauto_internal.f90.

  logical, save, public:: all_output_save = .false.

cal_save

type(dc_cal), save, public gtool_historyauto_internal::cal_save

Definition at line 318 of file gtool_historyauto_internal.f90.

  type(DC_CAL), save, public:: cal_save

checked_tstep_varnum

integer, save, public gtool_historyauto_internal::checked_tstep_varnum = 0

Definition at line 135 of file gtool_historyauto_internal.f90.

  integer, save, public:: checked_tstep_varnum = 0

checked_tstepnum

integer, save, public gtool_historyauto_internal::checked_tstepnum = 0

Definition at line 132 of file gtool_historyauto_internal.f90.

  integer, save, public:: checked_tstepnum = 0

close_timing_vars

logical, dimension(1:max_vars, 1:save_tstepnum), save, public gtool_historyauto_internal::close_timing_vars = .false.

Definition at line 198 of file gtool_historyauto_internal.f90.

  logical, save, public:: close_timing_vars(1:MAX_VARS, 1:save_tstepnum) = .false.

conventions_save

character(string), save, public gtool_historyauto_internal::conventions_save

Definition at line 120 of file gtool_historyauto_internal.f90.

  character(STRING), save, public:: conventions_save

create_timing_vars

logical, dimension(1:max_vars, 1:save_tstepnum), save, public gtool_historyauto_internal::create_timing_vars = .false.

Definition at line 195 of file gtool_historyauto_internal.f90.

  logical, save, public:: create_timing_vars(1:MAX_VARS, 1:save_tstepnum) = .false.

data_axes

type(gt_history_axis_data), dimension(1:nf90_max_dims), target, save, public gtool_historyauto_internal::data_axes

Definition at line 166 of file gtool_historyauto_internal.f90.

  type(GT_HISTORY_AXIS_DATA), save, target, public:: data_axes(1:NF90_MAX_DIMS)

data_axes_whole

type(gt_history_axis_data), dimension(1:nf90_max_dims), target, save, public gtool_historyauto_internal::data_axes_whole

Definition at line 167 of file gtool_historyauto_internal.f90.

  type(GT_HISTORY_AXIS_DATA), save, target, public:: data_axes_whole(1:NF90_MAX_DIMS)

data_weights

type(gt_history_axis_data), dimension(1:nf90_max_dims), target, save, public gtool_historyauto_internal::data_weights

Definition at line 169 of file gtool_historyauto_internal.f90.

  type(GT_HISTORY_AXIS_DATA), save, target, public:: data_weights(1:NF90_MAX_DIMS)

flag_allvarfixed

logical, save, public gtool_historyauto_internal::flag_allvarfixed = .false.

Definition at line 313 of file gtool_historyauto_internal.f90.

  logical, save, public:: flag_allvarfixed = .false.

flag_output_prev_vars

logical, dimension(1:max_vars), save, public gtool_historyauto_internal::flag_output_prev_vars = .false.

Definition at line 238 of file gtool_historyauto_internal.f90.

  logical, save, public:: flag_output_prev_vars(1:MAX_VARS) = .false.

gt_version_save

character(token), save, public gtool_historyauto_internal::gt_version_save

Definition at line 121 of file gtool_historyauto_internal.f90.

  character(TOKEN),  save, public:: gt_version_save

gthst_axes

type(gt_history_axis), dimension(1:nf90_max_dims), target, save, public gtool_historyauto_internal::gthst_axes

Definition at line 165 of file gtool_historyauto_internal.f90.

  type(GT_HISTORY_AXIS), save, target, public:: gthst_axes(1:NF90_MAX_DIMS)

gthst_history_vars

type(gt_history_multi), dimension(1:max_vars), save, public gtool_historyauto_internal::gthst_history_vars

Definition at line 191 of file gtool_historyauto_internal.f90.

  type(GT_HISTORY_MULTI), save, public:: gthst_history_vars(1:MAX_VARS)

gthst_vars

type(gt_history_varinfo), dimension(1:max_vars), save, public gtool_historyauto_internal::gthst_vars

Definition at line 189 of file gtool_historyauto_internal.f90.

  type(GT_HISTORY_VARINFO), save, public:: gthst_vars(1:MAX_VARS)

gthst_weights

type(gt_history_varinfo), dimension(1:nf90_max_dims), save, public gtool_historyauto_internal::gthst_weights

Definition at line 168 of file gtool_historyauto_internal.f90.

  type(GT_HISTORY_VARINFO), save, public:: gthst_weights(1:NF90_MAX_DIMS)

gthstnml

type(gthst_nmlinfo), save, public gtool_historyauto_internal::gthstnml

Definition at line 154 of file gtool_historyauto_internal.f90.

  type(GTHST_NMLINFO), save, public:: gthstnml

histaddvar_vars

logical, dimension(1:max_vars), save, public gtool_historyauto_internal::histaddvar_vars = .false.

Definition at line 229 of file gtool_historyauto_internal.f90.

  logical, save, public:: histaddvar_vars(1:MAX_VARS) = .false.

initialized

logical, save, public gtool_historyauto_internal::initialized = .false.

Definition at line 328 of file gtool_historyauto_internal.f90.

  logical, save, public:: initialized = .false.

institution_save

character(string), save, public gtool_historyauto_internal::institution_save

Definition at line 119 of file gtool_historyauto_internal.f90.

  character(STRING), save, public:: institution_save

interval_time_vars

real(dp), dimension(1:max_vars), save, public gtool_historyauto_internal::interval_time_vars

Definition at line 211 of file gtool_historyauto_internal.f90.

  real(DP), save, public:: interval_time_vars(1:MAX_VARS)

interval_unitsym_vars

integer, dimension(1:max_vars), save, public gtool_historyauto_internal::interval_unitsym_vars

Definition at line 214 of file gtool_historyauto_internal.f90.

  integer, save, public:: interval_unitsym_vars(1:MAX_VARS)

max_dims_depended_by_var

integer, parameter, public gtool_historyauto_internal::max_dims_depended_by_var = 7

Definition at line 107 of file gtool_historyauto_internal.f90.

  integer, parameter, public:: MAX_DIMS_DEPENDED_BY_VAR = 7

max_remainder_range

real(dp), parameter, public gtool_historyauto_internal::max_remainder_range = 1.0e-3_DP

Definition at line 112 of file gtool_historyauto_internal.f90.

  real(DP), parameter, public:: max_remainder_range = 1.0e-3_dp

max_vars

integer, parameter, public gtool_historyauto_internal::max_vars = NF90_MAX_VARS

Definition at line 186 of file gtool_historyauto_internal.f90.

  integer, parameter, public:: MAX_VARS = nf90_max_vars

newfile_createtime_vars

real(dp), dimension(1:max_vars), save, public gtool_historyauto_internal::newfile_createtime_vars

Definition at line 235 of file gtool_historyauto_internal.f90.

  real(DP), save, public:: newfile_createtime_vars(1:MAX_VARS)

newfile_inttime_vars

real(dp), dimension(1:max_vars), save, public gtool_historyauto_internal::newfile_inttime_vars

Definition at line 232 of file gtool_historyauto_internal.f90.

  real(DP), save, public:: newfile_inttime_vars(1:MAX_VARS)

numdims

integer, save, public gtool_historyauto_internal::numdims

Definition at line 87 of file gtool_historyauto_internal.f90.

  integer, save, public:: numdims

numvars

integer, save, public gtool_historyauto_internal::numvars = 0

Definition at line 102 of file gtool_historyauto_internal.f90.

  integer, save, public:: numvars = 0

numwgts

integer, save, public gtool_historyauto_internal::numwgts = 0

Definition at line 92 of file gtool_historyauto_internal.f90.

  integer, save, public:: numwgts = 0

origin_time_vars

real(dp), dimension(1:max_vars), save, public gtool_historyauto_internal::origin_time_vars

Definition at line 223 of file gtool_historyauto_internal.f90.

  real(DP), save, public:: origin_time_vars(1:MAX_VARS)

output_timing_avr_vars

logical, dimension(1:max_vars, 1:save_tstepnum), save, public gtool_historyauto_internal::output_timing_avr_vars = .false.

Definition at line 208 of file gtool_historyauto_internal.f90.

  logical, save, public:: output_timing_avr_vars(1:MAX_VARS, 1:save_tstepnum) = .false.

output_timing_vars

logical, dimension(1:max_vars, 1:save_tstepnum), save, public gtool_historyauto_internal::output_timing_vars = .false.

Definition at line 205 of file gtool_historyauto_internal.f90.

  logical, save, public:: output_timing_vars(1:MAX_VARS, 1:save_tstepnum) = .false.

output_valid_vars

logical, dimension(1:max_vars), save, public gtool_historyauto_internal::output_valid_vars = .false.

Definition at line 192 of file gtool_historyauto_internal.f90.

  logical, save, public:: output_valid_vars(1:MAX_VARS) = .false.

prev_outtime_vars

real(dp), dimension(1:max_vars), save, public gtool_historyauto_internal::prev_outtime_vars

Definition at line 217 of file gtool_historyauto_internal.f90.

  real(DP), save, public:: prev_outtime_vars(1:MAX_VARS)

rank_save

character(token), save, public gtool_historyauto_internal::rank_save

Definition at line 122 of file gtool_historyauto_internal.f90.

  character(TOKEN),  save, public:: rank_save

renew_timing_vars

logical, dimension(1:max_vars, 1:save_tstepnum), save, public gtool_historyauto_internal::renew_timing_vars = .false.

Definition at line 201 of file gtool_historyauto_internal.f90.

  logical, save, public:: renew_timing_vars(1:MAX_VARS, 1:save_tstepnum) = .false.

save_mpi_gather

logical, save, public gtool_historyauto_internal::save_mpi_gather = .false.

Definition at line 175 of file gtool_historyauto_internal.f90.

  logical, save, public:: save_mpi_gather = .false.

save_mpi_split

logical, save, public gtool_historyauto_internal::save_mpi_split = .false.

Definition at line 174 of file gtool_historyauto_internal.f90.

  logical, save, public:: save_mpi_split  = .false.

save_tstepnum

integer, parameter, public gtool_historyauto_internal::save_tstepnum = 1

Definition at line 128 of file gtool_historyauto_internal.f90.

  integer, parameter, public:: save_tstepnum = 1

saved_time

real(dp), dimension(1:save_tstepnum), save, public gtool_historyauto_internal::saved_time

Definition at line 131 of file gtool_historyauto_internal.f90.

  real(DP), save, public:: saved_time(1:save_tstepnum)

saved_tstep

integer, save, public gtool_historyauto_internal::saved_tstep = 1

Definition at line 138 of file gtool_historyauto_internal.f90.

  integer, save, public:: saved_tstep = 1

slice_vars

type(slice_info), dimension(1:max_vars), target, save, public gtool_historyauto_internal::slice_vars

Definition at line 261 of file gtool_historyauto_internal.f90.

  type(SLICE_INFO), save, target, public:: slice_vars(1:MAX_VARS)

source_save

character(string), save, public gtool_historyauto_internal::source_save

Definition at line 118 of file gtool_historyauto_internal.f90.

  character(STRING), save, public:: source_save

space_avr_vars

type(space_avr_info), dimension(1:max_vars), target, save, public gtool_historyauto_internal::space_avr_vars

Definition at line 298 of file gtool_historyauto_internal.f90.

  type(SPACE_AVR_INFO), save, target, public:: space_avr_vars(1:MAX_VARS)

sub_sname

character(*), parameter, public gtool_historyauto_internal::sub_sname = "HistAuto"

Definition at line 330 of file gtool_historyauto_internal.f90.

  character(*), parameter, public:: sub_sname = "HistAuto"

tavr_vars

logical, dimension(1:max_vars), save, public gtool_historyauto_internal::tavr_vars = .false.

Definition at line 220 of file gtool_historyauto_internal.f90.

  logical, save, public:: tavr_vars(1:MAX_VARS) = .false.

terminus_time_vars

real(dp), dimension(1:max_vars), save, public gtool_historyauto_internal::terminus_time_vars

Definition at line 226 of file gtool_historyauto_internal.f90.

  real(DP), save, public:: terminus_time_vars(1:MAX_VARS)

time_unit_bycreate

character(token), save, public gtool_historyauto_internal::time_unit_bycreate = ''

Definition at line 148 of file gtool_historyauto_internal.f90.

  character(TOKEN), save, public:: time_unit_bycreate = ''

time_unit_suffix

character(string), save, public gtool_historyauto_internal::time_unit_suffix = ''

Definition at line 149 of file gtool_historyauto_internal.f90.

  character(STRING), save, public:: time_unit_suffix = ''

title_save

character(string), save, public gtool_historyauto_internal::title_save

Definition at line 117 of file gtool_historyauto_internal.f90.

  character(STRING), save, public:: title_save

varname_vars

character(token), dimension(1:max_vars), save, public gtool_historyauto_internal::varname_vars = ''

Definition at line 190 of file gtool_historyauto_internal.f90.

  character(TOKEN), save, public:: varname_vars(1:MAX_VARS) = ''

version

character(*), parameter, public gtool_historyauto_internal::version = '$Name: $' // '$Id: gtool_historyauto_internal.rb2f90,v 1.6 2010-07-04 22:01:51 morikawa Exp $'

Definition at line 332 of file gtool_historyauto_internal.f90.

  character(*), parameter, public:: version = &
    & '$Name:  $' // &
    & '$Id: gtool_historyauto_internal.rb2f90,v 1.6 2010-07-04 22:01:51 morikawa Exp $'

weight_vars

type(axes_weight), dimension(1:max_vars), target, save, public gtool_historyauto_internal::weight_vars

Definition at line 285 of file gtool_historyauto_internal.f90.

  type(AXES_WEIGHT), save, target, public:: weight_vars(1:MAX_VARS)

wgtsuf

character(*), parameter, public gtool_historyauto_internal::wgtsuf = '_weight'

Definition at line 97 of file gtool_historyauto_internal.f90.

  character(*), parameter, public:: wgtsuf = '_weight'

zero_time

real(dp), save, public gtool_historyauto_internal::zero_time

Definition at line 241 of file gtool_historyauto_internal.f90.

  real(DP), save, public:: zero_time