hstnmlinfooutputstepdisable.f90

Go to the documentation of this file.

!> @file hstnmlinfooutputstepdisable.f90
!>
!> @author Yasuhiro MORIKAWA
!> @copyright Copyright (C) GFD Dennou Club, 2007-2026. All rights reserved. <br/>
!>            License is BSD-2-Clause. See [COPYRIGHT](@ref COPYRIGHT) in detail
!>
!> @en
!> @brief Invalidate HstNmlInfoOutputStep
!> @enden
!>
!> @ja
!> @brief HstNmlInfoOutputStep の無効化
!> @endja
 
  !> @en
  !> @brief Configure that HstNmlInfoOutputStep returns .false. already
  !>
  !> After this subroutine is used,
  !> HstNmlInfoOutputStep returns .false. already
  !> corresponding to the @p name.
  !>
  !> This subroutine is expected to use when
  !> interval of data output is changed from initialization of output,
  !> and time is specified explicitly whenever data is output.
  !>
  !> Use after state is changed from define mode to
  !> output mode by HstNmlInfoEndDefine.
  !> If this subroutine is used before
  !> HstNmlInfoEndDefine is used, error is occurred.
  !>
  !> When data corresponding to @p name is not found, error is occurred.
  !> When @p name is blank, error is occurred too.
  !>
  !> If @p gthstnml is not initialized by HstNmlInfoCreate yet,
  !> error is occurred.
  !> @enden
  !>
  !> @ja
  !> @brief HstNmlInfoOutputStep が常に .false. を返すよう設定する
  !>
  !> このサブルーチンを使用すると, @p name に関して,
  !> 以降は HstNmlInfoOutputStep が常に .false. を返すようになります.
  !>
  !> データ出力間隔を出力の初期設定から変更し,
  !> データを出力するたびに時刻を明示的に指定する場合に利用することを
  !> 想定しています.
  !>
  !> HstNmlInfoEndDefine で定義モードから出力モードに
  !> 移行した後に呼び出してください.
  !> HstNmlInfoEndDefine を呼ぶ前にこのサブルーチンを使用すると,
  !> プログラムはエラーを発生させます.
  !>
  !> @p name に関する情報が見当たらない場合,
  !> プログラムはエラーを発生させます.
  !> @p name が空文字の場合にも,
  !> プログラムはエラーを発生させます.
  !>
  !> なお, 与えられた @p gthstnml が HstNmlInfoCreate によって初期設定
  !> されていない場合にも, プログラムはエラーを発生させます.
  !> @endja
  !>
  !> @param[in] gthstnml gtool_history_nmlinfo_types::GTHST_NMLINFO 型変数
  !> @param[in] name 変数名. 先頭の空白は無視されます.
  !>                 Variable identifier. Blanks at the head of the name are ignored.
  !> @param[out] err 例外処理用フラグ. Exception handling flag.
  subroutine hstnmlinfooutputstepdisable( gthstnml, &
    & name, err )
    use gtool_history_nmlinfo_types, only: gthst_nmlinfo, gthst_nmlinfo_entry
    use gtool_history_nmlinfo_internal, only: listsearch
    use dc_trace, only: beginsub, endsub
    use dc_types, only: string
    use dc_error, only: storeerror, dc_noerr, dc_enotinit, dc_enoentry, hst_ebadname, hst_eindefine
    implicit none
    type(gthst_nmlinfo), intent(in):: gthstnml
    character(*), intent(in):: name
                              ! 変数名. 
                              ! 先頭の空白は無視されます. 
                              ! 
                              ! Variable identifier. 
                              ! Blanks at the head of the name are ignored. 
    logical, intent(out), optional:: err
                              ! 例外処理用フラグ. 
                              ! デフォルトでは, この手続き内でエラーが
                              ! 生じた場合, プログラムは強制終了します. 
                              ! 引数 *err* が与えられる場合, 
                              ! プログラムは強制終了せず, 代わりに
                              ! *err* に .true. が代入されます. 
                              !
                              ! Exception handling flag. 
                              ! By default, when error occur in 
                              ! this procedure, the program aborts. 
                              ! If this *err* argument is given, 
                              ! .true. is substituted to *err* and 
                              ! the program does not abort. 
 
    !-----------------------------------
    !  作業変数
    !  Work variables
    type(gthst_nmlinfo_entry), pointer:: hptr =>null()
    integer:: stat
    character(STRING):: cause_c
    character(*), parameter:: subname = 'HstNmlInfoOutputStepDisable'
  continue
    call beginsub( subname )
    stat = dc_noerr
    cause_c = ''
 
    !-----------------------------------------------------------------
    !  初期設定のチェック
    !  Check initialization
    !-----------------------------------------------------------------
    if ( .not. gthstnml % initialized ) then
      stat = dc_enotinit
      cause_c = 'GTHST_NMLINFO'
      goto 999
    end if
 
    if ( trim( name ) == '' ) then
      stat = hst_ebadname
      cause_c = ''
      goto 999
    end if
 
    if ( gthstnml % define_mode ) then
      stat = hst_eindefine
      cause_c = 'OutputStepDisable'
      goto 999
    end if
 
    !-----------------------------------------------------------------
    !  *gthstnml* 内から, *name* に関する history を探査.
    !  Search "history" correspond to *name* in *gthstnml*
    !-----------------------------------------------------------------
    hptr => gthstnml % gthstnml_list
    call listsearch( gthstnml_list = hptr, & ! (inout)
      &              name = name )           ! (in)
 
    if ( .not. associated( hptr ) ) then
      stat = dc_enoentry
      cause_c = adjustl( name )
      goto 999
    end if
 
    hptr % output_step_disable = .true.
 
    nullify( hptr )
 
    !-----------------------------------------------------------------
    !  終了処理, 例外処理
    !  Termination and Exception handling
    !-----------------------------------------------------------------
999 continue
    call storeerror( stat, subname, err, cause_c )
    call endsub( subname )
  end subroutine hstnmlinfooutputstepdisable