historyvarinfocreate.f90

Go to the documentation of this file.

!> @file historyvarinfocreate.f90
!>
!> @author Yasuhiro MORIKAWA
!> @copyright Copyright (C) GFD Dennou Club, 2000-2026. All rights reserved. <br/>
!>            License is BSD-2-Clause. See [COPYRIGHT](@ref COPYRIGHT) in detail
!>
!> @en
!> @brief Constructor of GT_HISTORY_VARINFO
!> @enden
!>
!> @ja
!> @brief GT_HISTORY_VARINFO 変数の作成
!> @endja
 
!>
!> @en
!> @brief Create a GT_HISTORY_VARINFO variable
!>
!> Creates a GT_HISTORY_VARINFO variable.
!> After setting with this subroutine,
!> pass it to the varinfo argument of HistoryAddVariable.
!> To add attributes, use HistoryVarinfoAddAttr.
!> @param[inout] varinfo       Variable information
!> @param[in]    name          Variable name
!> @param[in]    dims          Dependent dimensions
!> @param[in]    longname      Descriptive name
!> @param[in]    units         Units
!> @param[in]    xtype         Variable type (optional)
!> @param[in]    time_average  Time average flag (optional)
!> @param[in]    average       Time average flag (optional, backward compatibility)
!> @param[out]   err           Error flag (optional)
!> @enden
!>
!> @ja
!> @brief GT_HISTORY_VARINFO 型変数作成
!>
!> GT_HISTORY_VARINFO 型変数を作成します。
!> このサブルーチンによる設定の後、
!> HistoryAddVariable の varinfo に与えます。
!> さらに属性を付加する場合には HistoryVarinfoAddAttr
!> を用いてください。
!> @param[inout] varinfo       変数情報
!> @param[in]    name          変数名
!> @param[in]    dims          依存する次元
!> @param[in]    longname      変数の記述的名称
!> @param[in]    units         変数の単位
!> @param[in]    xtype         変数の型 (省略可能)
!> @param[in]    time_average  時間平均 (省略可能)
!> @param[in]    average       時間平均 (省略可能, 後方互換用)
!> @param[out]   err           エラーフラグ (省略可能)
!> @endja
!>
  subroutine historyvarinfocreate1( varinfo, & ! (out)
    & name, dims, longname, units, xtype, &    ! (in)
    & time_average, average, err &            ! (in) optional
    & )
    !
    use gtool_history_types, only: gt_history_varinfo
    use dc_types, only: string, token
    use dc_trace, only: beginsub, endsub
    use dc_message, only: messagenotify
    use dc_error, only: storeerror, dc_noerr, dc_ealreadyinit
    implicit none
    type(gt_history_varinfo),intent(inout) :: varinfo
    character(*), intent(in):: name     ! 変数名
    character(*), intent(in):: dims(:)  ! 依存する次元
    character(*), intent(in):: longname ! 変数の記述的名称
    character(*), intent(in):: units    ! 変数の単位
    character(*), intent(in), optional:: xtype
                                         ! 変数の型
    logical, intent(in), optional:: time_average
                                         ! 時間平均
    logical, intent(in), optional:: average
                                         ! 時間平均 (後方互換用)
    logical, intent(out), optional:: err
                              ! 例外処理用フラグ. 
                              ! デフォルトでは, この手続き内でエラーが
                              ! 生じた場合, プログラムは強制終了します. 
                              ! 引数 *err* が与えられる場合, 
                              ! プログラムは強制終了せず, 代わりに
                              ! *err* に .true. が代入されます. 
                              !
                              ! Exception handling flag. 
                              ! By default, when error occur in 
                              ! this procedure, the program aborts. 
                              ! If this *err* argument is given, 
                              ! .true. is substituted to *err* and 
                              ! the program does not abort. 
 
    ! Internal Work
    integer:: i, numdims, stat
    character(STRING):: cause_c
    character(*), parameter:: subname = "HistoryVarinfoCreate1"
  continue
    call beginsub(subname)
    stat = dc_noerr
    cause_c = ''
 
    if ( varinfo % initialized ) then
      stat = dc_ealreadyinit
      cause_c = 'GT_HISTORY_VARINFO'
      goto 999
    end if
 
    varinfo % name = name
    varinfo % longname = longname
    varinfo % units = units
    if ( present(xtype) )        varinfo % xtype = xtype
    if ( present(time_average) ) varinfo % time_average = time_average
    if ( present(average) )      varinfo % time_average = average
    numdims = size(dims)
    allocate(varinfo % dims(numdims))
    do i = 1, numdims
      varinfo % dims(i) = dims(i)
      if (len(trim(dims(i))) > token) then
        call messagenotify('W', subname, &
          & 'dimension name <%c> is trancated to <%c>', &
          & c1=trim(dims(i)), c2=trim(varinfo % dims(i)))
      end if
    end do
    varinfo % initialized = .true.
 
999 continue
    call storeerror( stat, subname, err, cause_c )
    call endsub(subname)
  end subroutine historyvarinfocreate1
 
  !-------------------------------------------------------------------
 
!> @en
  !> @brief Create a GT_HISTORY_VARINFO variable (generic interface)
  !>
  !> Usage is same as HistoryVarinfoCreate.
  !> @enden
  !> @ja
  !> @brief GT_HISTORY_VARINFO 型変数作成 (総称インターフェース)
  !>
  !> 使用方法は HistoryVarinfoCreate と同様です。
  !> @endja
  subroutine historyvarinfocreate2( varinfo, & ! (out)
    & name, dims, longname, units, xtype, &    ! (in)
    & time_average, average, err &            ! (in) optional
    & )
    use gtool_history_types, only: gt_history_varinfo
    use gtool_history_generic, only: historyvarinfocreate
    use dc_trace, only: beginsub, endsub
    implicit none
    type(gt_history_varinfo),intent(inout) :: varinfo
    character(*), intent(in):: name     ! 変数名
    character(*), intent(in):: dims(:)  ! 依存する次元
    character(*), intent(in):: longname ! 変数の記述的名称
    character(*), intent(in):: units    ! 変数の単位
    character(*), intent(in), optional:: xtype
                                         ! 変数の型
    logical, intent(in), optional:: time_average
                                         ! 時間平均
    logical, intent(in), optional:: average
                                         ! 時間平均 (後方互換用)
    logical, intent(out), optional:: err
                              ! 例外処理用フラグ. 
                              ! デフォルトでは, この手続き内でエラーが
                              ! 生じた場合, プログラムは強制終了します. 
                              ! 引数 *err* が与えられる場合, 
                              ! プログラムは強制終了せず, 代わりに
                              ! *err* に .true. が代入されます. 
                              !
                              ! Exception handling flag. 
                              ! By default, when error occur in 
                              ! this procedure, the program aborts. 
                              ! If this *err* argument is given, 
                              ! .true. is substituted to *err* and 
                              ! the program does not abort. 
 
    ! Internal Work
    character(*), parameter:: subname = "HistoryVarinfoCreate2"
  continue
    call beginsub(subname)
    call historyvarinfocreate( varinfo, & ! (out)
      & name, dims, longname, units, xtype, &    ! (in)
      & time_average, average, err &            ! (in) optional
      & ) 
    call endsub(subname)
  end subroutine historyvarinfocreate2