gtvaropenbydimord.f90

Go to the documentation of this file.

!> @file gtvaropenbydimord.f90
!>
!> @author Yasuhiro MORIKAWA, Eizi TOYODA
!> @copyright Copyright (C) GFD Dennou Club, 2000-2026. All rights reserved. <br/>
!>            License is BSD-2-Clause. See [COPYRIGHT](@ref COPYRIGHT) in detail
!>
!> @en
!> @brief Open GT_VARIABLE of dimension by dimord
!>
!> This subroutine is provided through gtdata_generic.
!> @enden
!>
!> @ja
!> @brief 次元順序番号による GT_VARIABLE のオープン
!>
!> このサブルーチンは gtdata_generic から提供されます。
!> @endja
!>
 
!>
!> @en
!> @brief Open dimension variable by order number
!>
!> Opens the variable corresponding to the dimord-th dimension of
!> already-opened variable source_var and stores it in var.
!> The order dimord skips dimensions with width 1 (compacted),
!> but if count_compact is set to .true., all dimensions are counted.
!>
!> Variables opened with Open must always be closed with Close.
!>
!> When dimord == 0, the variable itself is reopened, incrementing
!> the reference counter.
!>
!> Open is a generic name for 2 subroutines; it is also possible
!> to open by specifying the variable URL directly.
!> @param[out] var           Variable handle
!> @param[in]  source_var    Source variable
!> @param[in]  dimord        Dimension order number
!> @param[in]  count_compact Include compact dimensions (optional)
!> @param[in]  inherit_slice Inherit current slice state (optional)
!> @param[out] err           Error flag (optional)
!> @enden
!>
!> @ja
!> @brief 次元順序番号による次元変数のオープン
!>
!> 既に開かれた変数 source_var の dimord 番目の次元にあたる変数を
!> 開き var に格納します。順序 dimord は現在の入出力範囲が
!> 幅1になっている (コンパクト化している) を飛ばした順序ですが、
!> count_compact に .true. を指定するとすべての次元のなかの順序になります。
!>
!> Open された変数は必ず Close されなければなりません。
!>
!> dimord == 0 の場合は変数自体を再度開きます。これは参照カウンタを
!> 増加させる手段です。
!>
!> Open は 2 つのサブルーチンの総称名であり、
!> 変数 URL を直接指定することで開くことも可能です。
!> @param[out] var           変数ハンドル
!> @param[in]  source_var    元の変数
!> @param[in]  dimord        次元順序番号
!> @param[in]  count_compact コンパクト次元を含むか (省略可能)
!> @param[in]  inherit_slice 現在のスライス状態を引き継ぐか (省略可能)
!> @param[out] err           エラーフラグ (省略可能)
!> @endja
!>
subroutine gtvaropenbydimord(var, source_var, dimord, count_compact, inherit_slice, err)
  use gtdata_types, only: gt_variable
  use gtdata_internal_map, only: var_class, vtb_class_netcdf, &
    & map_dup, map_create, map_lookup, gt_dimmap, &
    & map_set, dimord_skip_compact
  use gtdata_netcdf_generic, only: open, inquire
  use gtdata_netcdf_types, only: gd_nc_variable
  use gtdata_generic, only: gt_open => open
  use dc_present, only: present_and_true, present_and_false
  use dc_trace, only: beginsub, endsub, dbgmessage
  use dc_string, only: cprintf
  use dc_error, only: storeerror, gt_enomoredims, gt_enomoredims, &
    & dc_noerr, gt_efake
  use dc_types, only: string
  implicit none
  type(gt_variable), intent(out):: var
  type(gt_variable), intent(in):: source_var
  integer, intent(in):: dimord
  logical, intent(in), optional:: count_compact
  logical, intent(in), optional:: inherit_slice
  logical, intent(out), optional:: err
  integer:: sclass, scid, ld, sndims, stat, udimord, idimord, cause_i
  type(gd_nc_variable):: gdnc
  type(gt_dimmap), allocatable:: map_src(:)
  type(gt_dimmap):: map_result(1)
  logical:: cnt_compact, keep_slice
  character(STRING) :: endsub_msg
  character(len = *),      parameter:: subname = "GTVarOpen-By-Dimord"
  character(len = *),      parameter:: version = &
    & '$Name:  $' // &
    & '$Id: gtvaropenbydimord.f90,v 1.5 2009-07-04 04:58:06 morikawa Exp $'
continue
  call beginsub(subname, 'var.mapid=%d dimord=%d ', &
    & i=(/source_var%mapid, dimord/), version=version)
  stat = dc_noerr
  cause_i = dimord
  endsub_msg = ''
 
  ! 変数それ自体を開き直す処理
  if (dimord == 0) then
    call map_dup(var, source_var)
    if (present(err)) err = .false.
    endsub_msg = 'dup'
    goto 999
  endif
 
  ! 表を引き、dimord 番 (count_compact に注意) の次元の内部変数
  ! 次元番号を調べる。
  call map_lookup(source_var, ndims=sndims)
  if (sndims <= 0 .or. dimord > sndims) then
    stat = gt_enomoredims
    goto 999
  endif
  allocate(map_src(sndims))
  call map_lookup(source_var, map=map_src)
  cnt_compact = .false.
  if (present_and_true(count_compact)) then
    cnt_compact = .true.
  else
    cnt_compact = .false.
  end if
  keep_slice = .true.
  if (present_and_false(inherit_slice)) then
    keep_slice = .false.
  end if
  call dbgmessage('count_compact=%y', l=(/cnt_compact/))
 
  if (cnt_compact) then
    udimord = dimord
  else
    udimord = dimord_skip_compact(dimord, map=map_src)
  endif
  if (udimord <= 0 .or. udimord > size(map_src)) then
    stat = gt_enomoredims
    goto 999
  endif
 
  idimord = map_src(udimord)%dimno
  if (idimord < 1) then
    call gt_open(var, map_src(udimord)%url, err=err)
    ! storeerror はしなくてよい
    deallocate(map_src)
    goto 999
  endif
 
  ! 実態種別に合わせ「次元変数オープン」処理
  call var_class(source_var, sclass, scid)
  if (sclass == vtb_class_netcdf) then
    call open(gdnc, gd_nc_variable(scid), idimord, err)
    call inquire(gdnc, dimlen=ld)
    call map_create(var, vtb_class_netcdf, gdnc%id, 1, (/ld/), stat)
    if (stat /= dc_noerr) then
      cause_i = 1
      goto 999
    end if
    call map_lookup(var, map=map_result)
    map_result(1)%offset = map_src(udimord)%offset
    map_result(1)%step = map_src(udimord)%step
    map_result(1)%allcount = map_src(udimord)%allcount
    if (keep_slice) then
      map_result(1)%start = map_src(udimord)%start
      map_result(1)%count = map_src(udimord)%count
      map_result(1)%stride = map_src(udimord)%stride
    else
      map_result(1)%start = 1
      map_result(1)%count = map_src(udimord)%allcount
      map_result(1)%stride = 1
    end if
    call map_set(var, map=map_result, stat=stat)
  else
    stat = gt_efake
  endif
 
  deallocate(map_src)
  endsub_msg = cprintf('result_var=%d', i=(/var%mapid/))
999 continue
  call storeerror(stat, subname, cause_i=cause_i, err=err)
  call endsub(subname, '%c', c1=trim(endsub_msg))
end subroutine gtvaropenbydimord