gtvarcopyattrall.f90

Go to the documentation of this file.

!> @file gtvarcopyattrall.f90
!>
!> @author Eizi TOYODA, Yasuhiro MORIKAWA
!> @copyright Copyright (C) GFD Dennou Club, 2000-2026. All rights reserved. <br/>
!>            License is BSD-2-Clause. See [COPYRIGHT](@ref COPYRIGHT) in detail
!>
!> @en
!> @brief Copy all attributes
!>
!> This subroutine is provided as gtdata_generic#Copy_Attr
!> through gtdata_generic.
!> @enden
!>
!> @ja
!> @brief 全属性のコピー
!>
!> このサブルーチンは gtdata_generic から gtdata_generic#Copy_Attr
!> として提供されます。
!> @endja
!>
 
!>
!> @en
!> @brief Copy all attributes from one variable to another
!>
!> Copies all attributes of variable from to variable to.
!> By default, global attributes are also copied.
!> If global is set to .false., global attributes are not copied.
!>
!> Copy_Attr is a generic name for 2 subroutines; there is also
!> a method to copy by specifying an attribute.
!> @param[inout] to     Destination variable handle
!> @param[inout] from   Source variable handle
!> @param[out]   err    Error flag (optional)
!> @param[in]    global Whether to copy global attributes (optional)
!> @enden
!>
!> @ja
!> @brief 1つの変数から別の変数へ全属性をコピー
!>
!> 変数 from の全ての属性を変数 to へコピーします。
!> デフォルトでは大域属性もコピーしますが、
!> global に .false. を与える場合、大域属性をコピーしません。
!>
!> Copy_Attr は 2 つのサブルーチンの総称名であり、
!> 他にも属性を指定してコピーする方法もあります。
!> @param[inout] to     コピー先の変数ハンドル
!> @param[inout] from   コピー元の変数ハンドル
!> @param[out]   err    エラーフラグ (省略可能)
!> @param[in]    global 大域属性をコピーするか (省略可能)
!> @endja
!>
subroutine gtvarcopyattrall(to, from, err, global)
  use gtdata_types, only: gt_variable
  use gtdata_generic, only: attr_rewind, attr_next, gtvarcopyattr
  use dc_present,only:present_and_true, present_and_false
  use dc_url,   only: gt_plus
  use dc_error, only: dumperror
  use dc_trace, only: beginsub, endsub, dbgmessage
  use dc_types, only: string
  type(gt_variable), intent(inout):: to
  type(gt_variable), intent(inout):: from
  logical, intent(out), optional:: err
  logical, intent(in), optional:: global
  character(len = *), parameter:: subnam = "GTVarCopyAttrAll"
  character(len = STRING):: aname
  logical:: end
continue
  if (present(err)) err = .false.
  call beginsub(subnam)
  call attr_rewind(from)
  do
    call attr_next(from, aname, end)
    if (end) exit
    if ( (present_and_false(global)) .and. (aname(1:1) == gt_plus) ) then
      call dbgmessage("Ignored attr=%c", c1=aname)
      cycle
    end if
    call dbgmessage("Copied attr=%c", c1=aname)
    call gtvarcopyattr(to=to, attrname=aname, from=from, err=err)
    if (present_and_true(err)) err = .false.
  enddo
  call endsub(subnam)
end subroutine gtvarcopyattrall