gtvarclose.f90

Go to the documentation of this file.

!> @file gtvarclose.f90
!>
!> @author Yasuhiro MORIKAWA, Eizi TOYODA
!> @copyright Copyright (C) GFD Dennou Club, 2000-2026. All rights reserved. <br/>
!>            License is BSD-2-Clause. See [COPYRIGHT](@ref COPYRIGHT) in detail
!>
!> @en
!> @brief Variable finalization
!>
!> This subroutine is provided through gtdata_generic.
!> @enden
!>
!> @ja
!> @brief 変数の終了処理
!>
!> このサブルーチンは gtdata_generic から提供されます。
!> @endja
!>
 
!>
!> @en
!> @brief Finalize variable
!>
!> Performs finalization for variable var. Variables that have been
!> Opened or Created must be finalized using this subroutine at the
!> end of the program.
!>
!> If an error occurs during finalization, outputs a message and
!> terminates the program. If err is provided, returns .true.
!> in that argument and program does not terminate.
!> @param[in]  var Variable handle to close
!> @param[out] err Error flag (optional)
!> @enden
!>
!> @ja
!> @brief 変数を終了処理
!>
!> 変数 var の終了処理を行います。Open または Create されたものは
!> プログラムの最後に必ずこのサブルーチンを用いて終了処理を行ってください。
!>
!> 終了処理の際にエラーが生じた場合、メッセージを出力してプログラムは
!> 強制終了します。err を与えてある場合にはこの引数に .true.
!> が返り、プログラムは終了しません。
!> @param[in]  var クローズする変数ハンドル
!> @param[out] err エラーフラグ (省略可能)
!> @endja
!>
subroutine gtvarclose(var, err)
  use gtdata_types, only: gt_variable
  use gtdata_internal_map, only: vtb_class_netcdf, &
    & maptabdelete, map_lookup
  use gtdata_internal_vartable, only: vartabledelete, vartablelookup
  use gtdata_netcdf_generic, only: close
  use gtdata_netcdf_types, only: gd_nc_variable
  use dc_error, only: storeerror, gt_ebadvar
  use dc_trace, only: beginsub, endsub, dbgmessage
  implicit none
  type(gt_variable), intent(in), target:: var
  logical, intent(out), optional:: err
  integer:: vid, class, cid
  logical:: action, myerr
continue
  call beginsub('gtvarclose', fmt='var=%d', i=(/var%mapid/))
  call map_lookup(var, vid=vid)
  call maptabdelete(var, myerr)
  if (myerr) goto 999
  ! vid が 0 になるのは dup_dimmap で作られたハンドル
  if (vid == 0) goto 999
  call vartablelookup(vid, class, cid)
  call vartabledelete(vid, action, myerr)
  if (myerr) goto 999
  if (.not. action) then
    call dbgmessage('refcount decrement only, no close internal var')
    goto 999
  else if (class == vtb_class_netcdf) then
    call close(gd_nc_variable(cid), myerr)
    if (myerr) goto 999
  else
    call storeerror(gt_ebadvar, "GTVarClose", err)
    call endsub('GTVarClose', 'badvar')
    myerr = .true.
  endif
999 continue
  call endsub('gtvarclose')
  if (present(err)) err = myerr
end subroutine gtvarclose