gdncvarcreate.f90

Go to the documentation of this file.

!> @file gdncvarcreate.f90
!>
!> @author Eizi TOYODA, Yasuhiro MORIKAWA
!> @copyright Copyright (C) GFD Dennou Club, 2000-2026. All rights reserved. <br/>
!>            License is BSD-2-Clause. See [COPYRIGHT](@ref COPYRIGHT) in detail
!>
!> @en
!> @brief Create variable in netCDF file
!>
!> These subroutines and functions are provided as gtdata_netcdf_generic#Create
!> through gtdata_netcdf_generic.
!> @enden
!>
!> @ja
!> @brief netCDF ファイルへ変数作成
!>
!> これらのサブルーチン、関数は gtdata_netcdf_generic から
!> gtdata_netcdf_generic#Create として提供されます。
!> @endja
!>
 
!>
!> @en
!> @brief Create a variable
!>
!> Creates a variable at the specified URL.
!> The dimensions the variable depends on are given in dims.
!> The returned var contains the variable ID and other information.
!>
!> Setting overwrite to .true. enables overwrite mode (default: no overwrite).
!> If err is provided, errors return .false. instead of terminating.
!> @enden
!>
!> @ja
!> @brief 変数を作成
!>
!> 変数 URL url に変数を作成します。
!> 変数が依存する次元を dims に与えます。
!> 返される引数 var には変数 ID などの情報が格納されます。
!>
!> overwrite に .true. を設定すると上書き可能モード (デフォルト: 上書き不可)。
!> err を与えた場合、エラー時はプログラム終了せず .false. が返されます。
!> @endja
!>
!> @param[out] var       @en Created variable handle @enden @ja 作成した変数ハンドル @endja
!> @param[in]  url       @en Variable URL @enden @ja 変数 URL @endja
!> @param[in]  xtype     @en Data type (float, double, int, char) @enden
!>                       @ja データ型 (float, double, int, char) @endja
!> @param[in]  dims      @en Array of dimension variables @enden @ja 次元変数の配列 @endja
!> @param[in]  overwrite @en Enable overwrite mode (optional) @enden
!>                       @ja 上書きモードを有効化 (省略可能) @endja
!> @param[out] err       @en Error flag (optional) @enden @ja エラーフラグ (省略可能) @endja
!>
subroutine gdncvarcreate(var, url, xtype, dims, overwrite, err)
  use gtdata_netcdf_types, only: gd_nc_variable, gd_nc_variable_entry, gd_nc_variable_search
  use dc_types, only: string
  use dc_string, only: strieq
  use gtdata_netcdf_internal, only: vtable_add, vtable_lookup
  use gtdata_netcdf_file_generic, only: gdncfileopen, gdncfiledefinemode
  use dc_url, only: urlsplit
  use dc_trace, only: beginsub, endsub, dbgmessage
  use gtdata_netcdf_generic, only: tostring ! for debug
  use netcdf, only: &
    & nf90_noerr, nf90_float, nf90_double, nf90_int, nf90_char, nf90_ebaddim, nf90_def_var
  use dc_error, only: storeerror, gt_enomem, gt_eotherfile, &
    & gt_edimmultidim
  implicit none
  type(gd_nc_variable), intent(out):: var
  character(len = *), intent(in):: url
  character(len = *), intent(in):: xtype
  type(gd_nc_variable), intent(in):: dims(:)
  logical, intent(in), optional:: overwrite
  logical, intent(out), optional:: err
  type(gd_nc_variable_search):: ent
  type(gd_nc_variable_entry):: ent_dim
  character(len = string):: filename, varname
  integer, allocatable:: dimids(:)
  integer:: stat, nvdims, i
  integer:: nc_xtype
  logical:: clobber
  intrinsic trim
  character(len = *), parameter:: subnam = "GDNcVarCreate"
continue
  clobber = .false.
  if (present(overwrite)) clobber = overwrite
  call beginsub(subnam)
  call dbgmessage('url=%c', c1=trim(url))
  call dbgmessage('xtype=%c', c1=trim(xtype))
  call dbgmessage('dims=(/%*d/)', i=(/dims(:)%id/), n=(/size(dims)/))
  call dbgmessage('ovwr=%y', l=(/clobber/))
 
  ! もし必要ならファイル作成
  call urlsplit(url, filename, varname)
  call gdncfileopen(ent%fileid, filename, stat=stat, writable=.true., &
    & overwrite=clobber)
  if (stat /= nf90_noerr) goto 999
 
  ! 次元にまつわる準備
  nvdims = size(dims)
  allocate(dimids(max(1, nvdims)), stat=stat)
  if (stat /= 0) then
    stat = gt_enomem
    goto 999
  end if
  do, i = 1, nvdims
    stat = vtable_lookup(dims(i), ent_dim)
    if (stat /= nf90_noerr) then
      stat = nf90_ebaddim
      goto 999
    endif
    if (ent%fileid /= ent_dim%fileid) then
      stat = gt_eotherfile
      goto 999
    endif
    if (ent_dim%dimid <= 0) then
      stat = gt_edimmultidim
      goto 999
    endif
    dimids(i) = ent_dim%dimid
  enddo
  ent%dimid = 0
 
  ! 変数の型の判定
  nc_xtype = nf90_float
  if (strieq(xtype, "double")) then
    nc_xtype = nf90_double
  else if (strieq(xtype, "DOUBLEPRECISION")) then
    nc_xtype = nf90_double
  end if
  if (strieq(xtype, "int")) then
    nc_xtype = nf90_int
  else if (strieq(xtype, "INTEGER")) then
    nc_xtype = nf90_int
  end if
  if (strieq(xtype, "char")) then
    nc_xtype = nf90_char
  else if (strieq(xtype, "CHARACTER")) then
    nc_xtype = nf90_char
  end if
 
  ! 本当の変数作成操作
  stat = gdncfiledefinemode(ent%fileid)
  if (stat /= nf90_noerr) goto 999
  if ( nvdims == 0 ) then
    stat = nf90_def_var(ent%fileid, name = trim(varname), &
      & xtype = nc_xtype, varid=ent%varid)
  else
    stat = nf90_def_var(ent%fileid, name = trim(varname), &
      & xtype = nc_xtype, dimids = dimids, varid=ent%varid)
  end if
  if (stat /= nf90_noerr) goto 999
 
  ! 登録
  stat = vtable_add(var, ent)
 
999 continue
  if (allocated(dimids)) deallocate(dimids)
  if (stat /= nf90_noerr) var % id = -1
  call storeerror(stat, subnam, err, cause_c=url)
  call endsub(subnam, 'stat=%d, var.id=%d', i=(/stat, var % id/))
end subroutine