hstnmlinfosetvalidname.f90

Go to the documentation of this file.

!> @file hstnmlinfosetvalidname.f90
!>
!> @author Yasuhiro MORIKAWA
!> @copyright Copyright (C) GFD Dennou Club, 2007-2026. All rights reserved. <br/>
!>            License is BSD-2-Clause. See [COPYRIGHT](@ref COPYRIGHT) in detail
!>
!> @en
!> @brief Set validation to variable names
!> @enden
!>
!> @ja
!> @brief 変数名の有効性を設定
!> @endja
 
  !> @en
  !> @brief Set validation to variable names
  !>
  !> For detection of invalid variable names,
  !> set validation to variable names explicitly by this
  !> subroutine.
  !>
  !> If @p gthstnml is not initialized by HstNmlInfoCreate yet,
  !> error is occurred.
  !> @enden
  !>
  !> @ja
  !> @brief 変数名の有効性を設定
  !>
  !> 無効な変数名を検知するため, このサブルーチンで
  !> 有効な変数に対しては明示的に設定を行います.
  !>
  !> なお, 与えられた @p gthstnml が HstNmlInfoCreate によって初期設定
  !> されていない場合, プログラムはエラーを発生させます.
  !> @endja
  !>
  !> @param[in] gthstnml gtool_history_nmlinfo_types::GTHST_NMLINFO 型変数
  !> @param[in] name 有効であることを設定する変数名.
  !>                 "Data1,Data2" のようにカンマで区切って複数指定可能.
  !>                 A variable name that is set validation.
  !>                 Multiple variables can be specified as "Data1,Data2".
  !> @param[out] err 例外処理用フラグ. Exception handling flag.
  subroutine hstnmlinfosetvalidname( gthstnml, &
    & name, &
    & err )
    use gtool_history_nmlinfo_types, only: gthst_nmlinfo, gthst_nmlinfo_entry
    use gtool_history_nmlinfo_internal, only: listsearch
    use gtool_history_nmlinfo_internal, only: name_delimiter
    use dc_trace, only: beginsub, endsub
    use dc_string, only: split
    use dc_types, only: string, token
    use dc_error, only: storeerror, dc_noerr, dc_enotinit
    implicit none
    type(gthst_nmlinfo), intent(in):: gthstnml
    character(*), intent(in):: name
                              ! 有効であることを設定する変数名. 
                              ! 
                              ! "Data1,Data2" のようにカンマで区切って複数
                              ! の変数を指定することも可能です. 
                              ! 
                              ! A variable name that is set validation. 
                              ! 
                              ! Multiple variables can be specified 
                              ! as "Data1,Data2" too. Delimiter is comma. 
    logical, intent(out), optional:: err
                              ! 例外処理用フラグ. 
                              ! デフォルトでは, この手続き内でエラーが
                              ! 生じた場合, プログラムは強制終了します. 
                              ! 引数 *err* が与えられる場合, 
                              ! プログラムは強制終了せず, 代わりに
                              ! *err* に .true. が代入されます. 
                              !
                              ! Exception handling flag. 
                              ! By default, when error occur in 
                              ! this procedure, the program aborts. 
                              ! If this *err* argument is given, 
                              ! .true. is substituted to *err* and 
                              ! the program does not abort. 
 
    !-----------------------------------
    !  作業変数
    !  Work variables
    type(gthst_nmlinfo_entry), pointer:: hptr =>null()
    character(TOKEN), pointer:: varnames_array(:) =>null()
    integer:: i, vnmax
    integer:: stat
    character(STRING):: cause_c
    character(*), parameter:: subname = 'HstNmlInfoSetValidName'
  continue
    call beginsub( subname, fmt = '@name=%c', c1 = trim(name) )
    stat = dc_noerr
    cause_c = ''
 
    !-----------------------------------------------------------------
    !  初期設定のチェック
    !  Check initialization
    !-----------------------------------------------------------------
    if ( .not. gthstnml % initialized ) then
      stat = dc_enotinit
      cause_c = 'GTHST_NMLINFO'
      goto 999
    end if
 
    !-----------------------------------------------------------------
    !  複数の変数名の取り扱い
    !  Handle multiple variables
    !-----------------------------------------------------------------
    call split( str = name, sep = name_delimiter, & ! (in)
      & carray = varnames_array )                   ! (out)
    vnmax = size( varnames_array )
 
    !-----------------------------------------------------------------
    !  *gthstnml* 内から, *name* に関する情報を探査.
    !  Search information correspond to *name* in *gthstnml*
    !-----------------------------------------------------------------
    do i = 1, vnmax
      hptr => gthstnml % gthstnml_list
      call listsearch( gthstnml_list = hptr, &    ! (inout)
        &              name = varnames_array(i) ) ! (in)
      if ( associated( hptr ) ) then
        hptr % name_invalid = .false.
      end if
    end do
 
    !-----------------------------------------------------------------
    !  終了処理, 例外処理
    !  Termination and Exception handling
    !-----------------------------------------------------------------
999 continue
    call storeerror( stat, subname, err, cause_c )
    call endsub( subname )
  end subroutine hstnmlinfosetvalidname