hstnmlinfoassocgthist.f90

Go to the documentation of this file.

!> @file hstnmlinfoassocgthist.f90
!>
!> @author Yasuhiro MORIKAWA
!> @copyright Copyright (C) GFD Dennou Club, 2007-2026. All rights reserved. <br/>
!>            License is BSD-2-Clause. See [COPYRIGHT](@ref COPYRIGHT) in detail
!>
!> @en
!> @brief Associate a gtool_history_types::GT_HISTORY variable
!> @enden
!>
!> @ja
!> @brief gtool_history_types::GT_HISTORY 型変数の結合
!> @endja
 
  !> @en
  !> @brief Associate a gtool_history_types::GT_HISTORY variable
  !>
  !> This subroutine associates given gtool_history_types::GT_HISTORY
  !> pointer @p history to
  !> gtool_history_types::GT_HISTORY corresponding to @p name in @p gthstnml.
  !> Give null @p history.
  !>
  !> Use after state is changed from define mode to
  !> output mode by HstNmlInfoEndDefine.
  !> If this subroutine is used before
  !> HstNmlInfoEndDefine is used, error is occurred.
  !>
  !> When data corresponding to @p name is not found,
  !> error is occurred.
  !> When @p name is blank,
  !> error is occurred too.
  !>
  !> If @p gthstnml is not initialized by HstNmlInfoCreate yet,
  !> error is occurred.
  !> @enden
  !>
  !> @ja
  !> @brief gtool_history_types::GT_HISTORY 型変数の結合
  !>
  !> 与えられた gtool_history_types::GT_HISTORY 型のポインタ @p history に対し,
  !> @p gthstnml 内の @p name に関する gtool_history_types::GT_HISTORY 型変数を
  !> 結合します.
  !> 空状態の @p history を与えてください.
  !>
  !> HstNmlInfoEndDefine で定義モードから出力モードに
  !> 移行した後に呼び出してください.
  !> HstNmlInfoEndDefine を呼ぶ前にこのサブルーチンを使用すると,
  !> プログラムはエラーを発生させます.
  !>
  !> @p name に関する情報が見当たらない場合,
  !> プログラムはエラーを発生させます.
  !> @p name が空文字の場合にも,
  !> プログラムはエラーを発生させます.
  !>
  !> なお, 与えられた @p gthstnml が HstNmlInfoCreate によって初期設定
  !> されていない場合にも, プログラムはエラーを発生させます.
  !> @endja
  !>
  !> @param[in] gthstnml gtool_history_nmlinfo_types::GTHST_NMLINFO 型変数
  !> @param[in] name 変数名. 先頭の空白は無視されます.
  !>                 Variable identifier. Blanks at the head of the name are ignored.
  !> @param[out] history gtool_history_types::GT_HISTORY 型ポインタ.
  !>                     Pointer of gtool_history_types::GT_HISTORY.
  !> @param[out] err 例外処理用フラグ. Exception handling flag.
  subroutine hstnmlinfoassocgthist( gthstnml, &
    & name, history, err )
    use gtool_history_nmlinfo_types, only: gthst_nmlinfo, gthst_nmlinfo_entry
    use gtool_history_nmlinfo_internal, only: listsearch
    use gtool_history, only: gt_history
    use dc_trace, only: beginsub, endsub
    use dc_types, only: string
    use dc_error, only: storeerror, dc_noerr, dc_enotinit, dc_enoentry, hst_ebadname, hst_eindefine
    implicit none
    type(gthst_nmlinfo), intent(in):: gthstnml
    character(*), intent(in):: name
                              ! 変数名. 
                              ! 先頭の空白は無視されます. 
                              ! 
                              ! Variable identifier. 
                              ! Blanks at the head of the name are ignored. 
    type(gt_history), pointer:: history
                              ! (out)
                              ! 
                              ! gtool_history モジュール用構造体. 
                              ! Derived type for "gtool_history" module
    logical, intent(out), optional:: err
                              ! 例外処理用フラグ. 
                              ! デフォルトでは, この手続き内でエラーが
                              ! 生じた場合, プログラムは強制終了します. 
                              ! 引数 *err* が与えられる場合, 
                              ! プログラムは強制終了せず, 代わりに
                              ! *err* に .true. が代入されます. 
                              !
                              ! Exception handling flag. 
                              ! By default, when error occur in 
                              ! this procedure, the program aborts. 
                              ! If this *err* argument is given, 
                              ! .true. is substituted to *err* and 
                              ! the program does not abort. 
 
    !-----------------------------------
    !  作業変数
    !  Work variables
    type(gthst_nmlinfo_entry), pointer:: hptr =>null()
    integer:: stat
    character(STRING):: cause_c
    character(*), parameter:: subname = 'HstNmlInfoAssocGtHist'
  continue
    call beginsub( subname )
    stat = dc_noerr
    cause_c = ''
 
    !-----------------------------------------------------------------
    !  初期設定のチェック
    !  Check initialization
    !-----------------------------------------------------------------
    if ( .not. gthstnml % initialized ) then
      stat = dc_enotinit
      cause_c = 'GTHST_NMLINFO'
      goto 999
    end if
 
    if ( trim( name ) == '' ) then
      stat = hst_ebadname
      cause_c = ''
      goto 999
    end if
 
    if ( gthstnml % define_mode ) then
      stat = hst_eindefine
      cause_c = 'AssocGtHist'
      goto 999
    end if
 
    !-----------------------------------------------------------------
    !  *gthstnml* 内から, *name* に関する history を探査.
    !  Search "history" correspond to *name* in *gthstnml*
    !-----------------------------------------------------------------
    hptr => gthstnml % gthstnml_list
    call listsearch( gthstnml_list = hptr, & ! (inout)
      &              name = name )           ! (in)
 
    if ( .not. associated( hptr ) ) then
      stat = dc_enoentry
      cause_c = adjustl( name )
      goto 999
    end if
 
    nullify( history )
    history => hptr % history
 
    nullify( hptr )
 
    !-----------------------------------------------------------------
    !  終了処理, 例外処理
    !  Termination and Exception handling
    !-----------------------------------------------------------------
999 continue
    call storeerror( stat, subname, err, cause_c )
    call endsub( subname )
  end subroutine hstnmlinfoassocgthist