hstnmlinfoallnamevalid.f90

Go to the documentation of this file.

!> @file hstnmlinfoallnamevalid.f90
!>
!> @author Yasuhiro MORIKAWA
!> @copyright Copyright (C) GFD Dennou Club, 2007-2026. All rights reserved. <br/>
!>            License is BSD-2-Clause. See [COPYRIGHT](@ref COPYRIGHT) in detail
!>
!> @en
!> @brief Check invalid variable names
!> @enden
!>
!> @ja
!> @brief 無効な変数名のチェック
!> @endja
 
  !> @en
  !> @brief Check invalid variable names
  !>
  !> If variable names that are not set validation by
  !> HstNmlInfoSetValidName exist,
  !> .true. is set to @p invalid, and invalid variable names
  !> are joined with comma, and set to @p names.
  !>
  !> If @p gthstnml is not initialized by HstNmlInfoCreate yet,
  !> error is occurred.
  !> @enden
  !>
  !> @ja
  !> @brief 無効な変数名のチェック
  !>
  !> HstNmlInfoSetValidName によって, 有効性を設定されていない変数が
  !> ある場合,
  !> @p invalid に .true. を返し, @p names には無効な
  !> 変数名をカンマで区切った文字列を返します.
  !>
  !> なお, 与えられた @p gthstnml が HstNmlInfoCreate によって初期設定
  !> されていない場合, プログラムはエラーを発生させます.
  !> @endja
  !>
  !> @param[in] gthstnml gtool_history_nmlinfo_types::GTHST_NMLINFO 型変数
  !> @param[out] invalid 無効な変数名が存在する場合に .true.
  !>                     If invalid variable names exist, .true. is returned.
  !> @param[out] names 無効な変数名のリスト. List of invalid variable names.
  !> @param[out] err 例外処理用フラグ. Exception handling flag.
  subroutine hstnmlinfoallnamevalid( gthstnml, &
    & invalid, &
    & names, &
    & err )
    use gtool_history_nmlinfo_types, only: gthst_nmlinfo, gthst_nmlinfo_entry
    use gtool_history_nmlinfo_internal, only: listnext, name_delimiter
    use dc_trace, only: beginsub, endsub
    use dc_types, only: string
    use dc_error, only: storeerror, dc_noerr, dc_enotinit
    implicit none
    type(gthst_nmlinfo), intent(in):: gthstnml
    logical, intent(out):: invalid
                              ! 無効な変数名が存在する
                              ! 場合には .true. を返す. 
                              ! 
                              ! If invalid variable names are exist, 
                              ! .true. is returned. 
                              ! 
    character(*), intent(out):: names
                              ! 無効な変数名のリスト. 
                              ! 
                              ! List of invalid variable names. 
    logical, intent(out), optional:: err
                              ! 例外処理用フラグ. 
                              ! デフォルトでは, この手続き内でエラーが
                              ! 生じた場合, プログラムは強制終了します. 
                              ! 引数 *err* が与えられる場合, 
                              ! プログラムは強制終了せず, 代わりに
                              ! *err* に .true. が代入されます. 
                              !
                              ! Exception handling flag. 
                              ! By default, when error occur in 
                              ! this procedure, the program aborts. 
                              ! If this *err* argument is given, 
                              ! .true. is substituted to *err* and 
                              ! the program does not abort. 
 
    !-----------------------------------
    !  作業変数
    !  Work variables
    type(gthst_nmlinfo_entry), pointer:: hptr =>null()
    integer:: stat
    character(STRING):: cause_c
    character(*), parameter:: subname = 'HstNmlInfoAllNameValid'
  continue
    call beginsub( subname )
    stat = dc_noerr
    cause_c = ''
 
    names = ''
    invalid = .false.
 
    !-----------------------------------------------------------------
    !  初期設定のチェック
    !  Check initialization
    !-----------------------------------------------------------------
    if ( .not. gthstnml % initialized ) then
      stat = dc_enotinit
      cause_c = 'GTHST_NMLINFO'
      goto 999
    end if
 
    !-----------------------------------------------------------------
    !  *gthstnml* 内から, *name* に関する情報を探査.
    !  Search information correspond to *name* in *gthstnml*
    !-----------------------------------------------------------------
    hptr => gthstnml % gthstnml_list
    do while ( associated( hptr % next ) )
      call listnext( gthstnml_list = hptr ) ! (inout)
 
      if ( hptr % name_invalid ) then
        invalid = .true.
        if ( trim(names) /= '' ) names = trim(names) // name_delimiter
        names = trim(names) // adjustl( hptr % name )
      end if
    end do
 
    !-----------------------------------------------------------------
    !  終了処理, 例外処理
    !  Termination and Exception handling
    !-----------------------------------------------------------------
999 continue
    call storeerror( stat, subname, err, cause_c )
    call endsub( subname, fmt = '@invalid=%y @names=%c', &
      & l = (/ invalid /), c1 = trim(names) )
  end subroutine hstnmlinfoallnamevalid