historyaxiscopy.f90

Go to the documentation of this file.

!> @file historyaxiscopy.f90
!>
!> @author Yasuhiro MORIKAWA
!> @copyright Copyright (C) GFD Dennou Club, 2004-2026. All rights reserved. <br/>
!>            License is BSD-2-Clause. See [COPYRIGHT](@ref COPYRIGHT) in detail
!>
!> @en
!> @brief Copy GT_HISTORY_AXIS
!> @enden
!>
!> @ja
!> @brief GT_HISTORY_AXIS のコピー
!> @endja
 
!>
!> @en
!> @brief Copy a GT_HISTORY_AXIS variable
!>
!> Copies the GT_HISTORY_AXIS variable axis_src
!> to axis_dest.
!> axis_src must be initialized by HistoryAxisCreate.
!> To add attributes, use HistoryAxisAddAttr.
!>
!> If err is given, the program does not abort on error;
!> instead, err returns .true.
!>
!> Arguments after err are values to override during copy.
!> @param[out]    axis_dest Destination GT_HISTORY_AXIS
!> @param[in]     axis_src  Source GT_HISTORY_AXIS
!> @param[out]    err       Error flag (optional)
!> @param[in]     name      Dimension variable name (optional, override)
!> @param[in]     length    Dimension length (optional, override)
!> @param[in]     longname  Descriptive name (optional, override)
!> @param[in]     units     Units (optional, override)
!> @param[in]     xtype     Type (optional, override)
!> @enden
!>
!> @ja
!> @brief GT_HISTORY_AXIS 型変数コピー
!>
!> GT_HISTORY_AXIS 型の変数 axis_src を
!> axis_dest にコピーします。
!> axis_src は HistoryAxisCreate によって初期設定されている必要が
!> あります。
!> さらに属性を付加する場合には HistoryAxisAddAttr
!> を用いてください。
!>
!> err を与えておくと、コピーの際何らかの不具合が生じても
!> 終了せずに err が真になって返ります。
!>
!> err 以降の引数は、コピーの際に上書きする値です。
!> @param[out]    axis_dest コピー先 GT_HISTORY_AXIS
!> @param[in]     axis_src  コピー元 GT_HISTORY_AXIS
!> @param[out]    err       エラーフラグ (省略可能)
!> @param[in]     name      次元変数名 (省略可能, 上書き)
!> @param[in]     length    次元長 (省略可能, 上書き)
!> @param[in]     longname  次元変数の記述的名称 (省略可能, 上書き)
!> @param[in]     units     次元変数の単位 (省略可能, 上書き)
!> @param[in]     xtype     次元変数の型 (省略可能, 上書き)
!> @endja
!>
  subroutine historyaxiscopy1(axis_dest, axis_src, err, &
    & name, length, longname, units, xtype)
    !
    use gtool_history_types, only: gt_history_axis
    use gtool_history_internal, only: copy_attrs
    use dc_trace, only: beginsub, endsub
    use dc_present, only: present_select
    use dc_string, only: cprintft
    implicit none
    type(gt_history_axis),intent(out) :: axis_dest ! コピー先 GT_HISTORY_AXIS
    type(gt_history_axis),intent(in)  :: axis_src  ! コピー元 GT_HISTORY_AXIS
    logical, intent(out), optional :: err
    character(*) , intent(in), optional:: name     ! 次元変数名
    integer, intent(in), optional:: length         ! 次元長 (配列サイズ)
    character(*) , intent(in), optional:: longname ! 次元変数の記述的名称
    character(*) , intent(in), optional:: units    ! 次元変数の単位
    character(*) , intent(in), optional:: xtype    ! 次元変数の型
    character(*), parameter:: subname = "HistoryAxisCopy1"
  continue
    call beginsub(subname)
    axis_dest % name     = cprintft('%c', c1=present_select('', axis_src % name, name))
    axis_dest % length   = present_select(.false., axis_src % length, length)
    axis_dest % longname = present_select('', axis_src % longname, longname)
    axis_dest % units    = present_select('', axis_src % units, units)
    axis_dest % xtype    = cprintft('%c', c1=present_select('', axis_src % xtype, xtype))
 
    if (associated( axis_src % attrs ) ) then
      allocate(  axis_dest % attrs( size( axis_src % attrs) )  )
      call copy_attrs( from = axis_src % attrs, &
        &              to = axis_dest % attrs, err = err)
    end if
    call endsub(subname)
  end subroutine historyaxiscopy1
 
  !-------------------------------------------------------------------
 
!> @en
  !> @brief Copy a GT_HISTORY_AXIS variable (generic interface)
  !>
  !> Usage is same as HistoryAxisCopy.
  !> @enden
  !> @ja
  !> @brief GT_HISTORY_AXIS 型変数コピー (総称インターフェース)
  !>
  !> 使用方法は HistoryAxisCopy と同様です。
  !> @endja
  subroutine historyaxiscopy2(axis_dest, axis_src, err, &
    & name, length, longname, units, xtype)
    use gtool_history_types, only: gt_history_axis
    use gtool_history_generic, only: historyaxiscopy
    use dc_trace, only: beginsub, endsub
    implicit none
    type(gt_history_axis),intent(out) :: axis_dest ! コピー先 GT_HISTORY_AXIS
    type(gt_history_axis),intent(in)  :: axis_src  ! コピー元 GT_HISTORY_AXIS
    logical, intent(out), optional :: err
    character(*) , intent(in), optional:: name     ! 次元変数名
    integer, intent(in), optional:: length         ! 次元長 (配列サイズ)
    character(*) , intent(in), optional:: longname ! 次元変数の記述的名称
    character(*) , intent(in), optional:: units    ! 次元変数の単位
    character(*) , intent(in), optional:: xtype    ! 次元変数の型
    character(*), parameter:: subname = "HistoryAxisCopy2"
  continue
    call beginsub(subname)
    call historyaxiscopy(axis_dest, axis_src, err, &
      & name, length, longname, units, xtype)
    call endsub(subname)
  end subroutine historyaxiscopy2