gtvarcreate.f90 File Reference

Create dependent variable. More...

Go to the source code of this file.

Functions/Subroutines
subroutine	gtvarcreate (var, url, dims, xtype, long_name, overwrite, err)

Detailed Description

Create dependent variable.

Author

Yasuhiro MORIKAWA, Eizi TOYODA

Copyright

Copyright (C) GFD Dennou Club, 2000-2026. All rights reserved.
License is BSD-2-Clause. See COPYRIGHT in detail

This subroutine is provided through gtdata_generic.

Definition in file gtvarcreate.f90.

Function/Subroutine Documentation

gtvarcreate()

subroutine gtvarcreate	(	type(gt_variable), intent(out)	var,
		character(len = *), intent(in)	url,
		type(gt_variable), dimension(:), intent(in), optional	dims,
		character(len = *), intent(in), optional	xtype,
		character(len = *), intent(in), optional	long_name,
		logical, intent(in), optional	overwrite,
		logical, intent(out), optional	err )

Create variable with dimensions

Creates a variable of GT_VARIABLE type with dimensions dims at location url, and sets it to var. Like variables opened with Open, var must later be closed with Close.

If xtype is omitted, it defaults to "float". Creation fails if the variable already exists, but continues by overwriting if overwrite == .true.. (Note: overwrite behavior is not yet guaranteed.) Omitting dims means setting a 0-dimensional variable.

If an error occurs during creation, outputs a message and terminates. If err is provided, returns .true. and program does not terminate.

Parameters

[out]	var	Variable handle
[in]	url	Variable URL
[in]	dims	Dimension variables (optional)
[in]	xtype	Data type (optional, default "float")
[in]	long_name	Long name attribute (optional)
[in]	overwrite	Allow overwrite (optional)
[out]	err	Error flag (optional)

Definition at line 69 of file gtvarcreate.f90.

  use gtdata_types, only: gt_variable
  use gtdata_internal_map, only: var_class, vtb_class_netcdf, &
    & map_create, gtvar_dump
  use gtdata_netcdf_generic, only: create, put_attr, inquire
  use gtdata_netcdf_types, only: gd_nc_variable
  use dc_string, only: strhead
  use dc_error, only: storeerror, dc_noerr
  use dc_types, only: token
  use dc_trace, only: beginsub, endsub, dbgmessage
  implicit none
  type(GT_VARIABLE), intent(out):: var
  character(len = *), intent(in):: url
  type(GT_VARIABLE), intent(in), optional:: dims(:)
  character(len = *), intent(in), optional:: xtype
  character(len = *), intent(in), optional:: long_name
  logical, intent(in), optional:: overwrite
  logical, intent(out), optional:: err
  type(GD_NC_VARIABLE), allocatable:: gdnc_dims(:)
  type(GD_NC_VARIABLE):: gdnc
  integer, allocatable:: allcount(:)
  integer:: i, ndims, stat, cause_i
  character(len = TOKEN):: myxtype
  character(len = *),      parameter:: subname = "GTVarCreate"
  character(len = *),      parameter:: version = &
    & '$Name:  $' // &
    & '$Id: gtvarcreate.f90,v 1.4 2009-05-25 09:55:58 morikawa Exp $'
continue
  stat = dc_noerr
  ndims = 0
  cause_i = 0
  if (present(dims)) ndims = size(dims)
  call beginsub(subname, 'url=%c ndims=%d', c1=trim(url), i=(/ndims/), &
    & version=version)
  ! gdnc 変数の作成
  if (present(err)) err = .false.
  if (present(xtype)) then
    myxtype = xtype
  else
    myxtype = "float"
  endif
  if (present(dims)) then
    allocate(gdnc_dims(ndims), allcount(ndims))
    do, i = 1, ndims
      call var_class(dims(i), cid=gdnc_dims(i)%id)
      call dbgmessage('dim=%d mapid=%d -> cid=%d', i=(/i, dims(i)%mapid, gdnc_dims(i)%id/))
      call inquire(gdnc_dims(i), dimlen=allcount(i))
    enddo
    call create(var=gdnc, url=url, dims=gdnc_dims, xtype=myxtype, &
      & overwrite=overwrite, err=err)
  else
    ndims = 0
    allocate(gdnc_dims(1), allcount(1)) ! dummy
    call create(var=gdnc, url=url, dims=gdnc_dims(1:0), &
      & xtype=myxtype, overwrite=overwrite, err=err)
  endif
  call map_create(var, vtb_class_netcdf, gdnc%id, ndims, allcount, stat)
  if (stat /= dc_noerr) then
    cause_i = ndims
    goto 999
  end if
  deallocate(gdnc_dims, allcount)
  if (present(long_name)) then
    call put_attr(gdnc, 'long_name', long_name, err=err)
  endif
  call gtvar_dump(var)
  call dbgmessage('var%%mapid=%d', i=(/var % mapid/))
999 continue
  call storeerror(stat, subname, err, cause_i=cause_i)
  call endsub(subname)

References dc_trace::beginsub(), dc_trace::dbgmessage(), dc_error::dc_noerr, dc_trace::endsub(), gtdata_internal_map::gtvar_dump(), gtdata_internal_map::map_create(), dc_error::storeerror(), dc_types::token, and gtdata_internal_map::var_class().

Here is the call graph for this function: