gdncvarattr.f90

Go to the documentation of this file.

!> @file gdncvarattr.f90
!>
!> @author GFD Dennou Club
!> @copyright Copyright (C) GFD Dennou Club, 2000-2026. All rights reserved. <br/>
!>            License is BSD-2-Clause. See [COPYRIGHT](@ref COPYRIGHT) in detail
!>
!> @en
!> @brief Attribute enumeration for netCDF variables
!>
!> To enumerate all attributes of a variable:
!> 1. Call attr_rewind(var) to reset the iterator
!> 2. Call attr_next(var, name, [end]) in a loop
!> 3. name gives each attribute name; empty string when done
!> 4. Optionally, end becomes true when all attributes are enumerated
!>
!> Global attributes appear with '+' prefix added to their names.
!> @enden
!>
!> @ja
!> @brief netCDF 変数の属性列挙
!>
!> 変数のすべての属性を列挙するには:
!> 1. attr_rewind(var) を呼び出してイテレータをリセット
!> 2. ループ内で attr_next(var, name, [end]) を呼び出す
!> 3. name が各属性名を返す; 終了時は空文字列
!> 4. オプションで end が真になることでも終了を判定可能
!>
!> グローバル属性は名前の先頭に '+' が付加されて現れます。
!> @endja
!>
 
!>
!> @en
!> @brief Reset attribute iterator to beginning
!> @enden
!>
!> @ja
!> @brief 属性イテレータを先頭にリセット
!> @endja
!>
!> @param[in] var @en Variable handle @enden @ja 変数ハンドル @endja
!>
subroutine gdncvarattrrewind(var)
  use gtdata_netcdf_types, only: gd_nc_variable
  use gtdata_netcdf_internal, only: vtable_set_attrid
  use dc_trace, only: dbgmessage
  implicit none
  type(gd_nc_variable), intent(in):: var
  integer:: stat
  character(len = *), parameter:: subname = 'GDNcVarAttrRewind'
 
  stat = vtable_set_attrid(var, 0)
  call dbgmessage("%c %d", c1=subname, i=(/stat/))
end subroutine gdncvarattrrewind
 
!>
!> @en
!> @brief Get next attribute name in enumeration
!>
!> Returns the next attribute name. Variable attributes are returned first,
!> then global attributes (prefixed with '+').
!> @enden
!>
!> @ja
!> @brief 列挙の次の属性名を取得
!>
!> 次の属性名を返します。変数属性が先に返され、
!> その後グローバル属性 ('+' 接頭辞付き) が返されます。
!> @endja
!>
!> @param[in]  var  @en Variable handle @enden @ja 変数ハンドル @endja
!> @param[out] name @en Attribute name (empty string when done) @enden
!>                  @ja 属性名 (終了時は空文字列) @endja
!> @param[out] vend @en True when all attributes enumerated (optional) @enden
!>                  @ja 全属性列挙完了時に真 (省略可能) @endja
!>
subroutine gdncvarattrnext(var, name, vend)
  use gtdata_netcdf_types, only: gd_nc_variable, gd_nc_variable_entry
  use gtdata_netcdf_internal, only: vtable_set_attrid, vtable_lookup
  use netcdf, only: nf90_noerr, nf90_max_name, nf90_inq_attname, nf90_global
  use dc_url, only: gt_plus
  implicit none
  type(gd_nc_variable), intent(in):: var
  character(len = *), intent(out):: name
  type(gd_nc_variable_entry):: ent
  logical, intent(out), optional:: vend
  character(len = NF90_MAX_NAME):: attrname
  integer:: stat
  integer:: new_attrid
 
  stat = vtable_lookup(var, ent)
  if (stat /= nf90_noerr) goto 999
 
  new_attrid = ent%attrid
  ! 最初は変数属性の検索
  if (ent%attrid >= 0) then
    new_attrid = ent%attrid + 1
    stat = nf90_inq_attname(ent%fileid, ent%varid, new_attrid, attrname)
    if (stat == nf90_noerr) then
      name = attrname
      stat = vtable_set_attrid(var, new_attrid)
      vend = .false.
      return
    end if
    new_attrid = -1
  endif
 
  ! 次は大域属性の検索
  stat = nf90_inq_attname(ent%fileid, nf90_global, -new_attrid, attrname)
  if (stat == nf90_noerr) then
    new_attrid = new_attrid - 1
    name = gt_plus // attrname
    stat = vtable_set_attrid(var, new_attrid)
    vend = .false.
    return
  endif
 
999 continue
  ! ここでは attrid の再設定はしない。次呼んでもエラーになるのが適当。
  vend = .true.
  name = ""
  return
end subroutine gdncvarattrnext