dcdatetimezone.f90

Go to the documentation of this file.

! -*- mode: f90; coding: utf-8 -*-
!-----------------------------------------------------------------------
! Copyright (c) 2000-2026 Gtool Development Group. All rights reserved.
!-----------------------------------------------------------------------
!>
!> @author    Yasuhiro MORIKAWA
!> @copyright Copyright (C) GFD Dennou Club, 2000-2026. All rights reserved. <br/>
!>            License is BSD-2-Clause. see [COPYRIGHT](@ref COPYRIGHT) in detail
!> @en
!> @brief Procedures for timezone handling
!> @details
!> Procedures described in this file are provided from "dc_date" module.
!> @enden
!>
!> @ja
!> @brief タイムゾーンに関する手続き
!> @details
!> このファイルで提供される手続き群は dc_date モジュールにて提供されます。
!> @endja
!>
 
!> @en
!> @brief Set the timezone of a datetime
!> @details
!> Change the timezone of the argument `time` to `zone`.
!> The actual datetime is not changed.
!>
!> If an invalid value is given to the argument `zone`,
!> an error is raised.
!> If the argument `err` is given, .true. is returned to `err`
!> and the program continues.
!>
!> @param[inout] time Datetime to change timezone
!> @param[in]    zone Timezone to set (e.g., "+09:00")
!> @param[out]   err  Exception handling flag
!> @enden
!>
!> @ja
!> @brief 日時のタイムゾーンを設定
!> @details
!> 引数 `time` のタイムゾーンを `zone` へと変更します.
!> 実質的な日時は変更しません.
!>
!> 引数 `zone` に不適切な値が与えられた場合,
!> エラーを発生させます.
!> 引数 `err` を与えている場合には `err` に .true. が返り,
!> プログラムは続行します.
!>
!> @param[inout] time タイムゾーンを変更する日時
!> @param[in]    zone 設定するタイムゾーン (例: "+09:00")
!> @param[out]   err  例外処理用フラグ
!> @endja
subroutine dcdatetimesetzone(time, zone, err)
 
  use dc_types,      only: string
  use dc_date_types, only: dc_datetime, dc_difftime
  use dc_date_generic, only: validzone, zonetodiff, tochar, eval, &
    & operator(-), operator(+)
  use dc_error, only: storeerror, dc_ebadtimezone, dc_noerr
  use dc_message, only: messagenotify
  use dc_trace, only: beginsub, endsub
  use dc_string, only: stoi
  implicit none
  type(dc_datetime), intent(inout):: time
  character(*), intent(in):: zone
  logical, intent(out), optional:: err
  type(dc_difftime):: diff, diff_in
  integer :: stat
  character(STRING) :: zone_in, cause_c
  character(*), parameter :: subname = 'DCDateTimeSetZone'
continue
  call beginsub(subname, 'time=%c, zone=%c', &
    & c1=trim(tochar(time)), c2=trim(zone))
  stat = dc_noerr
  cause_c = ''
 
  if (.not. validzone(zone)) then
    stat = dc_ebadtimezone
    cause_c = zone
    if (present(err)) then
      call messagenotify('W', subname, &
        & 'zone=<%c> is invalid.', &
        & c1=trim(zone))
    else
      goto 999
    end if
  end if
 
  call eval(time, zone = zone_in)
  diff_in = zonetodiff(zone_in)
  diff = zonetodiff(zone)
 
  time = time + (diff_in - diff)
  time % zone = zone
 
999 continue
  call storeerror(stat, subname, err, cause_c)
  call endsub(subname, 'time=%c', &
    & c1=trim(tochar(time)))
end subroutine dcdatetimesetzone
 
!> @en
!> @brief Convert timezone string to DC_DIFFTIME
!> @details
!> Convert the given timezone to a dc_date_types#DC_DIFFTIME variable
!> and return it. If the timezone notation is invalid, it is
!> interpreted as if '+00:00' was given.
!>
!> @param[in] zone Timezone string (e.g., "+09:00")
!> @return Time difference corresponding to the timezone
!> @enden
!>
!> @ja
!> @brief タイムゾーン文字列を DC_DIFFTIME に変換
!> @details
!> 与えられるタイムゾーンを dc_date_types#DC_DIFFTIME 変数へと
!> 変換して返します. タイムゾーンの表記が無効な場合は '+00:00'
!> が与えられたと解釈します.
!>
!> @param[in] zone タイムゾーン文字列 (例: "+09:00")
!> @return タイムゾーンに対応する時間差
!> @endja
function dcdatetimezonetodiff(zone) result(diff)
 
  use dc_date_types, only: dc_difftime
  use dc_date_generic, only: validzone, dcdifftimecreate
  use dc_string, only: stoi
  implicit none
  type(dc_difftime):: diff
  character(*), intent(in):: zone
  integer:: hour, min, sgn
continue
  if (.not. validzone(zone)) then
    call dcdifftimecreate(diff)
  else
    if (zone(1:1) == '-') then
      sgn = 1
    else
      sgn = -1
    end if
    hour = stoi(zone(2:3))
    min = stoi(zone(5:6))
    call dcdifftimecreate(diff, hour = hour * sgn, min = min * sgn)
  end if
end function dcdatetimezonetodiff
 
!> @en
!> @brief Check if timezone notation is valid
!> @details
!> Returns .true. if the given timezone notation is valid,
!> .false. otherwise.
!>
!> The timezone notation should be like '+09:00', where the 1st character
!> is '+' or '-', 2nd-3rd and 5th-6th characters are digits,
!> and 4th character is ':'.
!>
!> @param[in] zone Timezone string to check
!> @return .true. if valid, .false. otherwise
!> @enden
!>
!> @ja
!> @brief タイムゾーン表記が有効かどうかをチェック
!> @details
!> 与えられるタイムゾーンの表記が有効であれば
!> .true. を, それ以外の場合は .false. を返します.
!>
!> タイムゾーンの表記は '+09:00' のように, 1 文字目が '+' または '-',
!> 2〜3, 5〜6 文字目が数値で, 4 文字目が ':' となります.
!>
!> @param[in] zone チェックするタイムゾーン文字列
!> @return 有効な場合は .true., それ以外は .false.
!> @endja
function dcdatetimevalidzone(zone) result(result)
 
  implicit none
  character(*), intent(in):: zone
  logical:: result
continue
  result = .false.
  if (len(zone) < 6) return
  if (verify(zone(1:1), '+-') /= 0) return
  if (verify(zone(2:3), '1234567890') /= 0) return
  if (verify(zone(5:6), '1234567890') /= 0) return
  if (zone(4:4) /= ':') return
  result = .true.
end function dcdatetimevalidzone