dc_url.f90

Go to the documentation of this file.

!-----------------------------------------------------------------------
! Copyright (c) 2000-2026 Gtool Development Group. All rights reserved.
!-----------------------------------------------------------------------
!>
!> @author    Youhei SASAKI, Yasuhiro MORIKAWA, Eizi TOYODA
!> @copyright Copyright (C) GFD Dennou Club, 2000-2026. All rights reserved. <br/>
!>            License is BSD-2-Clause. see [COPYRIGHT](@ref COPYRIGHT) in detail
!> @en
!> @brief Variable URL string parser
!> @details
!> This module provides procedures for parsing gtool4 variable URL strings.
!>
!> See "5. Various String Formats" of gtool4 netCDF convention
!> for variable URL format.
!>
!> @section url_procedures Procedures Summary
!>
!> | Procedure          | Description                                                    |
!> |--------------------|----------------------------------------------------------------|
!> | UrlSplit           | Split variable URL to filename, variable name, attribute name and I/O range |
!> | UrlMerge           | Merge filename, variable name, attribute name and I/O range to variable URL |
!> | UrlResolve         | Complement variable URL                                        |
!> | Url_Chop_IOrange   | Remove iorange from variable URL                               |
!> | UrlSearchIORange   | Get I/O range value for a dimension from variable URL          |
!> | operator(.OnTheSameFile.) | Check if two variable URLs point to the same file        |
!>
!> This module provides mnemonics for special characters in gtool4 variables.
!> When parsing gtool4 variables, use the variables provided here (GT_ATMARK, etc.)
!> instead of using characters directly.
!>
!> @enden
!>
!> @ja
!> @brief 変数 URL の文字列解析
!> @details
!> このモジュールは gtool4 変数 URL の文字列解析
!> を行うための手続きを提供します。
!>
!> gtool4 変数の書式に関しては,
!> gtool4 netCDF 規約の「5. 各種の文字列書式」を参照ください。
!>
!> @section url_procedures_ja 手続き群の要約
!>
!> | 手続名             | 説明                                                           |
!> |--------------------|----------------------------------------------------------------|
!> | UrlSplit           | 変数 URL を分解しファイル名、変数名、属性名および入出力範囲指定を取り出す |
!> | UrlMerge           | ファイル名、変数名、属性名および入出力範囲指定を連結して変数 URL を作成 |
!> | UrlResolve         | 変数 URL の補完                                                |
!> | Url_Chop_IOrange   | 変数 URL から iorange を除去                                   |
!> | UrlSearchIORange   | 変数 URL 内の iorange うち, ある次元に関する入出力範囲指定の値を取得 |
!> | operator(.OnTheSameFile.) | 2 つの変数 URL が同じファイルを指すかどうか判定            |
!>
!> このモジュールは gtool4 変数において特別な役割を果たす
!> 文字のニーモニックを提供します。gtool4 変数解析の際には、
!> 直接文字を用いるのではなく、ここで提供する変数群
!> (GT_ATMARK 等) を利用してください。
!>
!> @endja
!>
 
module dc_url
  implicit none
  private
 
  public:: url_chop_iorange
  public:: operator(.onthesamefile.)
 
  public:: urlmerge
  interface urlmerge
!    module procedure url_merge_v_vvv
    module procedure url_merge_cc
    module procedure url_merge_cccc
    module procedure url_merge_cccca
  end interface
 
  public:: urlsplit
  interface urlsplit
!    module procedure url_split_v
    module procedure url_split_c
  end interface
 
  public:: urlresolve
  interface urlresolve
    module procedure url_resolve_c
  end interface
 
  public:: urlsearchiorange
  interface urlsearchiorange
    module procedure url_search_iorange
  end interface
 
  interface operator(.onthesamefile.)
    module procedure urlonthesamefile
  end interface
 
  character, public, parameter:: gt_atmark = "@"
                                 ! ファイル名と変数名の区切りに用いられます。
  character, public, parameter:: gt_question = "?"
                                 ! ファイル名と変数名の区切りに用いられます。
  character, public, parameter:: gt_colon = ":"
                                 ! 変数の属性を示す時に用いられます。
  character, public, parameter:: gt_comma = ","
                                 ! 入出力範囲の限定に用いられます。
  character, public, parameter:: gt_equal = "="
                                 ! 入出力範囲の限定に用いられます。
  character, public, parameter:: gt_circumflex = "^"
                                 ! 座標の位置を値ではなく、
                                 ! 格子点番号で指定する時に用いられます。
  character, public, parameter:: gt_plus = "+"
                                 ! 属性の行頭にこの文字がつく場合、大域属性を示します。
 
contains
 
  ! ANUrlMerge - 変数 URL の合成
  ! 空文字列の成分はないとみなされる。
 
!  type(VSTRING) function &
!    & url_merge_v_vvv(file, var, attr, iorange) result(result) !:nodoc:
!    use dcstring_base, only: VSTRING, operator(.cat.), operator(/=), &
!      & extract, operator(==) !:nodoc:
!    implicit none
!    type(VSTRING), intent(in):: file
!    type(VSTRING), intent(in), optional:: var
!    type(VSTRING), intent(in), optional:: attr
!    type(VSTRING), intent(in), optional:: iorange
!    result = file .cat. GT_ATMARK
!    if (present(var)) result = result .cat. var
!    if (present(attr)) then
!      if (attr /= "") result = result .cat. GT_COLON .cat. attr
!    endif
!    if (present(iorange)) then
!      if (extract(iorange, 1, 1) == GT_COMMA) then
!        result = result .cat. iorange
!      else if (iorange /= "") then
!        result = result .cat. GT_COMMA .cat. iorange
!      endif
!    endif
!  end function
 
  !> @en
  !> @brief Merge filename and variable name to URL
  !> @details
  !> Concatenates filename `file` and variable name `var` and returns
  !> as `result`.
  !>
  !> @param[in] file Filename
  !> @param[in] var Variable name
  !> @return Merged variable URL
  !> @enden
  !>
  !> @ja
  !> @brief ファイル名と変数名を URL に結合
  !> @details
  !> ファイル名 `file`、変数名 `var` を結合して `result` として返します。
  !>
  !> @param[in] file ファイル名
  !> @param[in] var 変数名
  !> @return 結合された変数 URL
  !> @endja
  function url_merge_cc(file, var) result(result)
    use dc_types, only: string
    character(len = STRING):: result
    character(len = *), intent(in):: file
    character(len = *), intent(in):: var
  continue
    result = url_merge_cccc(file, var, "", "")
  end function url_merge_cc
 
  !> @en
  !> @brief Merge filename, variable name, attribute and I/O range array to URL
  !> @details
  !> Concatenates filename `file`, variable name `var`, attribute `attr`,
  !> and I/O range `iorange` and returns as `result`.
  !> `iorange` is given as a character array. Each element of the array
  !> is concatenated with GT_COMMA before merging.
  !>
  !> @param[in] file Filename
  !> @param[in] var Variable name
  !> @param[in] attr Attribute name
  !> @param[in] iorange I/O range specification (character array)
  !> @return Merged variable URL
  !> @enden
  !>
  !> @ja
  !> @brief ファイル名、変数名、属性、入出力範囲配列を URL に結合
  !> @details
  !> ファイル名 `file`、変数名 `var`、属性 `attr`、
  !> 入出力範囲 `iorange` を結合して `result` として返します。
  !> `iorange` には文字型配列を与えます。文字型配列のそれぞれの要素は
  !> GT_COMMA で連結されてから結合されます。
  !>
  !> @param[in] file ファイル名
  !> @param[in] var 変数名
  !> @param[in] attr 属性名
  !> @param[in] iorange 入出力範囲指定 (文字型配列)
  !> @return 結合された変数 URL
  !> @endja
  function url_merge_cccca(file, var, attr, iorange) result(result)
    use dc_types, only: string
    character(len = STRING):: result
    character(len = *), intent(in):: file
    character(len = *), intent(in):: var
    character(len = *), intent(in):: attr
    character(len = *), intent(in):: iorange(:)
    integer:: i
  continue
    if (file /= "") then
      result = trim(file) // gt_atmark
    else
      result = gt_atmark
    endif
    if (var /= "") result = trim(result) // var
    if (attr /= "") then
      result = trim(result) // gt_colon // attr
    endif
    do i = 1, size(iorange)
      if (iorange(i) /= "") then
        if (iorange(i)(1:1) == gt_comma) then
          result = trim(result) // trim(iorange(i))
        else
          result = trim(result) // gt_comma // trim(iorange(i))
        endif
      endif
    end do
  end function url_merge_cccca
 
  !> @en
  !> @brief Merge filename, variable name, attribute and I/O range to URL
  !> @details
  !> Concatenates filename `file`, variable name `var`, attribute `attr`,
  !> and I/O range `iorange` and returns as `result`.
  !>
  !> @param[in] file Filename
  !> @param[in] var Variable name
  !> @param[in] attr Attribute name
  !> @param[in] iorange I/O range specification
  !> @return Merged variable URL
  !> @enden
  !>
  !> @ja
  !> @brief ファイル名、変数名、属性、入出力範囲を URL に結合
  !> @details
  !> ファイル名 `file`、変数名 `var`、属性 `attr`、
  !> 入出力範囲 `iorange` を結合して `result` として返します。
  !>
  !> @param[in] file ファイル名
  !> @param[in] var 変数名
  !> @param[in] attr 属性名
  !> @param[in] iorange 入出力範囲指定
  !> @return 結合された変数 URL
  !> @endja
  function url_merge_cccc(file, var, attr, iorange) result(result)
    use dc_types, only: string
    character(len = STRING):: result
    character(len = *), intent(in):: file
    character(len = *), intent(in):: var
    character(len = *), intent(in):: attr
    character(len = *), intent(in):: iorange
  continue
    if (trim(file) /= "") then
      result = trim(file) // gt_atmark
    else
      result = gt_atmark
    endif
    if (trim(var) /= "") result = trim(result) // var
    if (trim(attr) /= "") then
      result = trim(result) // gt_colon // attr
    endif
    if (trim(iorange) /= "") then
      if (iorange(1:1) == gt_comma) then
        result = trim(result) // iorange
      else
        result = trim(result) // gt_comma // iorange
      endif
    endif
  end function url_merge_cccc
 
  !> @en
  !> @brief Remove I/O range from variable URL
  !> @details
  !> Separates the I/O range specification part and the remaining part
  !> from the variable URL given in `fullname`, and returns them in
  !> `iorange` and `remainder` respectively.
  !>
  !> @param[in] fullname Variable URL
  !> @param[out] iorange I/O range specification part
  !> @param[out] remainder Remaining part
  !> @enden
  !>
  !> @ja
  !> @brief 変数 URL から入出力範囲を除去
  !> @details
  !> `fullname` で与えられる変数 URL の入出力範囲指定部分と
  !> 残りの部分とを分離し、それぞれ `iorange` と `remainder` に返します。
  !>
  !> @param[in] fullname 変数 URL
  !> @param[out] iorange 入出力範囲指定部分
  !> @param[out] remainder 残りの部分
  !> @endja
  subroutine url_chop_iorange(fullname, iorange, remainder)
    use dc_types, only: string
    character(len = *), intent(in):: fullname
    character(len = *), intent(out):: iorange   ! 入出力範囲指定部分
    character(len = *), intent(out):: remainder ! 残りの部分
    character(STRING):: file, var, attr
    call urlsplit(fullname, file=file, var=var, attr=attr, iorange=iorange)
    remainder = url_merge_cccc(file=file, var=var, attr=attr, iorange="")
  end subroutine url_chop_iorange
 
  !> @en
  !> @brief Get I/O range value for a dimension from variable URL
  !> @details
  !> Gets the I/O range specification value for dimension `dimvar`
  !> from the variable URL `fullname`.
  !>
  !> `fullname` is given either as a complete gtool4 variable URL or
  !> as just the I/O range specification part.
  !> `dimvar` is given as the dimension variable name contained in
  !> the I/O range specification part.
  !> If a dimension variable corresponding to `dimvar` exists,
  !> its value is returned.
  !> If a dimension variable corresponding to `dimvar` does not exist,
  !> an empty string is returned.
  !>
  !> @param[in] fullname Variable URL or I/O range specification
  !> @param[in] dimvar Dimension variable name to search
  !> @return I/O range value for the dimension (empty if not found)
  !> @enden
  !>
  !> @ja
  !> @brief 変数 URL 内の次元に関する入出力範囲指定の値を取得
  !> @details
  !> 変数 URL `fullname` 内の, 次元 `dimvar` に関する
  !> 入出力範囲指定の値を取得します。
  !>
  !> `fullname` には gtool4 変数全体または入出力範囲指定部分の値を与えます。
  !> `dimvar` には入出力範囲指定部分に含まれる次元変数名を与えます。
  !> `dimvar` に対応する次元変数が存在する場合、その値を返します。
  !> `dimvar` に対応する次元変数が存在しない場合、空文字を返します。
  !>
  !> @param[in] fullname 変数 URL または入出力範囲指定
  !> @param[in] dimvar 検索する次元変数名
  !> @return 次元の入出力範囲値 (見つからない場合は空文字)
  !> @endja
  function url_search_iorange(fullname, dimvar) result(result)
    use dc_types, only: string
    use dc_string, only: split
    character(len = *), intent(in):: fullname
    character(len = *), intent(in):: dimvar
    character(len = STRING):: result
    character(STRING):: file, var, attr, iorange
    character(STRING), pointer :: ioranges_slice(:) => null()
    integer :: i, eqpos, atmark
  continue
    result = ""
    ! @ または ? が含まれているなら urlsplit で分離
    atmark = index(fullname, gt_question)
    if (atmark == 0) atmark = index(fullname, gt_atmark)
    if (atmark /= 0) then
      call urlsplit(fullname, file=file, var=var, attr=attr, iorange=iorange)
    else
      iorange = fullname
    end if
    call split(iorange, ioranges_slice, gt_comma)
    do i = 1, size(ioranges_slice)
      eqpos = index(ioranges_slice(i), gt_equal)
      if (ioranges_slice(i)(1:eqpos-1) == trim(dimvar)) then
        result = trim(ioranges_slice(i)(eqpos+1:))
        exit
      end if
    end do
    deallocate(ioranges_slice)
  end function url_search_iorange
 
  !> @en
  !> @brief Split variable URL to components
  !> @details
  !> Splits the variable URL given in `fullname` into filename `file`,
  !> variable name `var`, attribute name `attr`, and I/O range
  !> specification `iorange` and returns them.
  !> Components that are not found are assigned empty strings.
  !>
  !> @param[in] fullname Variable URL
  !> @param[out] file Filename (optional)
  !> @param[out] var Variable name (optional)
  !> @param[out] attr Attribute name (optional)
  !> @param[out] iorange I/O range specification (optional)
  !> @enden
  !>
  !> @ja
  !> @brief 変数 URL を各成分に分解
  !> @details
  !> `fullname` で与えられる変数 URL を、ファイル名 `file`、変数名 `var`、
  !> 属性名 `attr`、入出力範囲指定 `iorange` に分解して返します。
  !> 見つからない成分には空文字列が代入されます。
  !>
  !> @param[in] fullname 変数 URL
  !> @param[out] file ファイル名 (省略可能)
  !> @param[out] var 変数名 (省略可能)
  !> @param[out] attr 属性名 (省略可能)
  !> @param[out] iorange 入出力範囲指定 (省略可能)
  !> @endja
  subroutine url_split_c(fullname, file, var, attr, iorange)
    use dc_types, only: string
    character(len = *), intent(in):: fullname
    character(len = *), intent(out), optional:: file, var, attr, iorange
    character(len = STRING):: varpart
    integer:: atmark, colon, comma
    character(len = *), parameter:: VARNAME_SET &
      = "0123456789eEdD+-=^,.:_" &
      // "ABCDEFGHIJKLMNOPQRSTUVWXYZ" &
      // "abcdefghijklmnopqrstuvwxyz"
  continue
    ! まず URL と変数属性指定 (? または @ 以降) を分離する。
    ! URL は @ を含みうるため、最後の @ 以降に対して変数属性
    ! として許されない文字（典型的には '/'）が含まれていたら
    ! 当該 @ は URL の一部とみなす。
    atmark = index(fullname, gt_question)
    if (atmark == 0) then
      atmark = index(fullname, gt_atmark, back=.true.)
      if (atmark /= 0) then
        if (verify(trim(fullname(atmark+1: )), varname_set) /= 0) then
          atmark = 0
        endif
      endif
    endif
    if (atmark == 0) then
      ! 変数属性指定はなかった。
      if (present(file)) file = fullname
      if (present(var)) var = ''
      if (present(attr)) attr = ''
      if (present(iorange)) iorange = ''
      return
    endif
    varpart = fullname(atmark+1: )
    ! 変数属性指定があった。
    if (present(file)) file = fullname(1: atmark - 1)
    ! 範囲指定を探索する。
    comma = index(varpart, gt_comma)
    if (comma /= 0) then
      ! 範囲指定がみつかった。
      if (present(var)) var = varpart(1: comma - 1)
      if (present(attr)) attr = ''
      if (present(iorange)) iorange = varpart(comma + 1: )
      return
    endif
    if (present(iorange)) iorange = ''
    ! 範囲指定がなかったので、属性名の検索をする。
    colon = index(varpart, gt_colon)
    if (colon == 0) then
      if (present(var)) var = varpart
      if (present(attr)) attr = ''
      varpart = ''
      return
    endif
    if (present(var)) var = varpart(1: colon - 1)
    if (present(attr)) attr = varpart(colon + 1: )
    varpart = ''
  end subroutine url_split_c
 
!  subroutine url_split_v(fullname, file, var, attr, iorange) !:nodoc:
!    use dcstring_base, only: VSTRING, operator(.cat.), operator(/=), &
!      & extract, operator(==) !:nodoc:
!    use dc_string
!    implicit none
!    type(VSTRING), intent(in):: fullname
!    type(VSTRING), intent(out), optional::        file, var, attr, iorange
!    type(VSTRING):: varpart
!    integer:: atmark, colon, comma
!    character(len = *), parameter:: VARNAME_SET &
!      = "0123456789eEdD+-=^,.:_" &
!      // "ABCDEFGHIJKLMNOPQRSTUVWXYZ" &
!      // "abcdefghijklmnopqrstuvwxyz"
!  continue
!    ! まず URL と変数属性指定 (? または @ 以降) を分離する。
!    ! URL は @ を含みうるため、最後の @ 以降に対して変数属性
!    ! として許されない文字（典型的には '/'）が含まれていたら
!    ! 当該 @ は URL の一部とみなす。
!    atmark = vindex(fullname, GT_QUESTION)
!    if (atmark == 0) then
!      atmark = vindex(fullname, GT_ATMARK, .TRUE.)
!      if (atmark /= 0) then
!        varpart = extract(fullname, atmark + 1)
!        if (vverify(varpart, VARNAME_SET) /= 0) then
!          atmark = 0
!        endif
!      endif
!    endif
!    if (atmark == 0) then
!      ! 変数属性指定はなかった。
!      if (present(file)) file = fullname
!      if (present(var)) var = ''
!      if (present(attr)) attr = ''
!      if (present(iorange)) iorange = ''
!      return
!    endif
!    varpart = extract(fullname, atmark + 1)
!    ! 変数属性指定があった。
!    if (present(file)) file = extract(fullname, 1, atmark - 1)
!    ! 範囲指定を探索する。
!    comma = vindex(varpart, GT_COMMA)
!    if (comma /= 0) then
!      ! 範囲指定がみつかった。
!      if (present(var)) var = extract(varpart, 1, comma - 1)
!      if (present(attr)) attr = ''
!      if (present(iorange)) iorange = extract(varpart, comma + 1)
!      return
!    endif
!    if (present(iorange)) iorange = ''
!    ! 範囲指定がなかったので、属性名の検索をする。
!    colon = vindex(varpart, GT_COLON)
!    if (colon == 0) then
!      if (present(var)) var = varpart
!      if (present(attr)) attr = ''
!      varpart = ''
!      return
!    endif
!    if (present(var)) var = extract(varpart, 1, colon - 1)
!    if (present(attr)) attr = extract(varpart, colon + 1)
!    varpart = ''
!  end subroutine url_split_v
 
  !> @en
  !> @brief Check if two variable URLs point to the same file
  !> @details
  !> Determines whether the variable URL given as the first argument
  !> and the variable URL given as the second argument point to
  !> the same file.
  !> Returns `.true.` if they point to the same file,
  !> `.false.` if they point to different files.
  !>
  !> @param[in] url_a First variable URL
  !> @param[in] url_b Second variable URL
  !> @return .true. if same file, .false. otherwise
  !> @enden
  !>
  !> @ja
  !> @brief 2つの変数 URL が同じファイルを指すか判定
  !> @details
  !> 1 つ目の引数に与えられる変数 URL と 2 つ目の引数に与えられる
  !> 変数 URL とが同じファイルを指しているかどうか判定します。
  !> もしも同じファイルであれば `.true.` を、
  !> 異なるファイルであれば `.false.` を返します。
  !>
  !> @param[in] url_a 1つ目の変数 URL
  !> @param[in] url_b 2つ目の変数 URL
  !> @return 同じファイルなら .true., そうでなければ .false.
  !> @endja
  logical function urlonthesamefile(url_a, url_b) result(result)
    use dc_string
    use dc_types, only: string
    character(len = *), intent(in) :: url_a
    character(len = *), intent(in) :: url_b
    character(len = STRING)        :: filepart_a
    character(len = STRING)        :: filepart_b
    call urlsplit(url_a, file=filepart_a)
    call urlsplit(url_b, file=filepart_b)
    result = (filepart_a == filepart_b)
  end function urlonthesamefile
 
  !> @en
  !> @brief Complement variable URL
  !> @details
  !> If the variable URL given in `relative` is incomplete (missing
  !> filename, variable name, attribute name, or I/O range specification),
  !> it is complemented from `base`.
  !>
  !> @param[in] relative Relative variable URL to complement
  !> @param[in] base Base variable URL for complementing
  !> @return Complemented variable URL
  !> @enden
  !>
  !> @ja
  !> @brief 変数 URL の補完
  !> @details
  !> `relative` で与えられる変数 URL が完全でない (ファイル名、変数名、
  !> 属性名、入出力範囲指定のどれかが無い) 場合に、`base`
  !> から補完します。
  !>
  !> @param[in] relative 補完する相対変数 URL
  !> @param[in] base 補完に使用する基準変数 URL
  !> @return 補完された変数 URL
  !> @endja
  function url_resolve_c(relative, base) result(result)
    use dc_string, only: strhead
    use dc_types, only: string
    use dc_trace, only: beginsub, endsub, dbgmessage
    implicit none
    character(len = *), intent(in):: relative
    character(len = *), intent(in):: base
    character(len = STRING):: result
    integer, parameter:: file = 1, var = 2, attr = 3, ior = 4
    character(len = STRING):: rel(file:ior), bas(file:ior)
    character(3), parameter:: pathdelim = "/:" // achar(94)
    integer:: idir_r, idir_b
  continue
    call beginsub('urlresolve', 'rel=<%c> base=<%c>', c1=relative, c2=base)
    call urlsplit(trim(relative), file=rel(file), var=rel(var), &
      & attr=rel(attr), iorange=rel(ior))
    call dbgmessage('rel -> file=<%c> var=<%c> attr=<%c>', &
      & c1=trim(rel(file)), c2=trim(rel(var)), &
      & c3=(trim(rel(attr)) // '> ior=<' // trim(rel(ior))))
    call urlsplit(base, file=bas(file), var=bas(var), &
      & attr=bas(attr), iorange=bas(ior))
    call dbgmessage('base -> file=<%s> var=<%s> attr=<%s> ior=<%s>', &
      & c1=trim(bas(file)), c2=trim(bas(var)), &
      & c3=(trim(bas(attr)) // '> ior=<' // trim(bas(ior))))
    ! --- ファイル名を欠くばあいは単に補う ---
    if (rel(file) == "") then
      rel(file) = bas(file)
      if (rel(var) == "") &
        & rel(var) = bas(var)
      result = urlmerge(file=rel(file), var=rel(var), &
        & attr=rel(attr), iorange=rel(ior))
      call endsub('urlresolve', '1 result=%c', c1=trim(result))
      return
    endif
    ! --- 絶対パス (と見られる) ファイル名はそのまま使用 ---
    if (strhead(rel(file), "file:") &
      & .OR. strhead(rel(file), "http:") &
      & .OR. strhead(rel(file), "ftp:") &
      & .OR. strhead(rel(file), "news:") &
      & .OR. strhead(rel(file), "www") &
      & .OR. strhead(rel(file), "/") &
      & .OR. strhead(rel(file), achar(94)) &
      & .OR. rel(file)(2:2) == ":" &
      ) then
      result = relative
      call endsub('urlresolve', '2 result=%c', c1=trim(result))
      return
    endif
    ! ディレクトリ名の取り出し
    idir_b = scan(bas(file), pathdelim, back=.true.) 
    if (idir_b == 0) then
      ! が、できなければ、（エラーとすべきかもしれぬが）
      ! 相対パスをそのまま使用
      result = relative
      call endsub('urlresolve', '3 result=%c', c1=trim(result))
      return
    endif
    ! 相対パスのほうのディレクトリ名の取り出し
    idir_r = scan(rel(file), pathdelim, back=.true.)
    if (idir_r == 0) then
      ! ができなければ全体を使用
      idir_r = 1
    endif
    result = base(1: idir_b) // relative(idir_r: )
    call endsub('urlresolve', '4 result=%c', c1=trim(result))
  end function url_resolve_c
 
  !> @namespace dc_url
end module dc_url