dc_args::dcargsoption Interface Reference

Public Member Functions
subroutine	dcargsoption0 (arg, options, flag, value, help)

Detailed Description

Definition at line 291 of file dc_args.f90.

Member Function/Subroutine Documentation

dcargsoption0()

subroutine dc_args::dcargsoption::dcargsoption0	(	type(args), intent(inout)	arg,
		character(len = *), dimension(:), intent(in)	options,
		logical, intent(out)	flag,
		character(len = *), intent(out), optional	value,
		character(len = *), intent(in), optional	help )

コマンドライン引数オプションを取得するための設定

オプション情報の登録と取得を行います.

コマンドライン引数のうち, options に与えるオプションに関する情 報を flag と value に取得します. options がコマンドライン 引数に与えられていれば flag に .true. が, そうでない場合は .false. が返ります. オプションに値が指定される場合は value に その値が返ります. オプション自体が与えられていない場合には value には空文字が返ります.

help には options に関するヘルプメッセージを arg に 登録します. サブルーチン DCArgsHelp を 用いた際に, このメッセージが出力されます. value を与えているかどうでこのメッセージは変化します.

オプションの書式

コマンドライン引数のうち, オプションと判定されるのは以下の場合です.

• 1 文字目が '-' の場合. この場合は短いオプションとなり, '-' の次の一文字のみがオプションとして有効になります.
• 1-2文字目が '–' (ハイフン 2 文字) の場合. この場合は長いオプションとなり, '–' 以降の文字列がオプションとして有効になります.

オプションの値は, "=" よりも後ろの文字列になります.

Parameters

[in,out]	arg	ARGS 型変数
[in]	options	オプション名の配列 (例: '-s', '–size')
[out]	flag	オプションが見つかった場合に .true. を返す
[out]	value	オプション値が指定されている場合にその値を返す (省略可能)
[in]	help	このオプションのヘルプメッセージ (省略可能)

Definition at line 558 of file dc_args.f90.

    use dc_message, only: messagenotify
    implicit none
    type(ARGS), intent(inout) :: arg
    character(len = *), intent(in) :: options(:)
    logical, intent(out) :: flag
    character(len = *), intent(out), optional :: value
    character(len = *), intent(in), optional :: help
    integer :: i, j, options_size, table_size
    type(OPT_ENTRY), allocatable :: local_tables(:)
    character(len = STRING) :: opt_name, opt_value, opt_full
    character(len = *), parameter  :: subname = 'DCArgsOption'
  continue
    flag = .false.
    if (present(value)) value = ''
    if (.not. arg % initialized) then
      call messagenotify('W', subname, 'Call Open before Option in dc_args.')
      call dcargsopen(arg)
    end if
    options_size = size(options)
    if (options_size < 1) then
      return
    end if
 
    !-----------------------------------
    ! 構造体 ARGS へのヘルプメッセージ用の情報登録
    ! * まずはテーブル arg % opt_table を一つ広げる.
    !-----------------------------------
    if ( .not. associated( arg % opt_table ) ) then
      ! 1 つめのオプション指定
      !
      table_size = 0
      allocate(arg % opt_table(table_size + 1))
    else
      ! 2 つめ以降のオプション指定
      !
      table_size = size(arg % opt_table)
      allocate(local_tables(table_size))
      local_tables(1:table_size) = arg % opt_table(1:table_size)
      deallocate(arg % opt_table)
      allocate(arg % opt_table(table_size + 1))
      arg % opt_table(1:table_size) = local_tables(1:table_size)
      deallocate(local_tables)
    end if
 
    !----- 値の代入 -----
    allocate(arg % opt_table(table_size + 1) % options(options_size))
    arg % opt_table(table_size + 1) % options = options
    arg % opt_table(table_size + 1) % help_message = ''
    if (present(help)) then
      arg % opt_table(table_size + 1) % help_message = help
    end if
    arg % opt_table(table_size + 1) % optvalue_flag = present(value)
 
 
    !----- options の正規化 -----
    do i = 1, options_size
      opt_full = arg % opt_table(table_size + 1) % options(i)
      if (dcoptionformc(opt_full, opt_name, opt_value)) then
        arg % opt_table(table_size + 1) % options(i) = opt_name
      else
        if (len(trim(adjustl(opt_full))) < 2) then
          arg % opt_table(table_size + 1) % options(i) = &
            & '-' // trim(adjustl(opt_full))
        else
          arg % opt_table(table_size + 1) % options(i) = &
            & '--' // trim(adjustl(opt_full))
        end if
      end if
    end do
 
    ! arg % cmd_opts_list 内の探査と flag, value への代入
    ! 呼ばれたものに関しては arg % cmd_opts_list % flag_called を
    ! .true. に
    do i = 1, options_size
      do j = 1, size(arg % cmd_opts_list)
        if (trim(arg % opt_table(table_size + 1) % options(i)) &
          &             == trim(arg % cmd_opts_list(j) % name)) then
          flag = .true.
          if (present(value)) then
            value = arg % cmd_opts_list(j) % value
          end if
          arg % cmd_opts_list(j) % flag_called = .true.
        end if
      end do
    end do

---

The documentation for this interface was generated from the following file:

• dc_utils/dc_args.f90