hstnmlinfooutputstep.f90

Go to the documentation of this file.

!> @file hstnmlinfooutputstep.f90
!>
!> @author Yasuhiro MORIKAWA
!> @copyright Copyright (C) GFD Dennou Club, 2007-2026. All rights reserved. <br/>
!>            License is BSD-2-Clause. See [COPYRIGHT](@ref COPYRIGHT) in detail
!>
!> @en
!> @brief Checker of output timing
!> @enden
!>
!> @ja
!> @brief 出力タイミングのチェック
!> @endja
 
  !> @en
  !> @brief Check output timing of a variable
  !>
  !> If @p time is the time that a variable @p name is output,
  !> .true. is returned, otherwise .false. is returned.
  !> When @p gthstnml is not initialized, .false. is returned too.
  !> When data corresponding to @p name is not found, .false. is returned too.
  !>
  !> If @p gthstnml is not initialized by HstNmlInfoCreate yet,
  !> error is occurred.
  !> @enden
  !>
  !> @ja
  !> @brief 出力タイミングのチェック
  !>
  !> @p time が変数 @p name の出力されるタイミングであれば
  !> .true. を, そうでなければ .false. を返します.
  !> @p gthstnml が初期設定されていない場合にも .false. が返ります.
  !> @p name に関するデータが存在しない場合にも .false. が返ります.
  !>
  !> なお, 与えられた @p gthstnml が HstNmlInfoCreate によって初期設定
  !> されていない場合, プログラムはエラーを発生させます.
  !> @endja
  !>
  !> @param[in] gthstnml gtool_history_nmlinfo_types::GTHST_NMLINFO 型変数
  !> @param[in] name 変数名. 先頭の空白は無視されます.
  !>                 Variable identifier. Blanks at the head of the name are ignored.
  !> @param[in] time 現在時刻. Current time
  !> @return 出力タイミングであれば .true.
  logical function hstnmlinfooutputstep( gthstnml, &
    & name, time ) result(result)
    use gtool_history_nmlinfo_types, only: gthst_nmlinfo, gthst_nmlinfo_entry
    use gtool_history_nmlinfo_internal, only: listsearch
    use dc_date_types, only: dc_difftime
    use dc_date_generic, only: dcdifftimecreate, mod, operator(==)
    use dc_types, only: dp
    implicit none
    type(gthst_nmlinfo), intent(in):: gthstnml
    character(*), intent(in):: name
                              ! 変数名. 
                              ! 先頭の空白は無視されます. 
                              ! 
                              ! Variable identifier. 
                              ! Blanks at the head of the name are ignored. 
    type(dc_difftime), intent(in):: time
                              ! 現在時刻. Current time
 
    !-----------------------------------
    !  作業変数
    !  Work variables
    type(gthst_nmlinfo_entry), pointer:: hptr =>null()
    type(dc_difftime):: interval_time
!!$    character(*), parameter:: subname = 'HstNmlInfoOutputStep'
  continue
 
    result = .false.
 
    !-----------------------------------------------------------------
    !  初期設定のチェック
    !  Check initialization
    !-----------------------------------------------------------------
    if ( .not. gthstnml % initialized ) goto 999
 
    !-----------------------------------------------------------------
    !  情報格納変数への結合
    !  Associate a variable storing information
    !-----------------------------------------------------------------
    hptr => gthstnml % gthstnml_list
    call listsearch( gthstnml_list = hptr, & ! (inout)
      &              name = name )           ! (in)
 
    if ( .not. associated( hptr ) ) goto 999
    if ( hptr % output_step_disable ) goto 999
 
    !-----------------------------------------------------------------
    !  時刻のチェック
    !  Check time
    !-----------------------------------------------------------------
    if ( .not. hptr % interval_value > 0.0 ) goto 999
 
    call dcdifftimecreate( &
      & diff = interval_time, &                      ! (out)
      & value = real( hptr % interval_value, dp ), & ! (in)
      & unit = hptr % interval_unit )                ! (in)
 
    if ( mod( time, interval_time ) == 0 ) then
      result = .true.
    end if
 
    !-----------------------------------------------------------------
    !  終了処理, 例外処理
    !  Termination and Exception handling
    !-----------------------------------------------------------------
999 continue
    nullify( hptr )
  end function hstnmlinfooutputstep