hstnmlinfonames.f90

Go to the documentation of this file.

!> @file hstnmlinfonames.f90
!>
!> @author Yasuhiro MORIKAWA
!> @copyright Copyright (C) GFD Dennou Club, 2007-2026. All rights reserved. <br/>
!>            License is BSD-2-Clause. See [COPYRIGHT](@ref COPYRIGHT) in detail
!>
!> @en
!> @brief Return list of variables
!> @enden
!>
!> @ja
!> @brief 変数リストの取得
!> @endja
 
  !> @en
  !> @brief Return list of registered variable identifiers
  !>
  !> List of variables registered in @p gthstnml is joined with comma,
  !> and returned.
  !>
  !> If @p gthstnml is not initialized by HstNmlInfoCreate yet,
  !> blank is returned.
  !> @enden
  !>
  !> @ja
  !> @brief 登録されている変数名リストを返す
  !>
  !> @p gthstnml に設定されている変数リストをカンマでつなげて
  !> 返します.
  !>
  !> なお, 与えられた @p gthstnml が HstNmlInfoCreate によって初期設定
  !> されていない場合, 空文字が返ります.
  !> @endja
  !>
  !> @param[in] gthstnml gtool_history_nmlinfo_types::GTHST_NMLINFO 型変数
  !> @return 変数名をカンマで結合した文字列
  function hstnmlinfonames( gthstnml ) result(result)
    use gtool_history_nmlinfo_types, only: gthst_nmlinfo, gthst_nmlinfo_entry
    use gtool_history_nmlinfo_internal, only: listnext
    use gtool_history_nmlinfo_internal, only: name_delimiter
    use dc_types, only: string
    implicit none
    character(STRING):: result
    type(gthst_nmlinfo), intent(in):: gthstnml
 
    !-----------------------------------
    !  作業変数
    !  Work variables
    type(gthst_nmlinfo_entry), pointer:: hptr =>null()
    logical:: first
!!$    character(*), parameter:: subname = 'HstNmlInfoNames'
  continue
 
    result = ''
    first = .true.
 
    !-----------------------------------------------------------------
    !  初期設定のチェック
    !  Check initialization
    !-----------------------------------------------------------------
    if ( .not. gthstnml % initialized ) goto 999
 
    !-----------------------------------------------------------------
    !  情報の取り出し
    !  Fetch information
    !-----------------------------------------------------------------
    hptr => gthstnml % gthstnml_list
    do while ( associated( hptr % next ) )
      call listnext( gthstnml_list = hptr ) ! (inout)
      if ( first ) then
        result = adjustl( hptr % name )
        first = .false.
      else
        result = trim( result ) // name_delimiter // adjustl( hptr % name )
      end if
    end do
 
    !-----------------------------------------------------------------
    !  終了処理, 例外処理
    !  Termination and Exception handling
    !-----------------------------------------------------------------
999 continue
    nullify( hptr )
  end function hstnmlinfonames