hstnmlinfodelete.f90

Go to the documentation of this file.

!> @file hstnmlinfodelete.f90
!>
!> @author Yasuhiro MORIKAWA
!> @copyright Copyright (C) GFD Dennou Club, 2007-2026. All rights reserved. <br/>
!>            License is BSD-2-Clause. See [COPYRIGHT](@ref COPYRIGHT) in detail
!>
!> @en
!> @brief Delete output information of a variable
!> @enden
!>
!> @ja
!> @brief 変数の出力情報の削除
!> @endja
 
  !> @en
  !> @brief Delete output information of a variable
  !>
  !> Delete output information of a variable.
  !>
  !> If @p gthstnml is not initialized by HstNmlInfoCreate yet,
  !> error is occurred.
  !> @enden
  !>
  !> @ja
  !> @brief 変数の出力情報を削除する
  !>
  !> 変数の出力情報を削除します.
  !>
  !> なお, 与えられた @p gthstnml が HstNmlInfoCreate によって初期設定
  !> されていない場合, プログラムはエラーを発生させます.
  !> @endja
  !>
  !> @param[inout] gthstnml gtool_history_nmlinfo_types::GTHST_NMLINFO 型変数
  !> @param[in] name 変数名. 先頭の空白は無視されます.
  !>                 "Data1,Data2" のようにカンマで区切って複数指定可能.
  !>                 Variable identifier. Blanks at the head of the name are ignored.
  !>                 Multiple variables can be specified as "Data1,Data2".
  !> @param[out] err 例外処理用フラグ. Exception handling flag.
  recursive subroutine hstnmlinfodelete( gthstnml, &
    & name, &
    & err )
    use gtool_history_nmlinfo_types, only: gthst_nmlinfo, gthst_nmlinfo_entry
    use gtool_history_nmlinfo_internal, only: listsearch, name_delimiter
    use dc_trace, only: beginsub, endsub, dbgmessage
    use dc_string, only: split
    use dc_present, only: present_and_not_empty, present_and_true
    use dc_types, only: string, token
    use dc_error, only: storeerror, dc_noerr, dc_enotinit, usr_errno, hst_enotindefine
    implicit none
    type(gthst_nmlinfo), intent(inout):: gthstnml
    character(*), intent(in):: name
                              ! 変数名. 
                              ! 
                              ! 先頭の空白は無視されます. 
                              ! 
                              ! "Data1,Data2" のようにカンマで区切って複数
                              ! の変数を指定することが可能です. 
                              ! 
                              ! Variable identifier. 
                              ! 
                              ! Blanks at the head of the name are ignored. 
                              ! 
                              ! Multiple variables can be specified 
                              ! as "Data1,Data2". Delimiter is comma. 
                              ! 
    logical, intent(out), optional:: err
                              ! 例外処理用フラグ. 
                              ! デフォルトでは, この手続き内でエラーが
                              ! 生じた場合, プログラムは強制終了します. 
                              ! 引数 *err* が与えられる場合, 
                              ! プログラムは強制終了せず, 代わりに
                              ! *err* に .true. が代入されます. 
                              !
                              ! Exception handling flag. 
                              ! By default, when error occur in 
                              ! this procedure, the program aborts. 
                              ! If this *err* argument is given, 
                              ! .true. is substituted to *err* and 
                              ! the program does not abort. 
 
    !-----------------------------------
    !  作業変数
    !  Work variables
    type(gthst_nmlinfo_entry), pointer:: hptr =>null()
    type(gthst_nmlinfo_entry), pointer:: hptr_prev =>null()
    type(gthst_nmlinfo_entry), pointer:: hptr_next =>null()
    character(TOKEN), pointer:: varnames_array(:) =>null()
    integer:: i, vnmax
    integer:: stat
    character(STRING):: cause_c
    character(*), parameter:: subname = 'HstNmlInfoDelete'
  continue
    call beginsub( subname, &
      & fmt = '@name=%c', &
      & c1 = trim( name ) )
    stat = dc_noerr
    cause_c = ''
 
    !-----------------------------------------------------------------
    !  初期設定のチェック
    !  Check initialization
    !-----------------------------------------------------------------
    if ( .not. gthstnml % initialized ) then
      stat = dc_enotinit
      cause_c = 'GTHST_NMLINFO'
      goto 999
    end if
 
    if ( .not. gthstnml % define_mode ) then
      stat = hst_enotindefine
      cause_c = 'Delete'
      goto 999
    end if
 
    !-----------------------------------------------------------------
    !  複数の変数を削除する場合
    !  Delete multiple variables
    !-----------------------------------------------------------------
    if ( present_and_not_empty(name) ) then
      if ( index(name, name_delimiter) > 0 ) then
        call dbgmessage( 'multiple entries (%c) will be deleted', c1 = trim(name) )
        call split( str = name, sep = name_delimiter, & ! (in)
          & carray = varnames_array )                   ! (out)
        vnmax = size( varnames_array )
 
        do i = 1, vnmax
          call hstnmlinfodelete( &
            & gthstnml = gthstnml, &      ! (inout)
            & name = varnames_array(i), & ! (in)
            & err = err )                 ! (out)
          if ( present_and_true( err ) ) then
            deallocate( varnames_array )
            stat = usr_errno
            goto 999
          end if
        end do
        deallocate( varnames_array )
        goto 999
      end if
    end if
 
    !-----------------------------------------------------------------
    !  *gthstnml* の情報を削除.
    !  Delete information in *gthstnml*
    !-----------------------------------------------------------------
    hptr => gthstnml % gthstnml_list
    call listsearch( gthstnml_list = hptr, & ! (inout)
      &              name = name, &          ! (in)
      &              previous = hptr_prev, & ! (out)
      &              next = hptr_next )      ! (out)
 
    if ( .not. associated( hptr ) ) goto 999
    if ( ( trim(hptr % name) /= '' ) .and. associated( hptr_prev ) ) then
      call dbgmessage( 'entry (%c) is deleted', c1 = trim( adjustl( name ) ) )
      hptr_prev % next => hptr_next
      deallocate( hptr )
    end if
 
    !-----------------------------------------------------------------
    !  終了処理, 例外処理
    !  Termination and Exception handling
    !-----------------------------------------------------------------
999 continue
    call storeerror( stat, subname, err, cause_c )
    call endsub( subname )
  end subroutine hstnmlinfodelete