gtvartmpnam.f90

Go to the documentation of this file.

!> @file gtvartmpnam.f90
!>
!> @author Eizi TOYODA, Yasuhiro MORIKAWA
!> @copyright Copyright (C) GFD Dennou Club, 2000-2026. All rights reserved. <br/>
!>            License is BSD-2-Clause. See [COPYRIGHT](@ref COPYRIGHT) in detail
!>
!> @en
!> @brief Auto-create variable name
!>
!> This subroutine is provided as gtdata_generic#GTDataTmpNam
!> through gtdata_generic.
!> @enden
!>
!> @ja
!> @brief 変数名の自動作成
!>
!> このサブルーチンは gtdata_generic から gtdata_generic#GTDataTmpNam
!> として提供されます。
!> @endja
!>
 
!>
!> @en
!> @brief Create unique variable name
!>
!> Creates file@base from filename file and variable name base,
!> returns in result.
!> If file is empty, gtool.nc is used as the filename.
!> If base is empty, tmp is used as the variable name.
!> @param[in]  file   Filename
!> @param[in]  base   Base variable name
!> @param[out] result Generated unique variable URL
!> @enden
!>
!> @ja
!> @brief 一意な変数名を作成
!>
!> ファイル名 file と変数名 base から file@base を作成して result に返す。
!> file が空文字の場合は gtool.nc がファイル名として代用され、
!> base が空文字の場合は tmp が変数名として代用される。
!> @param[in]  file   ファイル名
!> @param[in]  base   ベース変数名
!> @param[out] result 生成された一意な変数URL
!> @endja
!>
subroutine gtvartmpnam(file, base, result)
  use dc_types, only: string
  use dc_url, only: urlmerge
  use gtdata_generic, only: open, close
  use gtdata_types, only: gt_variable
  implicit none
  character(len = *), intent(in):: file
  character(len = *), intent(in):: base
  character(len = *), intent(out):: result
  type(gt_variable):: var
  integer:: n
  logical:: failed
  character(len = STRING):: fnam, vnam, vnambase
continue
  if (file == "") then
    fnam = "gtool.nc"
  else
    fnam = file
  endif
  if (base == "") then
    vnambase = "tmp"
  else
    vnambase = base
  endif
  n = 0
  do
    n = n + 1
    ! compatibility note (2001-12-02, TOYODA Eizi)
    ! dc_string の toChar を使いたいのだが FQS Fortran が失敗する
    write(unit=vnam, fmt="(i32)") n
    vnam = trim(vnambase) // trim(adjustl(vnam))
    result = urlmerge(file=fnam, var=vnam)
    call open(var, result, writable=.false., err=failed)
    if (failed) return
    call close(var)
  enddo
end subroutine gtvartmpnam