gtvarsliceauto.f90

Go to the documentation of this file.

!> @file gtvarsliceauto.f90
!>
!> @author Eizi TOYODA, Yasuhiro MORIKAWA
!> @copyright Copyright (C) GFD Dennou Club, 2000-2026. All rights reserved. <br/>
!>            License is BSD-2-Clause. See [COPYRIGHT](@ref COPYRIGHT) in detail
!>
!> @en
!> @brief Automatic I/O range specification
!>
!> This subroutine is provided as gtdata_generic#Slice
!> through gtdata_generic.
!> @enden
!>
!> @ja
!> @brief 入出力範囲の自動指定
!>
!> このサブルーチンは gtdata_generic から gtdata_generic#Slice
!> として提供されます。
!> @endja
!>
 
!>
!> @en
!> @brief Automatically specify I/O range
!>
!> Makes the I/O range of variable var "appropriately" small.
!> If compatible is specified, sets it to the exact same I/O range
!> as that variable.
!>
!> Slice is a generic name for multiple subroutines; there are also
!> methods to specify by string or number.
!>
!> Related procedures to Slice include Get_Slice and Slice_Next.
!> Get_Slice retrieves the set I/O range.
!> Slice_Next is used to read the entire variable by moving the I/O range.
!> @param[inout] var        Variable handle
!> @param[in]    compatible Variable to match I/O range (optional)
!> @enden
!>
!> @ja
!> @brief 入出力範囲を自動指定
!>
!> 変数 var の入出力範囲を「適当に」小さくします。
!> compatible を指定すると、その変数と全く同じ入出力範囲に指定します。
!>
!> Slice は複数のサブルーチンの総称名であり、
!> 他にも文字列や番号で指定する方法があります。
!>
!> Slice に関連する手続きとして、Get_Slice と Slice_Next があります。
!> Get_Slice は設定された入出力範囲を取得します。
!> Slice_Next は入出力範囲を移動することによって、変数全体を読み取る
!> ために利用するサブルーチンです。
!> @param[inout] var        変数ハンドル
!> @param[in]    compatible 入出力範囲を合わせる変数 (省略可能)
!> @endja
!>
subroutine gtvarsliceauto(var, compatible)
  use gtdata_types, only: gt_variable
  use gtdata_generic, only: inquire, get_slice, gtvarslice
  type(gt_variable), intent(inout):: var
  type(gt_variable), intent(in), optional:: compatible
  integer:: nd, i
  integer, allocatable:: start(:), count(:), stride(:)
  call inquire(var, alldims=nd)
  if (nd <= 0) return
  allocate(start(nd), count(nd), stride(nd))
  if (present(compatible)) then
    call get_slice(compatible, start, count, stride)
    do, i = 1, nd
      call gtvarslice(var, i, start(i), count(i), stride(i))
    enddo
  else
    call get_slice(var, start, count, stride)
    do, i = 1, nd
      if (count(i) < 1) count(i) = 1
      call gtvarslice(var, i, start(i), count(i), stride(i))
    enddo
  endif
  deallocate(start, count, stride)
end subroutine gtvarsliceauto