gtvarputattrchar.f90

Go to the documentation of this file.

!> @file gtvarputattrchar.f90
!>
!> @author Eizi TOYODA, Yasuhiro MORIKAWA
!> @copyright Copyright (C) GFD Dennou Club, 2000-2026. All rights reserved. <br/>
!>            License is BSD-2-Clause. See [COPYRIGHT](@ref COPYRIGHT) in detail
!>
!> @en
!> @brief Put attribute values
!>
!> These subroutines are provided as gtdata_generic#Put_Attr
!> through gtdata_generic.
!> @enden
!>
!> @ja
!> @brief 属性の付加
!>
!> これらのサブルーチンは gtdata_generic から gtdata_generic#Put_Attr
!> として提供されます。
!> @endja
!>
 
!>
!> @en
!> @brief Put attribute value (logical)
!>
!> Attaches attribute name with value to variable var.
!> Put_Attr is a generic name for multiple subroutines, so value
!> can accept various types. Some variants with xtype argument
!> allow specifying the storage type independently.
!>
!> If an error occurs and err is provided, err returns .true..
!> If err is not provided, the program terminates.
!> @param[inout] var   Variable handle
!> @param[in]    name  Attribute name
!> @param[in]    value Attribute value (logical)
!> @param[out]   err   Error flag (optional)
!> @enden
!>
!> @ja
!> @brief 属性値の付加 (論理型)
!>
!> 変数 var に属性名 name とその値 value を付加します。
!> Put_Attr は複数のサブルーチンの総称名なので、
!> value には様々な型の変数を与えることが可能です。
!> xtype 引数を持つバリアントでは、格納型を独立に指定できます。
!>
!> エラーが発生した場合、引数 err が与えられる場合は err が
!> .true. となって返ります。err を与えなければプログラムは停止します。
!> @param[inout] var   変数ハンドル
!> @param[in]    name  属性名
!> @param[in]    value 属性値 (論理型)
!> @param[out]   err   エラーフラグ (省略可能)
!> @endja
!>
subroutine gtvarputattrlogical(var, name, value, err)
  use gtdata_types, only: gt_variable
  use gtdata_internal_map, only: var_class, vtb_class_netcdf
  use gtdata_netcdf_generic, only: put_attr
  use gtdata_netcdf_types, only: gd_nc_variable
  use dc_string, only: tochar
  implicit none
  type(gt_variable),  intent(inout)        :: var
  character(len = *), intent(in)           :: name
  logical,            intent(in)           :: value
  logical,            intent(out), optional:: err
  integer:: class, cid
continue
  call var_class(var, class, cid)
  if (class == vtb_class_netcdf) then
    if (value) then
      call put_attr(gd_nc_variable(cid), name, "true", err=err)
    else
      call put_attr(gd_nc_variable(cid), name, "false", err=err)
    endif
  endif
end subroutine gtvarputattrlogical
 
!subroutine GTVarPutAttrString(var, name, value, err)
!  !--
!  ! VSTRING 型を引き取り上記 put_attr を呼び出す。下位層のことは関知しない
!  !++
!  use gtdata_types, only: GT_VARIABLE
!  use dc_string, only: VSTRING, vchar, operator(==), len
!  use gtdata_generic, only: put_attr
!  implicit none
!  type(GT_VARIABLE), intent(inout):: var
!  character(len = *), intent(in):: name
!  type(VSTRING), intent(in):: value
!  logical, intent(out), optional:: err
!continue
!  call put_attr(var, name, vchar(value, len(value)), err=err)
!end subroutine GTVarPutAttrString
 
!> @en
!> @brief Put attribute value (integer array)
!>
!> value accepts an array. To write a scalar, use Fortran array
!> constructors (/ ... /). For example, (/a/) creates a length-1 array.
!> @param[inout] var   Variable handle
!> @param[in]    name  Attribute name
!> @param[in]    value Attribute value (integer array)
!> @param[out]   err   Error flag (optional)
!> @enden
!> @ja
!> @brief 属性値の付加 (整数配列)
!>
!> value は配列を受け取ります。スカラーを書き出すには
!> Fortran の配列構成子 (/ ... /) を使ってください。
!> @param[inout] var   変数ハンドル
!> @param[in]    name  属性名
!> @param[in]    value 属性値 (整数配列)
!> @param[out]   err   エラーフラグ (省略可能)
!> @endja
subroutine gtvarputattrint(var, name, value, err)
  use gtdata_types, only: gt_variable
  use gtdata_internal_map, only: var_class, vtb_class_netcdf
  use gtdata_netcdf_generic, only: put_attr
  use gtdata_netcdf_types, only: gd_nc_variable
  use dc_string, only: tochar
  type(gt_variable), intent(inout):: var
  character(len = *), intent(in):: name
  integer, intent(in):: value(:)
  logical, intent(out), optional:: err
  integer:: class, cid
continue
  call var_class(var, class, cid)
  if (class == vtb_class_netcdf) then
    call put_attr(gd_nc_variable(cid), name, value, err)
  endif
end subroutine gtvarputattrint
 
!> @en
!> @brief Put attribute value (real array)
!> @param[inout] var   Variable handle
!> @param[in]    name  Attribute name
!> @param[in]    value Attribute value (real array)
!> @param[out]   err   Error flag (optional)
!> @enden
!> @ja
!> @brief 属性値の付加 (実数配列)
!> @param[inout] var   変数ハンドル
!> @param[in]    name  属性名
!> @param[in]    value 属性値 (実数配列)
!> @param[out]   err   エラーフラグ (省略可能)
!> @endja
subroutine gtvarputattrreal(var, name, value, err)
  use gtdata_types, only: gt_variable
  use gtdata_internal_map, only: var_class, vtb_class_netcdf
  use gtdata_netcdf_generic, only: put_attr
  use gtdata_netcdf_types, only: gd_nc_variable
  use dc_string, only: tochar
  implicit none
  type(gt_variable), intent(inout):: var
  character(len = *), intent(in):: name
  real, intent(in):: value(:)
  logical, intent(out), optional:: err
  integer:: class, cid
continue
  call var_class(var, class, cid)
  if (class == vtb_class_netcdf) then
    call put_attr(gd_nc_variable(cid), name, value, err)
  endif
end subroutine gtvarputattrreal
 
!> @en
!> @brief Put attribute value (double precision array)
!> @param[inout] var   Variable handle
!> @param[in]    name  Attribute name
!> @param[in]    value Attribute value (double precision array)
!> @param[out]   err   Error flag (optional)
!> @enden
!> @ja
!> @brief 属性値の付加 (倍精度実数配列)
!> @param[inout] var   変数ハンドル
!> @param[in]    name  属性名
!> @param[in]    value 属性値 (倍精度実数配列)
!> @param[out]   err   エラーフラグ (省略可能)
!> @endja
subroutine gtvarputattrdouble(var, name, value, err)
  use gtdata_types, only: gt_variable
  use gtdata_internal_map, only: var_class, vtb_class_netcdf
  use gtdata_netcdf_generic, only: put_attr
  use gtdata_netcdf_types, only: gd_nc_variable
  use dc_string, only: tochar
  use dc_types, only: dp
  implicit none
  type(gt_variable), intent(inout):: var
  character(len = *), intent(in):: name
  real(DP), intent(in):: value(:)
  logical, intent(out), optional:: err
  integer:: class, cid
continue
  call var_class(var, class, cid)
  if (class == vtb_class_netcdf) then
    call put_attr(gd_nc_variable(cid), name, value, err)
  endif
end subroutine gtvarputattrdouble
 
!> @en
!> @brief Put attribute value (character with type specification)
!>
!> By specifying xtype, even if value is character type, values can
!> be stored as integer, real (single/double precision).
!> Valid xtype strings:
!> - Integer: "INTEGER", "integer", "int"
!> - Real (single): "REAL", "real", "float"
!> - Real (double): "DOUBLEPRECISION", "DOUBLE", "double"
!> @param[inout] var   Variable handle
!> @param[in]    name  Attribute name
!> @param[in]    value Attribute value (character)
!> @param[in]    xtype Storage type (optional)
!> @param[out]   err   Error flag (optional)
!> @enden
!> @ja
!> @brief 属性値の付加 (型指定付き文字列)
!>
!> xtype に型を指定することで、引数 value には文字型を与えても、
!> 整数型、実数型 (単精度、倍精度) の値を付加することが可能です。
!> 有効な xtype 文字列:
!> - 整数型: "INTEGER", "integer", "int"
!> - 実数型 (単精度): "REAL", "real", "float"
!> - 実数型 (倍精度): "DOUBLEPRECISION", "DOUBLE", "double"
!> @param[inout] var   変数ハンドル
!> @param[in]    name  属性名
!> @param[in]    value 属性値 (文字列)
!> @param[in]    xtype 格納型 (省略可能)
!> @param[out]   err   エラーフラグ (省略可能)
!> @endja
subroutine gtvarputattrchar(var, name, value, xtype, err)
  use gtdata_types, only: gt_variable
  use gtdata_internal_map, only: var_class, vtb_class_netcdf
  use gtdata_netcdf_generic, only: put_attr
  use gtdata_netcdf_types, only: gd_nc_variable
  use dc_trace, only: beginsub, endsub
  implicit none
  type(gt_variable), intent(inout):: var
  character(len = *), intent(in):: name
  character(len = *), intent(in):: value
  character(len = *), intent(in), optional:: xtype
  logical, intent(out), optional:: err
  integer:: class, cid
  character(*), parameter:: subnam = "gtvarputattrchar"
continue
  call beginsub(subnam, "%d:%c = %c", i=(/var%mapid/), c1=trim(name), c2=trim(value))
  call var_class(var, class, cid)
  if (class == vtb_class_netcdf) then
    call put_attr(gd_nc_variable(cid), name, value, xtype, err)
  endif
  call endsub(subnam)
end subroutine gtvarputattrchar