gtool_history_nmlinfo_internal.f90

Go to the documentation of this file.

!> @file gtool_history_nmlinfo_internal.f90
!>
!> @author Yasuhiro MORIKAWA
!> @copyright Copyright (C) GFD Dennou Club, 2007-2026. All rights reserved. <br/>
!>            License is BSD-2-Clause. See [COPYRIGHT](@ref COPYRIGHT) in detail
!>
!> @en
!> @brief Internal constants, variables, procedures used in "gtool_history_nmlinfo"
!> @enden
!>
!> @ja
!> @brief gtool_history_nmlinfo 内で使用される内部向け定数, 変数, 手続き群
!> @endja
 
module gtool_history_nmlinfo_internal
  !>
  !> @en
  !> @brief Internal constants, variables, procedures used in "gtool_history_nmlinfo"
  !> @enden
  !>
  !> @ja
  !> @brief gtool_history_nmlinfo 内で使用される内部向け定数, 変数, 手続き群
  !> @endja
  !>
 
  use dc_hash, only: hash
  implicit none
  private
  public:: listnext, listlast, listsearch
 
  character(1), parameter, public:: name_delimiter = ','
                              ! 複数の変数名の区切り文字
                              ! Delimiter for multiple variable names
 
  type(hash), save, public:: opened_files
                              ! 複数の変数を一つのファイルへ
                              ! 出力するためのチェック用変数. 
                              ! 
                              ! Variables for checking for 
                              ! output multiple variables to one file. 
 
  character(*), parameter, public:: version = &
    & '$Name:  $' // &
    & '$Id: gtool_history_nmlinfo_internal.f90,v 1.1 2009-05-11 15:15:15 morikawa Exp $'
 
  !-----------------------------------------------------------------
  !  非公開手続
  !  Private procedures
  !-----------------------------------------------------------------
 
  interface listnext
    module procedure hstnmlinfolistnext
  end interface
 
  interface listlast
    module procedure hstnmlinfolistlast
  end interface
 
  interface listsearch
    module procedure hstnmlinfolistsearch
  end interface
 
contains
 
  !>
  !> @en
  !> @brief Advance to next entry in list
  !>
  !> gthstnml_list (type GTHST_NMLINFO_ENTRY) that is a list structure
  !> is received, and gthstnml_list is reassociated to next entry, and
  !> is returned.
  !> If next entry is not found, gthstnml_list is associated to
  !> next in last entry (null), and returned.
  !> If gthstnml_list is null from the beginning, null is returned.
  !>
  !> @param[inout] gthstnml_list List entry pointer
  !> @param[out]   err           Error flag (optional)
  !> @enden
  !>
  !> @ja
  !> @brief リストの次エントリへ移動
  !>
  !> リスト構造である gthstnml_list (GTHST_NMLINFO_ENTRY 型) を受け取り,
  !> 次のエントリを gthstnml_list に再結合して返します.
  !> 次のエントリが無い場合, gthstnml_list の最後のエントリの
  !> next (空状態) に接続して返します.
  !> gthstnml_list が始めから空の場合には空状態を返します.
  !>
  !> @param[inout] gthstnml_list リストエントリポインタ
  !> @param[out]   err           例外処理用フラグ (省略可能)
  !> @endja
  !>
  subroutine hstnmlinfolistnext( &
    & gthstnml_list, err )
    use gtool_history_nmlinfo_types, only: gthst_nmlinfo_entry
    use dc_trace, only: beginsub, endsub
    use dc_error, only: storeerror, dc_noerr
    use dc_types, only: string
    implicit none
    type(gthst_nmlinfo_entry), pointer:: gthstnml_list
                              ! (inout)
    logical, intent(out), optional:: err
                              ! 例外処理用フラグ. 
                              ! デフォルトでは, この手続き内でエラーが
                              ! 生じた場合, プログラムは強制終了します. 
                              ! 引数 *err* が与えられる場合, 
                              ! プログラムは強制終了せず, 代わりに
                              ! *err* に .true. が代入されます. 
                              !
                              ! Exception handling flag. 
                              ! By default, when error occur in 
                              ! this procedure, the program aborts. 
                              ! If this *err* argument is given, 
                              ! .true. is substituted to *err* and 
                              ! the program does not abort. 
 
    !-----------------------------------
    !  作業変数
    !  Work variables
    integer:: stat
    character(STRING):: cause_c
    character(*), parameter:: subname = 'HstNmlInfoListNext'
  continue
    call beginsub( subname )
    stat = dc_noerr
    cause_c = ''
 
    !-----------------------------------------------------------------
    !  空状態の場合は何もしないで返す
    !  If null, return without change
    !-----------------------------------------------------------------
    if ( .not. associated( gthstnml_list ) ) goto 999
 
    !-----------------------------------------------------------------
    !  次のエントリに結合して返す
    !  Next entry is associated, and returned
    !-----------------------------------------------------------------
    gthstnml_list => gthstnml_list % next
 
    !-----------------------------------------------------------------
    !  終了処理, 例外処理
    !  Termination and Exception handling
    !-----------------------------------------------------------------
999 continue
    call storeerror( stat, subname, err, cause_c )
    call endsub( subname )
  end subroutine hstnmlinfolistnext
 
  !>
  !> @en
  !> @brief Move to last entry in list
  !>
  !> gthstnml_list (type GTHST_NMLINFO_ENTRY) that is a list structure
  !> is received, and gthstnml_list is reassociated to
  !> last entry, and returned.
  !> If gthstnml_list is null from the beginning, null is returned.
  !>
  !> If previous is given, an entry previous to the above entry
  !> is associated.
  !>
  !> @param[inout] gthstnml_list List entry pointer
  !> @param[out]   previous      Previous entry pointer (optional)
  !> @param[out]   err           Error flag (optional)
  !> @enden
  !>
  !> @ja
  !> @brief リストの最後のエントリへ移動
  !>
  !> リスト構造である gthstnml_list (GTHST_NMLINFO_ENTRY 型) を受け取り,
  !> 最後のエントリに再結合して返します.
  !> gthstnml_list が始めから空の場合には空状態を返します.
  !>
  !> previous が与えられる場合, 当該エントリの一つ前の
  !> エントリに結合します.
  !>
  !> @param[inout] gthstnml_list リストエントリポインタ
  !> @param[out]   previous      前のエントリポインタ (省略可能)
  !> @param[out]   err           例外処理用フラグ (省略可能)
  !> @endja
  !>
  subroutine hstnmlinfolistlast( &
    & gthstnml_list, previous, err )
    use gtool_history_nmlinfo_types, only: gthst_nmlinfo_entry
    use dc_trace, only: beginsub, endsub
    use dc_error, only: storeerror, dc_noerr
    use dc_types, only: string
    implicit none
    type(gthst_nmlinfo_entry), pointer:: gthstnml_list
                              ! (inout)
    type(gthst_nmlinfo_entry), pointer, optional:: previous
                              ! (out)
    logical, intent(out), optional:: err
                              ! 例外処理用フラグ. 
                              ! デフォルトでは, この手続き内でエラーが
                              ! 生じた場合, プログラムは強制終了します. 
                              ! 引数 *err* が与えられる場合, 
                              ! プログラムは強制終了せず, 代わりに
                              ! *err* に .true. が代入されます. 
                              !
                              ! Exception handling flag. 
                              ! By default, when error occur in 
                              ! this procedure, the program aborts. 
                              ! If this *err* argument is given, 
                              ! .true. is substituted to *err* and 
                              ! the program does not abort. 
 
    !-----------------------------------
    !  作業変数
    !  Work variables
    integer:: stat
    character(STRING):: cause_c
    character(*), parameter:: subname = 'HstNmlInfoListLast'
  continue
    call beginsub( subname )
    stat = dc_noerr
    cause_c = ''
 
    if ( present( previous ) ) nullify( previous )
 
    !-----------------------------------------------------------------
    !  空状態の場合は何もしないで返す
    !  If null, return without change
    !-----------------------------------------------------------------
    if ( .not. associated( gthstnml_list ) ) goto 999
 
    !-----------------------------------------------------------------
    !  最後のエントリの *next* に結合して返す
    !  "*next*" in last entry is associated, and returned
    !-----------------------------------------------------------------
    do while ( associated( gthstnml_list % next ) )
      if ( present( previous ) ) previous => gthstnml_list
      call listnext( gthstnml_list = gthstnml_list ) ! (inout)
    end do
 
    !-----------------------------------------------------------------
    !  終了処理, 例外処理
    !  Termination and Exception handling
    !-----------------------------------------------------------------
999 continue
    call storeerror( stat, subname, err, cause_c )
    call endsub( subname )
  end subroutine hstnmlinfolistlast
 
  !>
  !> @en
  !> @brief Search list entry by name
  !>
  !> gthstnml_list (type GTHST_NMLINFO_ENTRY) that is a list structure
  !> is received, and gthstnml_list is reassociated to
  !> the entry that has a value that is same as argument name,
  !> and returned.
  !> If the entry is not found, null is returned.
  !> If gthstnml_list is null from the beginning, null is returned.
  !>
  !> If previous is given, an entry previous to the above entry
  !> is associated. If previous entries are not found,
  !> null is returned.
  !>
  !> If next is given, an entry next to the above entry
  !> is associated. If next entries are not found,
  !> null is returned.
  !>
  !> @param[inout] gthstnml_list List entry pointer
  !> @param[in]    name          Variable identifier
  !> @param[out]   previous      Previous entry pointer (optional)
  !> @param[out]   next          Next entry pointer (optional)
  !> @param[out]   err           Error flag (optional)
  !> @enden
  !>
  !> @ja
  !> @brief 名前でリストエントリを検索
  !>
  !> リスト構造である gthstnml_list (GTHST_NMLINFO_ENTRY 型) を受け取り,
  !> 引数 name と同じ値を持つエントリに再結合して返します.
  !> 見つからない場合は空状態を返します.
  !> gthstnml_list が始めから空の場合には空状態を返します.
  !>
  !> previous が与えられる場合, 当該エントリの一つ前の
  !> エントリに結合します. 前のエントリが無い場合には
  !> 空状態を返します.
  !>
  !> next が与えられる場合, 当該エントリの一つ後ろの
  !> エントリに結合します. 後ろのエントリが無い場合には
  !> 空状態を返します.
  !>
  !> @param[inout] gthstnml_list リストエントリポインタ
  !> @param[in]    name          変数名 (先頭の空白は無視される)
  !> @param[out]   previous      前のエントリポインタ (省略可能)
  !> @param[out]   next          次のエントリポインタ (省略可能)
  !> @param[out]   err           例外処理用フラグ (省略可能)
  !> @endja
  !>
  subroutine hstnmlinfolistsearch( &
    & gthstnml_list, name, &
    & previous, next, err )
    use gtool_history_nmlinfo_types, only: gthst_nmlinfo_entry
    use dc_trace, only: beginsub, endsub
    use dc_error, only: storeerror, dc_noerr
    use dc_types, only: string
    implicit none
    type(gthst_nmlinfo_entry), pointer:: gthstnml_list
                              ! (inout)
    character(*), intent(in):: name
                              ! 変数名. 
                              ! 先頭の空白は無視されます. 
                              ! 
                              ! Variable identifier. 
                              ! Blanks at the head of the name are ignored. 
    type(gthst_nmlinfo_entry), pointer, optional:: previous
                              ! (out)
    type(gthst_nmlinfo_entry), pointer, optional:: next
                              ! (out)
    logical, intent(out), optional:: err
                              ! 例外処理用フラグ. 
                              ! デフォルトでは, この手続き内でエラーが
                              ! 生じた場合, プログラムは強制終了します. 
                              ! 引数 *err* が与えられる場合, 
                              ! プログラムは強制終了せず, 代わりに
                              ! *err* に .true. が代入されます. 
                              !
                              ! Exception handling flag. 
                              ! By default, when error occur in 
                              ! this procedure, the program aborts. 
                              ! If this *err* argument is given, 
                              ! .true. is substituted to *err* and 
                              ! the program does not abort. 
 
    !-----------------------------------
    !  作業変数
    !  Work variables
    integer:: stat
    character(STRING):: cause_c
    character(*), parameter:: subname = 'HstNmlInfoListSearch'
  continue
    call beginsub( subname )
    stat = dc_noerr
    cause_c = ''
 
    !-----------------------------------------------------------------
    !  空状態の場合は何もしないで返す
    !  If null, return without change
    !-----------------------------------------------------------------
    if ( .not. associated( gthstnml_list ) ) goto 999
 
    !-----------------------------------------------------------------
    !  引数 *name* と同じ *name* を持つエントリを探査
    !  The entry that has *name* that is same as argument *name* is searched
    !-----------------------------------------------------------------
    if ( present( previous ) ) nullify( previous )
    if ( present( next ) ) nullify( next )
    if ( trim( adjustl( gthstnml_list % name ) ) == trim( adjustl( name ) ) ) then
      if ( present( next ) ) then
        next => gthstnml_list % next
      end if
      goto 999
    end if
 
    do while ( associated( gthstnml_list ) )
      if ( present( previous ) ) previous => gthstnml_list
      call listnext( gthstnml_list = gthstnml_list ) ! (inout)
      if ( .not. associated( gthstnml_list ) ) goto 999
      if ( trim( adjustl( gthstnml_list % name ) ) == trim( adjustl( name ) ) ) then
        if ( present( next ) ) then
          next => gthstnml_list % next
        end if
        goto 999
      end if
    end do
 
    !-----------------------------------------------------------------
    !  終了処理, 例外処理
    !  Termination and Exception handling
    !-----------------------------------------------------------------
999 continue
    call storeerror( stat, subname, err, cause_c )
    call endsub( subname )
  end subroutine hstnmlinfolistsearch
 
end module gtool_history_nmlinfo_internal