gdncvarputattrint.f90

Go to the documentation of this file.

!> @file gdncvarputattrint.f90
!>
!> @author GFD Dennou Club
!> @copyright Copyright (C) GFD Dennou Club, 2000-2026. All rights reserved. <br/>
!>            License is BSD-2-Clause. See [COPYRIGHT](@ref COPYRIGHT) in detail
!>
!> @en
!> @brief Put integer attribute to a netCDF variable
!> @enden
!>
!> @ja
!> @brief netCDF 変数に整数属性を設定
!> @endja
!>
 
!>
!> @en
!> @brief Set integer attribute value
!>
!> Sets an integer attribute on a variable. If the name starts with '+',
!> the attribute is treated as a global attribute. If value array is empty,
!> the attribute is deleted.
!> @enden
!>
!> @ja
!> @brief 整数属性値を設定
!>
!> 変数に整数属性を設定します。名前が '+' で始まる場合、
!> グローバル属性として扱われます。value 配列が空の場合、属性は削除されます。
!> @endja
!>
!> @param[in]  var   @en Variable handle @enden @ja 変数ハンドル @endja
!> @param[in]  name  @en Attribute name @enden @ja 属性名 @endja
!> @param[in]  value @en Integer values to set @enden @ja 設定する整数値 @endja
!> @param[out] err   @en Error flag (optional) @enden @ja エラーフラグ (省略可能) @endja
!>
subroutine gdncvarputattrint(var, name, value, err)
  use gtdata_netcdf_types, only: gd_nc_variable, gd_nc_variable_entry
  use gtdata_netcdf_file_generic, only: gdncfiledefinemode
  use gtdata_netcdf_internal, only: vtable_lookup
  use netcdf, only: &
    & nf90_put_att, &
    & nf90_noerr, &
    & nf90_del_att, &
    & nf90_global
    use dc_url, only: gt_plus
    use dc_error
    implicit none
    type(gd_nc_variable), intent(in):: var
    character(len = *), intent(in):: name
    type(gd_nc_variable_entry):: ent
    integer, intent(in):: value(:)
    logical, intent(out), optional:: err
    integer:: stat
    continue
    stat = vtable_lookup(var, ent)
    if (stat /= nf90_noerr) goto 999
    if (size(value) == 0) then
      if (name(1:1) == gt_plus) then
        stat = nf90_del_att(ent%fileid, nf90_global, name(2:))
      else
        stat = nf90_del_att(ent%fileid, ent%varid, name)
      endif
      goto 999
    endif
    stat = gdncfiledefinemode(ent%fileid)
    if (stat /= nf90_noerr) goto 999
    if (name(1:1) == gt_plus) then
      stat = nf90_put_att(ent%fileid, nf90_global, name(2:), value)
    else
      stat = nf90_put_att(ent%fileid, ent%varid, name, value)
    endif
999 continue
    call storeerror(stat, 'GDNcVarPutAttrInt', err)
end subroutine