gdncvarcreated.f90

Go to the documentation of this file.

!> @file gdncvarcreated.f90
!>
!> @author Eizi TOYODA, Yasuhiro MORIKAWA
!> @copyright Copyright (C) GFD Dennou Club, 2000-2026. All rights reserved. <br/>
!>            License is BSD-2-Clause. See [COPYRIGHT](@ref COPYRIGHT) in detail
!>
!> @en
!> @brief Create dimension variable in netCDF file
!>
!> These subroutines and functions are provided as gtdata_netcdf_generic#Create
!> through gtdata_netcdf_generic.
!> @enden
!>
!> @ja
!> @brief netCDF ファイルへ次元変数作成
!>
!> これらのサブルーチン、関数は gtdata_netcdf_generic から
!> gtdata_netcdf_generic#Create として提供されます。
!> @endja
!>
 
!>
!> @en
!> @brief Create a dimension variable
!>
!> Creates a dimension variable at the specified URL.
!> The dimension length is specified by length.
!> The returned var contains the variable ID and other information.
!>
!> Setting overwrite to .true. enables overwrite mode (default: no overwrite).
!> If err is provided, errors return .false. instead of terminating.
!> @enden
!>
!> @ja
!> @brief 次元変数を作成
!>
!> 変数 URL url に次元変数を作成します。
!> 次元変数の長さを length に与えます。
!> 返される引数 var には変数 ID などの情報が格納されます。
!>
!> overwrite に .true. を設定すると上書き可能モード (デフォルト: 上書き不可)。
!> err を与えた場合、エラー時はプログラム終了せず .false. が返されます。
!> @endja
!>
!> @param[out] var       @en Created variable handle @enden @ja 作成した変数ハンドル @endja
!> @param[in]  url       @en Variable URL @enden @ja 変数 URL @endja
!> @param[in]  xtype     @en Data type (float, double, int, char) @enden
!>                       @ja データ型 (float, double, int, char) @endja
!> @param[in]  length    @en Dimension length @enden @ja 次元長 @endja
!> @param[in]  overwrite @en Enable overwrite mode (optional) @enden
!>                       @ja 上書きモードを有効化 (省略可能) @endja
!> @param[out] err       @en Error flag (optional) @enden @ja エラーフラグ (省略可能) @endja
!>
subroutine gdncvarcreated(var, url, xtype, length, overwrite, err)
  use gtdata_netcdf_types, only: gd_nc_variable, gd_nc_variable_search
  use gtdata_netcdf_internal, only: vtable_add
  use dc_string, only: strieq
  use dc_types, only: string
  use dc_url, only: urlsplit
  use dc_trace, only: beginsub, endsub, dbgmessage
  use netcdf, only: nf90_noerr, nf90_float, nf90_int, nf90_double, nf90_char, &
    & nf90_def_var, nf90_def_dim
  use gtdata_netcdf_file_generic, only: gdncfileopen, gdncfiledefinemode
  use dc_error, only: storeerror
  implicit none
  type(gd_nc_variable), intent(out):: var
  character(len = *), intent(in):: url
  character(len = *), intent(in):: xtype
  integer, intent(in):: length
  logical, intent(in), optional:: overwrite
  logical, intent(out), optional:: err
  type(gd_nc_variable_search):: ent
  character(len = string):: filename, varname, cause_c
  integer:: stat
  integer:: nc_xtype
  character(len = *), parameter:: subname = "GDNcVarCreateD"
continue
  call beginsub(subname, 'url=<%c>, xtype=<%c>, length=<%d>', &
    & c1=trim(url), c2=trim(xtype), i=(/length/))
  cause_c = trim(url)
  !
  ! --- ファイルを用意 ---
  call urlsplit(url, file=filename, var=varname)
  call gdncfileopen(ent%fileid, filename, stat=stat, writable=.true., &
    & overwrite=overwrite)
  if (stat /= nf90_noerr) goto 999
  stat = gdncfiledefinemode(ent%fileid)
  if (stat /= nf90_noerr) goto 999
  !
  ! --- 型の決定 ---
  nc_xtype = nf90_float
  if (strieq(xtype, "double")) then
    nc_xtype = nf90_double
  else if (strieq(xtype, "DOUBLEPRECISION")) then
    nc_xtype = nf90_double
  end if
  if (strieq(xtype, "int")) then
    nc_xtype = nf90_int
  else if (strieq(xtype, "INTEGER")) then
    nc_xtype = nf90_int
  end if
  if (strieq(xtype, "char")) then
    nc_xtype = nf90_char
  else if (strieq(xtype, "CHARACTER")) then
    nc_xtype = nf90_char
  end if
  !
  ! --- 次元変数の作成 ---
  stat = nf90_def_dim(ent%fileid, trim(varname), len=length, dimid=ent%dimid)
  if (stat /= nf90_noerr) goto 999
  stat = nf90_def_var(ent%fileid, trim(varname), &
    & xtype=nc_xtype, dimids=(/ent%dimid/), varid=ent%varid)
  if (stat /= nf90_noerr) goto 999
  !
  stat = vtable_add(var, ent)
  if (stat /= nf90_noerr) goto 999
 
999 continue
  call storeerror(stat, subname, err, cause_c=cause_c)
  if (stat /= nf90_noerr) var = gd_nc_variable(-1)
  call endsub(subname, 'stat=%d', i=(/stat/))
end subroutine gdncvarcreated