gdncfilesync.f90

Go to the documentation of this file.

!>
!> @file gdncfilesync.f90
!>
!> @author Yasuhiro MORIKAWA, Eizi TOYODA
!> @copyright Copyright (C) GFD Dennou Club, 2000-2026. All rights reserved. <br/>
!>            License is BSD-2-Clause. See [COPYRIGHT](@ref COPYRIGHT) in detail
!>
!> @en
!> @brief Synchronize netCDF file to disk
!> @enden
!>
!> @ja
!> @brief netCDF ファイルをディスクに同期
!> @endja
!>
 
!>
!> @en
!> @brief Synchronize netCDF file to disk
!>
!> Flushes buffered data to disk for the specified file or all open files.
!> Before syncing, switches the file to data mode if necessary.
!>
!> @note This subroutine does not call StoreError internally because it may
!>       be called from SysdepAbort within StoreError.
!> @enden
!>
!> @ja
!> @brief netCDF ファイルをディスクに同期
!>
!> 指定されたファイルまたは全てのオープンファイルのバッファデータを
!> ディスクにフラッシュします。同期前に、必要に応じてファイルを
!> データモードに切り替えます。
!>
!> @note このサブルーチンは StoreError の SysdepAbort から呼ばれる
!>       可能性があるため、内部で StoreError を呼び出しません。
!> @endja
!>
!> @param[in]  fileid @en netCDF file ID (optional, sync all if omitted) @enden
!>                    @ja netCDF ファイル ID (省略時は全ファイルを同期) @endja
!> @param[out] stat   @en Status code (optional) @enden @ja ステータスコード (省略可能) @endja
!>
subroutine gdncfilesync(fileid, stat)
  use gtdata_netcdf_file_types, only: gd_nc_file_id_entry
  use gtdata_netcdf_file_internal, only: id_head, id_used
  use gtdata_netcdf_file_generic, only: gdncfiledatamode
  use netcdf, only: nf90_sync, nf90_noerr
  use dc_error
  integer, intent(in), optional:: fileid
  integer, intent(out), optional:: stat
  integer:: ncid, mystat
  type(gd_nc_file_id_entry), pointer:: identptr
continue
  mystat = nf90_noerr
  if (present(fileid)) then
    ncid = fileid
    mystat = gdncfiledatamode(ncid)
    if (mystat /= nf90_noerr) goto 999
    mystat = nf90_sync(ncid)
  else if (id_used) then
    identptr => id_head
    do
      if (.not. associated(identptr)) exit
      ncid = identptr % id
      mystat = gdncfiledatamode(ncid)
      if (mystat /= nf90_noerr) exit
      mystat = nf90_sync(ncid)
      if (mystat /= nf90_noerr) exit
      identptr => identptr % next
    enddo
  endif
999 continue
  ! 自発的には StoreError しない。StoreError の SysdepAbort
  ! からも呼ばれる可能性があるためである。
  if (present(stat)) stat = mystat
end subroutine gdncfilesync