gdncfilereopen.f90

Go to the documentation of this file.

!>
!> @file gdncfilereopen.f90
!>
!> @author Yasuhiro MORIKAWA, Eizi TOYODA
!> @copyright Copyright (C) GFD Dennou Club, 2000-2026. All rights reserved. <br/>
!>            License is BSD-2-Clause. See [COPYRIGHT](@ref COPYRIGHT) in detail
!>
!> @en
!> @brief Increment reference count of an open netCDF file
!> @enden
!>
!> @ja
!> @brief オープン中の netCDF ファイルの参照カウントを増加
!> @endja
!>
 
!>
!> @en
!> @brief Increment reference count of an open netCDF file
!>
!> Searches the internal file list for the given file ID and increments
!> its reference count. Returns an error if the file ID is not found.
!> @enden
!>
!> @ja
!> @brief オープン中の netCDF ファイルの参照カウントを増加
!>
!> 内部ファイルリストから指定されたファイル ID を検索し、
!> 参照カウントを増加させます。ファイル ID が見つからない場合はエラーを返します。
!> @endja
!>
!> @param[in]  fileid @en netCDF file ID @enden @ja netCDF ファイル ID @endja
!> @param[out] err    @en Error flag (optional) @enden @ja エラーフラグ (省略可能) @endja
!>
subroutine gdncfilereopen(fileid, err)
  use gtdata_netcdf_file_types, only: gd_nc_file_id_entry
  use gtdata_netcdf_file_internal, only: id_head, id_used
  use netcdf, only: nf90_enotnc
  use dc_error, only: storeerror
  use dc_trace, only: beginsub, endsub, dbgmessage
  implicit none
  integer, intent(in):: fileid
  logical, intent(out), optional:: err
  type(gd_nc_file_id_entry), pointer:: identptr
  character(*), parameter:: subname = "GDNcFileReopen"
continue
  call beginsub(subname, 'file=%d', i=(/fileid/))
  if (id_used) then
    identptr => id_head
    do
      if (identptr % id == fileid) then
        identptr % count = identptr % count + 1
        if (present(err)) err = .false.
        call endsub(subname, 'count=%d', i=(/identptr % count/))
        return
      endif
      identptr => identptr % next
      if (.not. associated(identptr)) exit
    enddo
  endif
  call storeerror(nf90_enotnc, 'GDNcFileReopen', err, cause_i=fileid)
  call endsub(subname, 'err')
end subroutine gdncfilereopen