dcunits_com.f90

Go to the documentation of this file.

!-----------------------------------------------------------------------
! Copyright (c) 2000-2026 Gtool Development Group. All rights reserved.
!-----------------------------------------------------------------------
!>
!> @author    Eizi TOYODA, Yasuhiro MORIKAWA
!> @copyright Copyright (C) GFD Dennou Club, 2000-2026. All rights reserved. <br/>
!>            License is BSD-2-Clause. see [COPYRIGHT](@ref COPYRIGHT) in detail
!> @private
!> @en
!> @brief Internal module for dc_units
!> @details
!> This module provides internal constants and subroutines used by
!> the dc_units module. It contains scanner/tokenizer functionality
!> for parsing unit strings.
!>
!> @section dcunits_com_scanner Scanner symbols
!>
!> | Symbol       | Description              |
!> |--------------|--------------------------|
!> | S_EOF        | End of file/string       |
!> | S_SHIFT      | Shift operator (@, from, at) |
!> | S_TEXT       | Text/name token          |
!> | S_MULTIPLY   | Multiply operator (*, .) |
!> | S_DIVIDE     | Divide operator (/)      |
!> | S_EXPONENT   | Exponent operator (^, **)|
!> | S_OPENPAR    | Open parenthesis         |
!> | S_CLOSEPAR   | Close parenthesis        |
!> | S_REAL       | Real number              |
!> | S_INTEGER    | Integer number           |
!>
!> @enden
!>
!> @ja
!> @brief dc_units モジュール用の内部モジュール
!> @details
!> dc_units モジュールで用いる内部の定数およびサブルーチンを提供します.
!> 単位文字列をパースするためのスキャナ/トークナイザ機能を含みます.
!>
!> @section dcunits_com_scanner_ja スキャナシンボル
!>
!> | シンボル     | 説明                     |
!> |--------------|--------------------------|
!> | S_EOF        | ファイル/文字列の終端    |
!> | S_SHIFT      | シフト演算子 (@, from, at) |
!> | S_TEXT       | テキスト/名前トークン    |
!> | S_MULTIPLY   | 乗算演算子 (*, .)        |
!> | S_DIVIDE     | 除算演算子 (/)           |
!> | S_EXPONENT   | 指数演算子 (^, **)       |
!> | S_OPENPAR    | 開き括弧                 |
!> | S_CLOSEPAR   | 閉じ括弧                 |
!> | S_REAL       | 実数                     |
!> | S_INTEGER    | 整数                     |
!>
!> @endja
!>
 
module dcunits_com
  use dc_types, only: dp, string
  implicit none
  private
  public:: s_eof, s_shift, s_text, s_multiply, s_divide, s_exponent
  public:: s_openpar, s_closepar, s_real, s_integer
  public:: dcunitssetline, dcunitsgettoken
 
  !> @var S_EOF
  !> @en End of file/string symbol @enden
  !> @ja ファイル/文字列終端シンボル @endja
  integer, parameter:: s_eof = -128
 
  !> @var S_SHIFT
  !> @en Shift operator symbol @enden
  !> @ja シフト演算子シンボル @endja
  integer, parameter:: s_shift = 300
 
  !> @var S_TEXT
  !> @en Text/name token symbol @enden
  !> @ja テキスト/名前トークンシンボル @endja
  integer, parameter:: s_text = 301
 
  !> @var S_MULTIPLY
  !> @en Multiply operator symbol @enden
  !> @ja 乗算演算子シンボル @endja
  integer, parameter:: s_multiply = 302
 
  !> @var S_DIVIDE
  !> @en Divide operator symbol @enden
  !> @ja 除算演算子シンボル @endja
  integer, parameter:: s_divide = 303
 
  !> @var S_EXPONENT
  !> @en Exponent operator symbol @enden
  !> @ja 指数演算子シンボル @endja
  integer, parameter:: s_exponent = 304
 
  !> @var S_OPENPAR
  !> @en Open parenthesis symbol @enden
  !> @ja 開き括弧シンボル @endja
  integer, parameter:: s_openpar = 305
 
  !> @var S_CLOSEPAR
  !> @en Close parenthesis symbol @enden
  !> @ja 閉じ括弧シンボル @endja
  integer, parameter:: s_closepar = 306
 
  !> @var S_REAL
  !> @en Real number symbol @enden
  !> @ja 実数シンボル @endja
  integer, parameter:: s_real = 307
 
  !> @var S_INTEGER
  !> @en Integer number symbol @enden
  !> @ja 整数シンボル @endja
  integer, parameter:: s_integer = 308
 
  !> @var thisline
  !> @en Scanner buffer for input line @enden
  !> @ja スキャナバッファ（入力行） @endja
  character(STRING), private, save:: thisline = ""
 
  !> @var i
  !> @en Current position in scanner buffer @enden
  !> @ja スキャナバッファの現在位置 @endja
  integer, private, save:: i = 1
 
contains
 
  !>
  !> @en
  !> @brief Set input line for scanner
  !> @details
  !> Sets the input line to be scanned and resets the scanner position.
  !> @param[in] line Input line to scan
  !> @enden
  !>
  !> @ja
  !> @brief スキャナの入力行を設定します
  !> @details
  !> スキャンする入力行を設定し, スキャナ位置をリセットします.
  !> @param[in] line スキャンする入力行
  !> @endja
  !>
  subroutine dcunitssetline(line)
    implicit none
    character(*), intent(in):: line
    thisline = line
    i = 1
  end subroutine dcunitssetline
 
  !>
  !> @en
  !> @brief Get next token from input line
  !> @details
  !> Scans the input line and returns the next token.
  !> Token types include operators, numbers, and text.
  !> @param[out] tokentype Type of the token (S_EOF, S_TEXT, etc.)
  !> @param[out] ivalue    Integer values array (for integer tokens)
  !> @param[out] dvalue    Real value (for real number tokens)
  !> @param[out] cvalue    Character value (token string)
  !> @enden
  !>
  !> @ja
  !> @brief 入力行から次のトークンを取得します
  !> @details
  !> 入力行をスキャンし, 次のトークンを返します.
  !> トークンの種類には演算子, 数値, テキストがあります.
  !> @param[out] tokentype トークンの種類 (S_EOF, S_TEXT など)
  !> @param[out] ivalue    整数値配列 (整数トークン用)
  !> @param[out] dvalue    実数値 (実数トークン用)
  !> @param[out] cvalue    文字値 (トークン文字列)
  !> @endja
  !>
  subroutine dcunitsgettoken(tokentype, ivalue, dvalue, cvalue)
    use dc_regex, only: match
    implicit none
    integer, intent(out):: tokentype
    integer, intent(out):: ivalue(5)
    real(dp), intent(out):: dvalue
    character(*), intent(out):: cvalue
    integer:: iend, istr, ilen, ios
    ivalue = 0
    dvalue = 0.0_dp
    cvalue = ""
    iend = len_trim(thisline)
    do
      if (i > iend) exit
      ! '#' 文字が現われれば EOF シンボルを返す
      call match("^##", thisline(i:), istr, ilen)
      if (istr > 0) then
        i = iend + 1
        tokentype = s_eof
        return
      endif
      ! 空白を無視
      call match("^#s+", thisline(i:), istr, ilen)
      if (istr > 0) then
        i = i + ilen
        if (i > iend) exit
      endif
      ! シフト演算子チェック
      call match("^@", thisline(i:), istr, ilen)
      if (istr <= 0) call match("^from", thisline(i:), istr, ilen)
      if (istr <= 0) call match("^at", thisline(i:), istr, ilen)
      if (istr > 0) then
        i = i + ilen
        tokentype = s_shift
        cvalue = thisline(i: i+ilen-1)
        return
      endif
      ! 名前チェック
      call match("^#a#w*#a", thisline(i:), istr, ilen)
      if (istr <= 0) call match("^[#a'""]", thisline(i:), istr, ilen)
      if (istr > 0) then
        tokentype = s_text
        cvalue = thisline(i: i+ilen-1)
        i = i + ilen
        return
      endif
      ! '*' の前に '**' を認知せねば。
      call match("^#^", thisline(i:), istr, ilen)
      if (istr <= 0) call match("^#*#*", thisline(i:), istr, ilen)
      if (istr > 0) then
        tokentype = s_exponent
        cvalue = thisline(i: i+ilen-1)
        i = i + ilen
        return
      endif
      ! 実数にならない小数点は S_MULTIPLY
      call match("^#.[^#d]", thisline(i:), istr, ilen)
      if (istr <= 0) call match("^#*", thisline(i:), istr, ilen)
      if (istr > 0) then
        tokentype = s_multiply
        cvalue = thisline(i: i+ilen-1)
        i = i + 1
        return
      endif
      ! 実数チェック. 小数点は語頭にあれば必ず数字が伴うので安心せよ
      call match("^[-+]?#d*#.#d*[EeDd][-+]?#d+", thisline(i:), istr, ilen)
      if (istr <= 0) call match("^[-+]?#d*#.#d*", thisline(i:), istr, ilen)
      if (istr > 0) then
        read(thisline(i: i+ilen-1), fmt=*, &
          & iostat=ios) dvalue
        if (ios /= 0) dvalue = huge(dvalue)
        cvalue = thisline(i: i+ilen-1)
        tokentype = s_real
        i = i + ilen
        return
      endif
      ! 整数チェック
      call match("^[-+]?#d+", thisline(i:), istr, ilen)
      if (istr > 0) then
        read(thisline(i: i+ilen-1), fmt=*, &
          & iostat=ios) ivalue(1)
        if (ios /= 0) ivalue(1) = huge(1)
        cvalue = thisline(i: i+ilen-1)
        tokentype = s_integer
        i = i + ilen
        return
      endif
      ! ほかの１字トークンチェック
      if (thisline(i:i) == '/') then
        tokentype = s_divide
        cvalue = thisline(i:i)
        i = i + 1
        return
      endif
      if (thisline(i:i) == '(') then
        tokentype = s_openpar
        cvalue = thisline(i:i)
        i = i + 1
        return
      endif
      if (thisline(i:i) == ')') then
        tokentype = s_closepar
        cvalue = thisline(i:i)
        i = i + 1
        return
      endif
      ! だめだこりゃ。はい次いってみよう
      tokentype = ichar(thisline(i:i))
      cvalue = thisline(i:i)
      i = i + 1
      return
    enddo
    i = iend + 1
    tokentype = s_eof
    cvalue = ""
  end subroutine dcunitsgettoken
 
end module dcunits_com