dcstringcprintf.f90

Go to the documentation of this file.

! -*- mode: f90; coding: utf-8 -*-
!-----------------------------------------------------------------------
! Copyright (c) 2000-2026 Gtool Development Group. All rights reserved.
!-----------------------------------------------------------------------
!>
!> @author    Yasuhiro MORIKAWA, Eizi TOYODA
!> @copyright Copyright (C) GFD Dennou Club, 2000-2026. All rights reserved. <br/>
!>            License is BSD-2-Clause. see [COPYRIGHT](@ref COPYRIGHT) in detail
!> @en
!> @brief Formatted output conversion (function version)
!> @details
!> Format a string like C sprintf(3) and return it.
!> Note that the implementation is quite different from C sprintf(3).
!> @enden
!>
!> @ja
!> @brief 書式変換出力 (関数版)
!> @details
!> C の sprintf(3) のように文字列をフォーマットして返します。
!> ただし、実装は C の sprintf(3) とは大分違うのでご注意ください。
!> @endja
!>
 
!> @en
!> @brief Format string and return result
!> @details
!> Return a formatted string according to format string `fmt`.
!> Use specifiers starting with '%' in `fmt`.
!> Use '%%' to output a literal '%'.
!> See dcstringsprintf.f90 for specifier details and examples.
!>
!> @param[in] fmt Format string with specifiers
!> @param[in] i Integer array data for %d, %o, %x
!> @param[in] r Single precision real array data for %r
!> @param[in] d Double precision real array data for %f
!> @param[in] L Logical array data for %b, %y
!> @param[in] n Repeat counts for %* specifier
!> @param[in] c1 First character string for %c
!> @param[in] c2 Second character string for %c
!> @param[in] c3 Third character string for %c
!> @param[in] ca Character array for %a
!> @return Formatted string
!> @enden
!>
!> @ja
!> @brief 書式変換した文字列を返す
!> @details
!> フォーマット文字列 `fmt` に従って変換された文字列を返します。
!> `fmt` には '%' で始まる指示子を含む文字列を与えます。
!> '%' を出力したい場合は '%%' と記述します。
!> 指示子に関しての詳細や用例に関しては dcstringsprintf.f90 を参照ください。
!>
!> @param[in] fmt 指示子を含むフォーマット文字列
!> @param[in] i %d, %o, %x 用の整数配列データ
!> @param[in] r %r 用の単精度実数配列データ
!> @param[in] d %f 用の倍精度実数配列データ
!> @param[in] L %b, %y 用の論理配列データ
!> @param[in] n %* 用の繰り返し回数
!> @param[in] c1 %c 用の1番目の文字列
!> @param[in] c2 %c 用の2番目の文字列
!> @param[in] c3 %c 用の3番目の文字列
!> @param[in] ca %a 用の文字配列
!> @return 書式変換された文字列
!> @endja
function dcstringcprintf(fmt, i, r, d, L, n, c1, c2, c3, ca, maxlen) result(result)
 
  use dc_types, only: string, dp, sp
  use dc_string, only: printf
  implicit none
  character(len = STRING):: result
  character(*), intent(in):: fmt
  integer, intent(in), optional:: i(:), n(:)
  real(sp), intent(in), optional:: r(:)
  real(dp), intent(in), optional:: d(:)
  logical, intent(in), optional:: l(:)
  character(*), intent(in), optional:: c1, c2, c3
  character(*), intent(in), optional:: ca(:)
  integer, intent(in), optional:: maxlen
  integer:: out_len
  continue
  call printf(result, fmt, i=i, r=r, d=d, l=l, n=n, c1=c1, c2=c2, c3=c3, ca=ca)
  if (present(maxlen)) then
    out_len = max(0, min(len(result), maxlen))
    if (out_len == 0) then
      result = ''
    else if (out_len < len(result)) then
      result = result(1:out_len)
    end if
  end if
end function dcstringcprintf
 
function dcstringcprintft(fmt, i, r, d, L, n, c1, c2, c3, ca, maxlen) result(result)
 
  use dc_types, only: string, token, dp, sp
  use dc_string, only: cprintf
  implicit none
  character(len = TOKEN):: result
  character(*), intent(in):: fmt
  integer, intent(in), optional:: i(:), n(:)
  real(sp), intent(in), optional:: r(:)
  real(dp), intent(in), optional:: d(:)
  logical, intent(in), optional:: l(:)
  character(*), intent(in), optional:: c1, c2, c3
  character(*), intent(in), optional:: ca(:)
  integer, intent(in), optional:: maxlen
  character(len = STRING):: tmp
  integer:: out_len
  continue
  if (present(maxlen)) then
    tmp = cprintf(fmt, i=i, r=r, d=d, l=l, n=n, c1=c1, c2=c2, c3=c3, ca=ca, maxlen=maxlen)
    out_len = max(0, min(len(result), maxlen))
  else
    tmp = cprintf(fmt, i=i, r=r, d=d, l=l, n=n, c1=c1, c2=c2, c3=c3, ca=ca)
    out_len = len(result)
  end if
  result = ''
  if (out_len > 0) then
    result(1:out_len) = tmp(1:out_len)
  end if
end function dcstringcprintft