dcdatetimesub.f90

Go to the documentation of this file.

! -*- mode: f90; coding: utf-8 -*-
!-----------------------------------------------------------------------
! Copyright (c) 2000-2026 Gtool Development Group. All rights reserved.
!-----------------------------------------------------------------------
!>
!> @author    Yasuhiro MORIKAWA, Eizi TOYODA
!> @copyright Copyright (C) GFD Dennou Club, 2000-2026. All rights reserved. <br/>
!>            License is BSD-2-Clause. see [COPYRIGHT](@ref COPYRIGHT) in detail
!> @en
!> @brief Functions for user defined operation (-)
!> @details
!> This file contains implementation procedures of subtraction
!> for dc_date_types#DC_DATETIME and dc_date_types#DC_DIFFTIME.
!> @enden
!>
!> @ja
!> @brief 利用者定義演算子 (-) のための関数
!> @details
!> このファイルには dc_date_types#DC_DATETIME および dc_date_types#DC_DIFFTIME
!> の減算の実装手続きが含まれています。
!> @endja
!>
 
!> @en
!> @brief Subtract DC_DIFFTIME from DC_DATETIME
!> @details
!> Subtract a time difference from a datetime.
!>
!> @param[in] time Datetime to subtract from
!> @param[in] diff Time difference to subtract
!> @return Result of subtraction
!> @enden
!>
!> @ja
!> @brief DC_DATETIME から DC_DIFFTIME を減算
!> @details
!> 日時から日時差を減算します.
!>
!> @param[in] time 減算元の日時
!> @param[in] diff 減算する日時差
!> @return 減算結果
!> @endja
function dcdatetime_sub_tf(time, diff) result(result)
 
  use dc_date_generic, only: eval, dcdatetimecreate
  use dc_date_types, only: dc_datetime, dc_difftime
  use dc_scaledsec, only: dc_scaled_sec, &
    & operator(<), operator(>), operator(<=), operator(>=), &
    & operator(+), operator(-), operator(*), operator(/), &
    & modulo, int, abs, sign
  implicit none
  type(dc_datetime):: result
  type(dc_datetime), intent(in):: time
  type(dc_difftime), intent(in):: diff
  type(dc_scaled_sec):: time_year, time_mon, time_day, time_sec
  integer:: time_caltype
  character(6):: time_zone
continue
  call eval(time, &
    & sclyear = time_year, sclmon = time_mon, sclday = time_day, &
    & sclsec = time_sec, caltype = time_caltype, zone = time_zone )
  call dcdatetimecreate(result, &
    & sclyear = time_year, &
    & sclmon = time_mon - diff % mon, &
    & sclday = time_day - diff % day, &
    & sclsec = time_sec - diff % sec, &
    & caltype = time_caltype, zone = time_zone)
end function dcdatetime_sub_tf
 
!> @en
!> @brief Subtract two DC_DATETIME values
!> @details
!> Subtract one datetime from another and return the difference.
!>
!> @param[in] time1 First datetime (minuend)
!> @param[in] time2 Second datetime (subtrahend)
!> @return Time difference between time1 and time2
!> @enden
!>
!> @ja
!> @brief 2つの DC_DATETIME を減算
!> @details
!> 2つの日時の差を計算して返します.
!>
!> @param[in] time1 1番目の日時 (被減数)
!> @param[in] time2 2番目の日時 (減数)
!> @return time1 と time2 の日時差
!> @endja
function dcdatetime_sub_tt(time1, time2) result(result)
 
  use dc_date_generic, only: evalsclsec, zonetodiff, operator(-)
  use dc_date_types, only: dc_datetime, dc_difftime
  use dc_date_internal, only: dcdate_normalize
  use dc_scaledsec, only: dc_scaled_sec, &
    & operator(<), operator(>), operator(<=), operator(>=), &
    & operator(+), operator(-), operator(*), operator(/), &
    & modulo, int, abs, sign
  implicit none
  type(dc_difftime):: result
  type(dc_datetime), intent(in):: time1, time2
continue
  result % day = time1 % day - time2 % day
  result % sec = time1 % sec - time2 % sec &
    & + evalsclsec(zonetodiff(time1 % zone) - zonetodiff(time2 % zone))
  result % day_seconds = time1 % day_seconds
  call dcdate_normalize(result % day, result % sec, result % day_seconds, result % nondim_flag)
end function dcdatetime_sub_tt
 
!> @en
!> @brief Subtract two DC_DIFFTIME values
!> @details
!> Subtract one time difference from another.
!>
!> @param[in] diff1 First time difference (minuend)
!> @param[in] diff2 Second time difference (subtrahend)
!> @return Result of subtraction
!> @enden
!>
!> @ja
!> @brief 2つの DC_DIFFTIME を減算
!> @details
!> 2つの日時差を減算します.
!>
!> @param[in] diff1 1番目の日時差 (被減数)
!> @param[in] diff2 2番目の日時差 (減数)
!> @return 減算結果
!> @endja
function dcdatetime_sub_ff(diff1, diff2) result(result)
 
  use dc_date_internal, only: dcdate_normalize, dcdate_nondimcheck
  use dc_date_types, only: dc_datetime, dc_difftime
  use dc_scaledsec, only: operator(-)
  implicit none
  type(dc_difftime):: result
  type(dc_difftime), intent(in):: diff1, diff2
continue
  result % mon = diff1 % mon - diff2 % mon
  result % day = diff1 % day - diff2 % day
  result % sec = diff1 % sec - diff2 % sec
  result % day_seconds = diff1 % day_seconds
  call dcdate_nondimcheck('dc_date#operator(-)', diff1, diff2, result)
  call dcdate_normalize(result % day, result % sec, result % day_seconds, result % nondim_flag)
end function dcdatetime_sub_ff
 
!> @en
!> @brief Subtract double precision from DC_DIFFTIME
!> @details
!> Subtract a double precision seconds value from a time difference.
!>
!> @param[in] diff Time difference (minuend)
!> @param[in] sec  Seconds to subtract (double precision)
!> @return Result of subtraction
!> @enden
!>
!> @ja
!> @brief DC_DIFFTIME から倍精度実数を減算
!> @details
!> 日時差から倍精度実数の秒数を減算します.
!>
!> @param[in] diff 日時差 (被減数)
!> @param[in] sec  減算する秒数 (倍精度実数)
!> @return 減算結果
!> @endja
function dcdatetime_sub_fd(diff, sec) result(result)
 
  use dc_date_internal, only: dcdate_normalize
  use dc_date_types, only: dc_datetime, dc_difftime
  use dc_scaledsec, only: operator(-)
  use dc_types, only: dp
  implicit none
  type(dc_difftime):: result
  type(dc_difftime), intent(in):: diff
  real(dp), intent(in):: sec
continue
  result % mon = diff % mon
  result % day = diff % day
  result % sec = diff % sec - sec
  result % day_seconds = diff % day_seconds
  call dcdate_normalize(result % day, result % sec, result % day_seconds, result % nondim_flag)
end function dcdatetime_sub_fd
 
!> @en
!> @brief Subtract single precision from DC_DIFFTIME
!> @details
!> Subtract a single precision seconds value from a time difference.
!>
!> @param[in] diff Time difference (minuend)
!> @param[in] sec  Seconds to subtract (single precision)
!> @return Result of subtraction
!> @enden
!>
!> @ja
!> @brief DC_DIFFTIME から単精度実数を減算
!> @details
!> 日時差から単精度実数の秒数を減算します.
!>
!> @param[in] diff 日時差 (被減数)
!> @param[in] sec  減算する秒数 (単精度実数)
!> @return 減算結果
!> @endja
function dcdatetime_sub_fr(diff, sec) result(result)
 
  use dc_date_generic, only: operator(-)
  use dc_date_types, only: dc_datetime, dc_difftime
  use dc_scaledsec, only: operator(-)
  use dc_types, only: dp
  implicit none
  type(dc_difftime):: result
  type(dc_difftime), intent(in):: diff
  real, intent(in):: sec
continue
  result = diff - real( sec, dp )
end function dcdatetime_sub_fr
 
!> @en
!> @brief Subtract integer from DC_DIFFTIME
!> @details
!> Subtract an integer seconds value from a time difference.
!>
!> @param[in] diff Time difference (minuend)
!> @param[in] sec  Seconds to subtract (integer)
!> @return Result of subtraction
!> @enden
!>
!> @ja
!> @brief DC_DIFFTIME から整数を減算
!> @details
!> 日時差から整数の秒数を減算します.
!>
!> @param[in] diff 日時差 (被減数)
!> @param[in] sec  減算する秒数 (整数)
!> @return 減算結果
!> @endja
function dcdatetime_sub_fi(diff, sec) result(result)
 
  use dc_date_generic, only: operator(-)
  use dc_date_types, only: dc_datetime, dc_difftime
  use dc_scaledsec, only: operator(-)
  use dc_types, only: dp
  implicit none
  type(dc_difftime):: result
  type(dc_difftime), intent(in):: diff
  integer, intent(in):: sec
continue
  result = diff - real( sec, dp )
end function dcdatetime_sub_fi