dcdatetimeputline.f90

Go to the documentation of this file.

! -*- mode: f90; coding: utf-8 -*-
!-----------------------------------------------------------------------
! Copyright (c) 2000-2026 Gtool Development Group. All rights reserved.
!-----------------------------------------------------------------------
!>
!> @author    Yasuhiro MORIKAWA
!> @copyright Copyright (C) GFD Dennou Club, 2000-2026. All rights reserved. <br/>
!>            License is BSD-2-Clause. see [COPYRIGHT](@ref COPYRIGHT) in detail
!> @en
!> @brief Print DC_DATETIME, DC_DIFFTIME information
!> @details
!> Procedures described in this file are provided from "dc_date" module.
!> @enden
!>
!> @ja
!> @brief dc_date_types#DC_DATETIME, dc_date_types#DC_DIFFTIME の印字
!> @details
!> このファイルで提供される手続き群は dc_date モジュールにて提供されます。
!> @endja
!>
 
!> @en
!> @brief Print information of DC_DATETIME
!> @details
!> Print the information set in the argument `time`.
!> By default, messages are output to standard output.
!> The output destination can be changed by specifying a unit number in `unit`.
!>
!> @param[in] time   Datetime to print
!> @param[in] unit   Unit number for output (default: standard output)
!> @param[in] indent Indentation for displayed messages
!> @enden
!>
!> @ja
!> @brief DC_DATETIME の情報を印字
!> @details
!> 引数 `time` に設定されている情報を印字します.
!> デフォルトではメッセージは標準出力に出力されます.
!> `unit` に装置番号を指定することで, 出力先を変更することが可能です.
!>
!> @param[in] time   印字する日時
!> @param[in] unit   出力先の装置番号 (デフォルト: 標準出力)
!> @param[in] indent 表示されるメッセージの字下げ
!> @endja
subroutine dcdatetimeputline( time, unit, indent )
 
  use dc_date_types, only: dc_datetime
  use dc_date_generic, only: tochar
  use dc_string, only: printf
  use dc_trace, only: beginsub, endsub
  use dc_types, only: stdout, string
  use dc_scaledsec, only: dcscaledsecputline
  implicit none
  type(dc_datetime), intent(in) :: time
  integer, intent(in), optional :: unit
  character(*), intent(in), optional:: indent
 
  integer :: out_unit
  integer:: indent_len
  character(STRING):: indent_str
  character(*), parameter :: subname = 'DCDateTimePutLine'
continue
  call beginsub(subname)
  if (present(unit)) then
    out_unit = unit
  else
    out_unit = stdout
  end if
 
  indent_len = 0
  indent_str = ''
  if ( present(indent) ) then
    if ( len(indent) /= 0 ) then
      indent_len = len(indent)
      indent_str(1:indent_len) = indent
    end if
  end if
 
  call printf(out_unit, &
    & indent_str(1:indent_len) // &
    & '#<DC_DATETIME:: @date=%c @caltype=%d @zone=%c', &
    & i=(/time % caltype/), c1=trim(tochar(time)), c2=trim(time % zone) )
 
  call printf(out_unit, &
    & indent_str(1:indent_len) // &
    & '                @day=' )
  call dcscaledsecputline( time % day, unit = unit, &
    & indent = indent_str(1:indent_len) // &
    & '                     ' )
 
  call printf(out_unit, &
    & indent_str(1:indent_len) // &
    & '                @sec=' )
  call dcscaledsecputline( time % sec, unit = unit, &
    & indent = indent_str(1:indent_len) // &
    & '                     ' )
 
  call printf(out_unit, &
    & indent_str(1:indent_len) // '>' )
 
  call endsub(subname)
end subroutine dcdatetimeputline
 
!> @en
!> @brief Print information of DC_DIFFTIME
!> @details
!> Print the information set in the argument `diff`.
!> By default, messages are output to standard output.
!> The output destination can be changed by specifying a unit number in `unit`.
!>
!> @param[in] diff   Time difference to print
!> @param[in] unit   Unit number for output (default: standard output)
!> @param[in] indent Indentation for displayed messages
!> @enden
!>
!> @ja
!> @brief DC_DIFFTIME の情報を印字
!> @details
!> 引数 `diff` に設定されている情報を印字します.
!> デフォルトではメッセージは標準出力に出力されます.
!> `unit` に装置番号を指定することで, 出力先を変更することが可能です.
!>
!> @param[in] diff   印字する日時差
!> @param[in] unit   出力先の装置番号 (デフォルト: 標準出力)
!> @param[in] indent 表示されるメッセージの字下げ
!> @endja
subroutine dcdifftimeputline( diff, unit, indent )
 
  use dc_date_types, only: dc_difftime
  use dc_date_generic, only: tochar
  use dc_string, only: printf
  use dc_trace, only: beginsub, endsub
  use dc_types, only: stdout, string
  use dc_scaledsec, only: dcscaledsecputline
  implicit none
  type(dc_difftime), intent(in) :: diff
  integer, intent(in), optional :: unit
  character(*), intent(in), optional:: indent
 
  integer :: out_unit
  integer:: indent_len
  character(STRING):: indent_str
  character(*), parameter :: subname = 'DCDiffTimePutLine'
continue
  call beginsub(subname)
  if (present(unit)) then
    out_unit = unit
  else
    out_unit = stdout
  end if
 
  indent_len = 0
  indent_str = ''
  if ( present(indent) ) then
    if ( len(indent) /= 0 ) then
      indent_len = len(indent)
      indent_str(1:indent_len) = indent
    end if
  end if
 
  call printf(out_unit, &
    & indent_str(1:indent_len) // &
    & '#<DC_DIFFTIME:: @diff=%c @nondim=%b', &
    & c1 = trim(tochar(diff)), l = (/ diff % nondim_flag /) )
 
  call printf(out_unit, &
    & indent_str(1:indent_len) // &
    & '                @mon=' )
  call dcscaledsecputline( diff % mon, unit = unit, &
    & indent = indent_str(1:indent_len) // &
    & '                     ' )
 
  call printf(out_unit, &
    & indent_str(1:indent_len) // &
    & '                @day=' )
  call dcscaledsecputline( diff % day, unit = unit, &
    & indent = indent_str(1:indent_len) // &
    & '                     ' )
 
  call printf(out_unit, &
    & indent_str(1:indent_len) // &
    & '                @sec=' )
  call dcscaledsecputline( diff % sec, unit = unit, &
    & indent = indent_str(1:indent_len) // &
    & '                     ' )
 
  call printf(out_unit, &
    & indent_str(1:indent_len) // '>' )
 
  call endsub(subname)
end subroutine dcdifftimeputline
 
 
!-----------------------------------------------
!> @en
!> @brief Print DC_DATETIME (for backward compatibility)
!> @param[in] time Datetime to print
!> @param[in] unit Unit number for output
!> @enden
!> @ja
!> @brief DC_DATETIME の印字 (後方互換用)
!> @param[in] time 印字する日時
!> @param[in] unit 出力先の装置番号
!> @endja
subroutine dcdatetimeputline_bc(time, unit)
  use dc_date_types, only: dc_datetime
  use dc_date_generic, only: dcdatetimeputline
  type(dc_datetime), intent(in) :: time
  integer, intent(in), optional :: unit
continue
  call dcdatetimeputline( time, unit )
end subroutine dcdatetimeputline_bc
 
!> @en
!> @brief Print DC_DIFFTIME (for backward compatibility)
!> @param[in] diff Time difference to print
!> @param[in] unit Unit number for output
!> @enden
!> @ja
!> @brief DC_DIFFTIME の印字 (後方互換用)
!> @param[in] diff 印字する日時差
!> @param[in] unit 出力先の装置番号
!> @endja
subroutine dcdifftimeputline_bc(diff, unit)
  use dc_date_types, only: dc_difftime
  use dc_date_generic, only: dcdifftimeputline
  type(dc_difftime), intent(in) :: diff
  integer, intent(in), optional :: unit
continue
  call dcdifftimeputline( diff, unit )
end subroutine dcdifftimeputline_bc