dcdatetimegt.f90

Go to the documentation of this file.

! -*- mode: f90; coding: utf-8 -*-
!-----------------------------------------------------------------------
! Copyright (c) 2000-2026 Gtool Development Group. All rights reserved.
!-----------------------------------------------------------------------
!>
!> @author    Yasuhiro MORIKAWA
!> @copyright Copyright (C) GFD Dennou Club, 2000-2026. All rights reserved. <br/>
!>            License is BSD-2-Clause. see [COPYRIGHT](@ref COPYRIGHT) in detail
!> @en
!> @brief Functions for user defined operation (>)
!> @details
!> This file contains implementation procedures of greater-than
!> comparison for dc_date_types#DC_DATETIME and dc_date_types#DC_DIFFTIME.
!> @enden
!>
!> @ja
!> @brief 利用者定義演算子 (>) のための関数
!> @details
!> このファイルには dc_date_types#DC_DATETIME および dc_date_types#DC_DIFFTIME
!> の大なり比較の実装手続きが含まれています。
!> @endja
!>
 
!> @en
!> @brief Compare two DC_DATETIME variables (>)
!> @details
!> Compare two datetime values.
!> Returns .true. if the datetime stored in the first argument is
!> later than the datetime stored in the second argument.
!>
!> @param[in] time1 First datetime to compare
!> @param[in] time2 Second datetime to compare
!> @return .true. if time1 > time2, .false. otherwise
!> @enden
!>
!> @ja
!> @brief 2つの DC_DATETIME 変数の比較 (>)
!> @details
!> 2 つの引数の日時を比較します.
!> 1 つ目の引数に格納される日時が 2 つ目の引数に格納される日時
!> よりも進んでいる場合, .true. が返ります.
!>
!> @param[in] time1 比較する1番目の日時
!> @param[in] time2 比較する2番目の日時
!> @return time1 > time2 の場合 .true., それ以外は .false.
!> @endja
logical function dcdatetime_gt_tt(time1, time2) result(result)
 
  use dc_date_generic, only: eval, evalsclsec, zonetodiff
  use dc_date_types, only: dc_datetime, dc_difftime
  use dc_scaledsec, only: dc_scaled_sec, &
    & operator(==), operator(<), operator(>), operator(<=), operator(>=), &
    & operator(+), operator(-), operator(*), operator(/), &
    & modulo, int, abs, sign
  implicit none
  type(dc_datetime), intent(in):: time1, time2
  type(dc_scaled_sec):: year1, year2, time1_sec, time2_sec
continue
  call eval(time1, sclyear=year1)
  call eval(time2, sclyear=year2)
  if (year1 > year2) then
    result = .true.
  elseif (year1 < year2) then
    result = .false.
  else
    time1_sec = evalsclsec(time1) + evalsclsec(zonetodiff(time1 % zone))
    time2_sec = evalsclsec(time2) + evalsclsec(zonetodiff(time2 % zone))
    if (time1_sec > time2_sec) then
      result = .true.
    else
      result = .false.
    end if
  end if
end function dcdatetime_gt_tt
 
!> @en
!> @brief Compare two DC_DIFFTIME variables (>)
!> @details
!> Compare two time difference values.
!> Returns .true. if the time difference stored in the first argument is
!> greater than the time difference stored in the second argument.
!>
!> @param[in] diff1 First time difference to compare
!> @param[in] diff2 Second time difference to compare
!> @return .true. if diff1 > diff2, .false. otherwise
!> @enden
!>
!> @ja
!> @brief 2つの DC_DIFFTIME 変数の比較 (>)
!> @details
!> 2 つの引数の日時差を比較します.
!> 1 つ目の引数に格納される日時差が 2 つ目の引数に格納される日時差
!> よりも大きい場合, .true. が返ります.
!>
!> @param[in] diff1 比較する1番目の日時差
!> @param[in] diff2 比較する2番目の日時差
!> @return diff1 > diff2 の場合 .true., それ以外は .false.
!> @endja
logical function dcdatetime_gt_ff(diff1, diff2) result(result)
 
  use dc_date_generic, only: evalsec
  use dc_scaledsec, only: &
    & operator(<), operator(>), operator(<=), operator(>=), operator(==)
  use dc_date_types, only: dc_datetime, dc_difftime
  implicit none
  type(dc_difftime), intent(in):: diff1, diff2
continue
  if ( diff1 % day_seconds == diff2 % day_seconds ) then
 
    if ( diff1 % mon > diff2 % mon ) then
      result = .true.  ; return
    elseif ( diff1 % mon < diff2 % mon ) then
      result = .false. ; return
    end if
    if ( diff1 % day > diff2 % day ) then
      result = .true.  ; return
    elseif ( diff1 % day < diff2 % day ) then
      result = .false. ; return
    end if
    if ( diff1 % sec > diff2 % sec ) then
      result = .true.  ; return
    elseif ( diff1 % sec < diff2 % sec ) then
      result = .false. ; return
    end if
    result = .false.
  else
 
    if (evalsec(diff1) > evalsec(diff2)) then
      result = .true.
    else
      result = .false.
    end if
  end if
end function dcdatetime_gt_ff
 
!> @en
!> @brief Compare DC_DIFFTIME with integer (>)
!> @details
!> Compare a time difference value with an integer.
!> Returns .true. if the time difference stored in the first argument is
!> greater than the integer stored in the second argument.
!>
!> @param[in] diff   Time difference to compare
!> @param[in] factor Integer value to compare
!> @return .true. if diff > factor, .false. otherwise
!> @enden
!>
!> @ja
!> @brief DC_DIFFTIME と整数の比較 (>)
!> @details
!> 2 つの引数の日時差を比較します.
!> 1 つ目の引数に格納される日時差が 2 つ目の引数に格納される日時差
!> よりも大きい場合, .true. が返ります.
!>
!> @param[in] diff   比較する日時差
!> @param[in] factor 比較する整数値
!> @return diff > factor の場合 .true., それ以外は .false.
!> @endja
logical function dcdatetime_gt_fi(diff, factor) result(result)
 
  use dc_date_generic, only: evalsec
  use dc_date_types, only: dc_difftime
  implicit none
  type(dc_difftime), intent(in):: diff
  integer, intent(in):: factor
continue
  result = evalsec(diff) > factor
end function dcdatetime_gt_fi
 
!> @en
!> @brief Compare integer with DC_DIFFTIME (>)
!> @details
!> Compare an integer with a time difference value.
!> Returns .true. if the integer stored in the first argument is
!> greater than the time difference stored in the second argument.
!>
!> @param[in] factor Integer value to compare
!> @param[in] diff   Time difference to compare
!> @return .true. if factor > diff, .false. otherwise
!> @enden
!>
!> @ja
!> @brief 整数と DC_DIFFTIME の比較 (>)
!> @details
!> 2 つの引数の日時差を比較します.
!> 1 つ目の引数に格納される日時差が 2 つ目の引数に格納される日時差
!> よりも大きい場合, .true. が返ります.
!>
!> @param[in] factor 比較する整数値
!> @param[in] diff   比較する日時差
!> @return factor > diff の場合 .true., それ以外は .false.
!> @endja
logical function dcdatetime_gt_if(factor, diff) result(result)
 
  use dc_date_generic, only: evalsec
  use dc_date_types, only: dc_difftime
  implicit none
  integer, intent(in):: factor
  type(dc_difftime), intent(in):: diff
continue
  result = factor > evalsec(diff)
end function dcdatetime_gt_if