DC_DATETIME/DC_DIFFTIME 型変数から月日秒への変換 More...

Functions/Subroutines
subroutine	dcdatetimeeval1 (time, year, mon, day, hour, min, sec, caltype, zone, sclyear, sclmon, sclday, sclsec)
subroutine	dcdifftimeeval1 (diff, year, mon, day, hour, min, sec, nondim, sclyear, sclmon, sclday, sclsec, sclnondim, err)
real(dp) function	dcdatetimeevalday (time)
real(dp) function	dcdifftimeevalday (diff)
real(dp) function	dcdatetimeevalhour (time)
real(dp) function	dcdifftimeevalhour (diff)
real(dp) function	dcdatetimeevalmin (time)
real(dp) function	dcdifftimeevalmin (diff)
real(dp) function	dcdatetimeevalsec (time)
real(dp) function	dcdifftimeevalsec (diff)
real(dp) function	dcdifftimeevalnondim (diff)
type(dc_scaled_sec) function	dcdatetimeevalsclsec (time)
type(dc_scaled_sec) function	dcdifftimeevalsclsec (diff)
real(dp) function	dcdatetimeevalbyunit (time, unit, unit_symbol)
real(dp) function	dcdifftimeevalbyunit (diff, unit, unit_symbol)

Detailed Description

DC_DATETIME/DC_DIFFTIME 型変数から月日秒への変換

Author: Yasuhiro MORIKAWA, Eizi TOYODA

Copyright: Copyright (C) GFD Dennou Club, 2000-2026. All rights reserved.
License is BSD-2-Clause. see COPYRIGHT in detail

このファイルで提供される手続き群は dc_date モジュールにて提供されます.

Definition in file dcdatetimeeval.f90.

Function/Subroutine Documentation

◆ dcdatetimeeval1()

subroutine dcdatetimeeval1	(	type(dc_datetime), intent(in)	time,
		integer, intent(out), optional	year,
		integer, intent(out), optional	mon,
		integer, intent(out), optional	day,
		integer, intent(out), optional	hour,
		integer, intent(out), optional	min,
		real(dp), intent(out), optional	sec,
		integer, intent(out), optional	caltype,
		character(*), intent(out), optional	zone,
		type(dc_scaled_sec), intent(out), optional	sclyear,
		type(dc_scaled_sec), intent(out), optional	sclmon,
		type(dc_scaled_sec), intent(out), optional	sclday,
		type(dc_scaled_sec), intent(out), optional	sclsec )

DC_DATETIME を日時成分に変換

DC_DATETIME 型変数 time を年, 月, 日, 時間, 分, 秒, 暦法, タイムゾーンに変換して返します.

Parameters

[in]	time	変換する DC_DATETIME 型変数
[out]	year	年 (省略可能)
[out]	mon	月 (省略可能)
[out]	day	日 (省略可能)
[out]	hour	時 (省略可能)
[out]	min	分 (省略可能)
[out]	sec	秒 (省略可能)
[out]	caltype	暦法 (省略可能)
[out]	zone	タイムゾーン (UTC からの時差) (省略可能)
[out]	sclyear	年 (DC_SCALED_SEC 型) (省略可能)
[out]	sclmon	月 (DC_SCALED_SEC 型) (省略可能)
[out]	sclday	日 (DC_SCALED_SEC 型) (省略可能)
[out]	sclsec	秒 (DC_SCALED_SEC 型) (省略可能)

Definition at line 63 of file dcdatetimeeval.f90.

  use dc_types, only: dp
  use dc_date_types, only: dc_datetime, &
    & cyclic_mdays, cal_noleap, cal_julian, cal_cyclic, &
    & year_months, year_days, four_years, four_century, &
    & hour_seconds, min_seconds
  use dc_scaledsec, only:  dc_scaled_sec, &
    & assignment(=), dcscaledsecputline, &
    & operator(==), operator(>), operator(<), operator(>=), operator(<=), &
    & operator(+), operator(-), operator(*), operator(/), mod, modulo, &
    & abs, int, floor, ceiling
  use dc_trace, only: beginsub, endsub
  implicit none
  type(DC_DATETIME), intent(in):: time
  integer, intent(out), optional:: year ! 年
  integer, intent(out), optional:: mon  ! 月
  integer, intent(out), optional:: day  ! 日
  integer, intent(out), optional:: hour ! 時
  integer, intent(out), optional:: min  ! 分
  real(DP),intent(out), optional:: sec  ! 秒
  integer, intent(out), optional:: caltype ! 暦法
  character(*), intent(out), optional:: zone ! タイムゾーン (UTC からの時差)
  type(DC_SCALED_SEC), intent(out), optional:: sclyear ! 年 (DC_SCALED_SEC 型)
  type(DC_SCALED_SEC), intent(out), optional:: sclmon  ! 月 (DC_SCALED_SEC 型)
  type(DC_SCALED_SEC), intent(out), optional:: sclday  ! 日 (DC_SCALED_SEC 型)
  type(DC_SCALED_SEC), intent(out), optional:: sclsec  ! 秒 (DC_SCALED_SEC 型)
 
  type(DC_SCALED_SEC):: iyear, month, iday, imon, isec
  !character(*), parameter :: subname = 'DCDateTimeEval1'
continue
  !call BeginSub(subname)
  if (present(zone)) then
    zone = time % zone
  end if
  if (present(caltype)) then
    caltype = time % caltype
  end if
  isec = time % sec
  if (present(hour)) then
    hour = floor(isec / hour_seconds)
    isec = modulo(isec, hour_seconds)
  end if
  if (present(min)) then
    min = floor(isec / min_seconds)
    isec = modulo(isec, min_seconds)
  end if
  if (present(sec)) then
    sec = isec
  end if
  if (present(sclsec)) then
    sclsec = isec
  end if
 
  if (time % caltype == cal_cyclic) then
    iday = time % day
    if (present(year)) year = 0
    if (present(sclyear)) sclyear = 0
    if (present(sclmon)) then
      sclmon = floor(iday / cyclic_mdays)
      iday = ceiling( modulo(iday, cyclic_mdays) )
    elseif (present(mon)) then
      mon = floor(iday / cyclic_mdays)
      iday = ceiling( modulo(iday, cyclic_mdays) )
    end if
    if (present(day)) day = iday
    if (present(sclday)) sclday = iday
    goto 999
  endif
  if (time % caltype == cal_noleap) then
    iday = int( modulo(time%day - 91, year_days) )
    iyear = int( (time%day - 91 - iday) / year_days )
  else
    if (time % caltype == cal_julian) then
      iday = int( modulo(time%day - 92, four_years) )
      iyear = int( (time%day - 92 - iday) / four_years ) * 4
    elseif (time%day < 640196) then
      iday = int( modulo(time%day - 92, four_years) )
      iyear = int( (time%day - 92 - iday) / four_years ) * 4
    else
      iday = int( modulo(time%day - 94, four_century) )
      iyear = int( (time%day - 94 - iday) / four_century ) * 400
      if (iday == four_century - 1) then
        iyear = iyear + 300
        iday = 36525
      else
        iyear = iyear + int( iday / 36524 ) * 100
        iday = int( modulo(iday, 36524) )
      endif
      iyear = iyear + int( iday / four_years ) * 4
      iday = int( modulo(iday, four_years) )
    endif
    if (iday == four_years - 1) then
      iyear = iyear + 3
      iday = year_days
    else
      iyear = iyear + int( iday / year_days )
      iday = int( modulo(iday, year_days) )
    endif
  endif
 
  iday = iday * 10 + 922
  month = int( iday / 306 )
 
  if (present(sclyear)) then
    imon = mod(month - 1, year_months) + 1
    sclyear = iyear + int( (month - imon) / year_months )
  elseif (present(year)) then
    imon = mod(month - 1, year_months) + 1
    year = iyear + int( (month - imon) / year_months )
  else
    imon = month
  end if
  if (present(sclmon)) then
    iday = int( mod(iday, 306) / 10 ) + 1
    sclmon = imon
  elseif (present(mon)) then
    iday = int( mod(iday, 306) / 10 ) + 1
    mon = imon
  else
    iday = int( iday / 10 )  + 1
  end if
 
  if (present(day)) day = iday
  if (present(sclday)) sclday = iday
 
999 continue
  !call EndSub(subname)

References dc_trace::beginsub(), dc_date_types::cal_cyclic, dc_date_types::cal_julian, dc_date_types::cal_noleap, dc_date_types::cyclic_mdays, dc_scaledsec::dcscaledsecputline(), dc_types::dp, dc_trace::endsub(), dc_date_types::four_century, dc_date_types::four_years, dc_date_types::hour_seconds, dc_date_types::min_seconds, dc_date_types::year_days, and dc_date_types::year_months.

Here is the call graph for this function:

◆ dcdatetimeevalbyunit()

real(dp) function dcdatetimeevalbyunit	(	type(dc_datetime), intent(in)	time,
		character(*), intent(in)	unit,
		integer, intent(in), optional	unit_symbol )

DC_DATETIME を指定単位で変換

DC_DATETIME 型変数の日時を unit または unit_symbol の単位に換算して倍精度実数型変数で返します.

unit には以下を与えることが可能です:

dc_date_types#UNIT_DAY (日)
dc_date_types#UNIT_HOUR (時)
dc_date_types#UNIT_MIN (分)
dc_date_types#UNIT_SEC (秒)

unit_symbol には以下を与えることが可能です:

dc_date_types#UNIT_SYMBOL_DAY (日)
dc_date_types#UNIT_SYMBOL_HOUR (時)
dc_date_types#UNIT_SYMBOL_MIN (分)
dc_date_types#UNIT_SYMBOL_SEC (秒)

これらに該当しないものを与えた場合, または引数を両方とも与えない場合, 0.0 が返ります.

Parameters

[in]	time	変換する DC_DATETIME 型変数
[in]	unit	単位文字列
[in]	unit_symbol	単位記号定数 (省略可能)

Returns: 変換された値 (倍精度実数型)

Definition at line 807 of file dcdatetimeeval.f90.

  use dc_types, only: dp
  use dc_date_generic, only: evalsec, evalmin, evalhour, evalday, parsetimeunits
  use dc_date_types, only: dc_datetime, &
    & unit_symbol_day, unit_symbol_hour, unit_symbol_min, unit_symbol_sec, &
    & unit_symbol_err
  implicit none
  real(DP):: result
  type(DC_DATETIME), intent(in):: time
  character(*), intent(in):: unit
  integer, intent(in), optional:: unit_symbol
  integer:: symbol
continue
  symbol = unit_symbol_err
  if ( present(unit_symbol) ) then
    symbol = unit_symbol
  else
    symbol = parsetimeunits(unit)
  end if
 
  if ( symbol == unit_symbol_sec ) then
    result = evalsec(time)
  elseif ( symbol == unit_symbol_min ) then
    result = evalmin(time)
  elseif ( symbol == unit_symbol_hour ) then
    result = evalhour(time)
  elseif ( symbol == unit_symbol_day ) then
    result = evalday(time)
  else
    result = 0.0_dp
  end if

References dc_types::dp, dc_date_types::unit_symbol_day, dc_date_types::unit_symbol_err, dc_date_types::unit_symbol_hour, dc_date_types::unit_symbol_min, and dc_date_types::unit_symbol_sec.

◆ dcdatetimeevalday()

real(dp) function dcdatetimeevalday ( type(dc_datetime), intent(in) time )

DC_DATETIME を日数に変換

DC_DATETIME 型変数の日時を日数に換算して倍精度実数型変数で返します. (例えば 12 時間は 0.5 日と換算されます)

Parameters

[in] time 変換する DC_DATETIME 型変数

Returns: 日数 (倍精度実数型)

Definition at line 354 of file dcdatetimeeval.f90.

  use dc_types, only: dp
  use dc_date_generic, only: eval
  use dc_date_types, only: dc_datetime
  use dc_scaledsec, only: dc_scaled_sec, assignment(=), operator(/), operator(+)
  implicit none
  real(DP):: result
  type(DC_DATETIME), intent(in):: time
  type(DC_SCALED_SEC):: day, sec
continue
  call eval(time, sclday = day, sclsec = sec)
  result = day + sec / time % day_seconds

References dc_types::dp.

◆ dcdatetimeevalhour()

real(dp) function dcdatetimeevalhour ( type(dc_datetime), intent(in) time )

DC_DATETIME を時間に変換

DC_DATETIME 型変数の日時を時間に換算して倍精度実数型変数で返します. (例えば 2 日は 48 時間に, 30 分は 0.5 時間と換算されます)

Parameters

[in] time 変換する DC_DATETIME 型変数

Returns: 時間 (倍精度実数型)

Definition at line 426 of file dcdatetimeeval.f90.

  use dc_types, only: dp
  use dc_date_generic, only: eval
  use dc_date_types, only: dc_datetime, hour_seconds
  use dc_scaledsec, only: dc_scaled_sec, assignment(=), operator(/), &
    & operator(+), operator(*), int
  implicit none
  real(DP):: result
  type(DC_DATETIME), intent(in):: time
  type(DC_SCALED_SEC):: day, sec
continue
  call eval(time, sclday = day, sclsec = sec)
  result = (day * time % day_seconds + sec) / hour_seconds

References dc_types::dp, and dc_date_types::hour_seconds.

◆ dcdatetimeevalmin()

real(dp) function dcdatetimeevalmin ( type(dc_datetime), intent(in) time )

DC_DATETIME を分に変換

DC_DATETIME 型変数の日時を分に換算して倍精度実数型変数で返します. (例えば 1 日は 1440 分に, 30 秒は 0.5 分と換算されます)

Parameters

[in] time 変換する DC_DATETIME 型変数

Returns: 分 (倍精度実数型)

Definition at line 500 of file dcdatetimeeval.f90.

  use dc_types, only: dp
  use dc_date_generic, only: eval
  use dc_date_types, only: dc_datetime, min_seconds
  use dc_scaledsec, only: dc_scaled_sec, assignment(=), operator(/), &
    & operator(+), operator(*), int
  implicit none
  real(DP):: result
  type(DC_DATETIME), intent(in):: time
  type(DC_SCALED_SEC):: day, sec
continue
  call eval(time, sclday = day, sclsec = sec)
  result = (day * time % day_seconds + sec) / min_seconds

References dc_types::dp, and dc_date_types::min_seconds.

◆ dcdatetimeevalsclsec()

type(dc_scaled_sec) function dcdatetimeevalsclsec ( type(dc_datetime), intent(in) time )

DC_DATETIME を秒に変換 (DC_SCALED_SEC 型)

DC_DATETIME 型変数の日時を秒に換算して DC_SCALED_SEC 型で返します.

Warning: 年の要素は無視されます. すなわち, 1999-01-01 が格納された time と 2007-01-01 が格納された time からは同じ値が返ります. (これはもしかすると望ましくない動作かもしれません)

Parameters

[in] time 変換する DC_DATETIME 型変数

Returns: 秒 (DC_SCALED_SEC 型)

Definition at line 696 of file dcdatetimeeval.f90.

  use dc_date_generic, only: eval
  use dc_date_types, only: dc_datetime
  use dc_scaledsec, only: dc_scaled_sec, operator(/), &
    & operator(+), operator(*), int
  implicit none
  type(DC_SCALED_SEC):: result
  type(DC_DATETIME), intent(in):: time
  type(DC_SCALED_SEC):: day, sec
continue
  call eval(time, sclday = day, sclsec = sec)
  result = day * time % day_seconds + sec

◆ dcdatetimeevalsec()

real(dp) function dcdatetimeevalsec ( type(dc_datetime), intent(in) time )

DC_DATETIME を秒に変換

DC_DATETIME 型変数の日時を秒に換算して倍精度実数型変数で返します.

Warning: 年の要素は無視されます. すなわち, 1999-01-01 が格納された time と 2007-01-01 が格納された time からは同じ値が返ります. (これはもしかすると望ましくない動作かもしれません)

Parameters

[in] time 変換する DC_DATETIME 型変数

Returns: 秒 (倍精度実数型)

Definition at line 580 of file dcdatetimeeval.f90.

  use dc_types, only: dp
  use dc_date_generic, only: eval
  use dc_date_types, only: dc_datetime
  use dc_scaledsec, only: assignment(=)
  implicit none
  real(DP):: result
  type(DC_DATETIME), intent(in):: time
  integer:: day
  real(DP):: sec, day_seconds
continue
  call eval(time, day = day, sec = sec)
  day_seconds = time % day_seconds
  result = day * day_seconds + sec

References dc_date_types::day_seconds, and dc_types::dp.

◆ dcdifftimeeval1()

subroutine dcdifftimeeval1	(	type(dc_difftime), intent(in)	diff,
		integer, intent(out), optional	year,
		integer, intent(out), optional	mon,
		integer, intent(out), optional	day,
		integer, intent(out), optional	hour,
		integer, intent(out), optional	min,
		real(dp), intent(out), optional	sec,
		real(dp), intent(out), optional	nondim,
		type(dc_scaled_sec), intent(out), optional	sclyear,
		type(dc_scaled_sec), intent(out), optional	sclmon,
		type(dc_scaled_sec), intent(out), optional	sclday,
		type(dc_scaled_sec), intent(out), optional	sclsec,
		type(dc_scaled_sec), intent(out), optional	sclnondim,
		logical, intent(out), optional	err )

DC_DIFFTIME を時間成分に変換

DC_DIFFTIME 型変数 diff を年, 月, 日, 時間, 分, 秒, 無次元時間に変換して返します.

Parameters

[in]	diff	変換する DC_DIFFTIME 型変数
[out]	year	年 (省略可能)
[out]	mon	月 (省略可能)
[out]	day	日 (省略可能)
[out]	hour	時 (省略可能)
[out]	min	分 (省略可能)
[out]	sec	秒 (省略可能)
[out]	nondim	無次元時間 (省略可能)
[out]	sclyear	年 (DC_SCALED_SEC 型) (省略可能)
[out]	sclmon	月 (DC_SCALED_SEC 型) (省略可能)
[out]	sclday	日 (DC_SCALED_SEC 型) (省略可能)
[out]	sclsec	秒 (DC_SCALED_SEC 型) (省略可能)
[out]	sclnondim	無次元時間 (DC_SCALED_SEC 型) (省略可能)
[out]	err	エラーフラグ (省略可能)

Definition at line 237 of file dcdatetimeeval.f90.

  use dc_types, only: dp
  use dc_trace, only: beginsub, endsub
  use dc_error, only: storeerror, dc_noerr, dc_enodimtime, dc_edimtime
  use dc_date_types, only: dc_difftime, &
    & min_seconds, hour_seconds, year_months
  use dc_scaledsec, only:  dc_scaled_sec, &
    & assignment(=), dcscaledsecputline, &
    & operator(==), operator(>), operator(<), operator(>=), operator(<=), &
    & operator(+), operator(-), operator(*), operator(/), mod, modulo, &
    & abs, int, floor, ceiling
  implicit none
  type(DC_DIFFTIME), intent(in):: diff
  integer, intent(out), optional:: year ! 年
  integer, intent(out), optional:: mon  ! 月
  integer, intent(out), optional:: day  ! 日
  integer, intent(out), optional:: hour ! 時
  integer, intent(out), optional:: min  ! 分
  real(DP),intent(out), optional:: sec  ! 秒
  real(DP),intent(out), optional:: nondim  ! 無次元時間. Nondimensional time
  type(DC_SCALED_SEC), intent(out), optional:: sclyear ! 年 (DC_SCALED_SEC 型)
  type(DC_SCALED_SEC), intent(out), optional:: sclmon  ! 月 (DC_SCALED_SEC 型)
  type(DC_SCALED_SEC), intent(out), optional:: sclday  ! 日 (DC_SCALED_SEC 型)
  type(DC_SCALED_SEC), intent(out), optional:: sclsec  ! 秒 (DC_SCALED_SEC 型)
  type(DC_SCALED_SEC), intent(out), optional:: sclnondim  ! 無次元時間 (DC_SCALED_SEC 型)
  logical, intent(out), optional :: err
  type(DC_SCALED_SEC):: imon, isec
  integer:: stat
  character(*), parameter :: subname = 'DCDiffTimeEval1'
continue
  !call BeginSub(subname)
  stat = dc_noerr
  if ( present(sclnondim) ) then
    if ( .not. diff % nondim_flag ) then
      stat = dc_edimtime
      goto 999
    end if
    sclnondim = diff % sec
  elseif ( present(nondim) ) then
    if ( .not. diff % nondim_flag ) then
      stat = dc_edimtime
      goto 999
    end if
    nondim = diff % sec
  else
    if ( diff % nondim_flag ) then
      stat = dc_enodimtime
      goto 999
    end if
  end if
 
  imon = diff % mon
  isec = diff % sec
  if (present(sclyear)) then
    sclyear = int( imon / year_months )
    imon = mod(imon, year_months)
  elseif (present(year)) then
    year = int( imon / year_months )
    imon = mod(imon, year_months)
  endif
 
  if (present(sclmon)) then
    sclmon = imon
  elseif (present(mon)) then
    mon = imon
  endif
 
  if (present(sclday)) then
    sclday = diff % day
  elseif (present(day)) then
    day = diff % day
  else
    isec = isec + diff % day * diff % day_seconds
  endif
 
  if (present(hour)) then
    hour = int(isec / hour_seconds)
    isec = mod(isec, hour_seconds)
  endif
  if (present(min)) then
    min = int(isec / min_seconds)
    isec = mod(isec, min_seconds)
  endif
 
  if (present(sec)) then
    sec = isec
  endif
  if (present(sclsec)) then
    sclsec = isec
  endif
999 continue
  call storeerror(stat, subname, err)
  !call EndSub(subname)

References dc_trace::beginsub(), dc_error::dc_edimtime, dc_error::dc_enodimtime, dc_error::dc_noerr, dc_scaledsec::dcscaledsecputline(), dc_types::dp, dc_trace::endsub(), dc_date_types::hour_seconds, dc_date_types::min_seconds, dc_error::storeerror(), and dc_date_types::year_months.

Here is the call graph for this function:

◆ dcdifftimeevalbyunit()

real(dp) function dcdifftimeevalbyunit	(	type(dc_difftime), intent(in)	diff,
		character(*), intent(in)	unit,
		integer, intent(in), optional	unit_symbol )

DC_DIFFTIME を指定単位で変換

DC_DIFFTIME 型変数の日時を unit の単位に換算して倍精度実数型変数で返します.

unit には以下を与えることが可能です:

dc_date_types#UNIT_DAY (日)
dc_date_types#UNIT_HOUR (時)
dc_date_types#UNIT_MIN (分)
dc_date_types#UNIT_SEC (秒)
dc_date_types#UNIT_NONDIM (無次元時間)

unit_symbol には以下を与えることが可能です:

dc_date_types#UNIT_SYMBOL_DAY (日)
dc_date_types#UNIT_SYMBOL_HOUR (時)
dc_date_types#UNIT_SYMBOL_MIN (分)
dc_date_types#UNIT_SYMBOL_SEC (秒)
dc_date_types#UNIT_SYMBOL_NONDIM (無次元時間)

これらに該当しないものを与えた場合, または引数を両方とも与えない場合, 0.0 が返ります.

Parameters

[in]	diff	変換する DC_DIFFTIME 型変数
[in]	unit	単位文字列
[in]	unit_symbol	単位記号定数 (省略可能)

Returns: 変換された値 (倍精度実数型)

Definition at line 897 of file dcdatetimeeval.f90.

  use dc_types, only: dp
  use dc_date_generic, only: evalnondim, evalsec, evalmin, evalhour, evalday, &
    & parsetimeunits
  use dc_date_types, only: dc_difftime, &
    & unit_symbol_day, unit_symbol_hour, unit_symbol_min, &
    & unit_symbol_sec, unit_symbol_nondim, unit_symbol_err
  implicit none
  real(DP):: result
  type(DC_DIFFTIME), intent(in):: diff
  character(*), intent(in):: unit
  integer, intent(in), optional:: unit_symbol
  integer:: symbol
continue
  symbol = unit_symbol_err
  if ( present(unit_symbol) ) then
    symbol = unit_symbol
  else
    symbol = parsetimeunits(unit)
  end if
 
  if ( symbol == unit_symbol_nondim ) then
    result = evalnondim(diff)
  elseif ( symbol == unit_symbol_sec ) then
    result = evalsec(diff)
  elseif ( symbol == unit_symbol_min ) then
    result = evalmin(diff)
  elseif ( symbol == unit_symbol_hour ) then
    result = evalhour(diff)
  elseif ( symbol == unit_symbol_day ) then
    result = evalday(diff)
  else
    result = 0.0_dp
  end if

References dc_types::dp, dc_date_types::unit_symbol_day, dc_date_types::unit_symbol_err, dc_date_types::unit_symbol_hour, dc_date_types::unit_symbol_min, dc_date_types::unit_symbol_nondim, and dc_date_types::unit_symbol_sec.

◆ dcdifftimeevalday()

real(dp) function dcdifftimeevalday ( type(dc_difftime), intent(in) diff )

DC_DIFFTIME を日数に変換

DC_DIFFTIME 型変数の日時を日数に換算して倍精度実数型変数で返します. (例えば 12 時間は 0.5 日と換算されます)

1 ヶ月は dc_date_types#CYCLIC_MDAYS と換算します.

Parameters

[in] diff 変換する DC_DIFFTIME 型変数

Returns: 日数 (倍精度実数型)

Definition at line 391 of file dcdatetimeeval.f90.

  use dc_types, only: dp
  use dc_date_generic, only: eval
  use dc_date_types, only: dc_difftime, cyclic_mdays
  use dc_scaledsec, only: dc_scaled_sec, assignment(=), operator(/), &
    & operator(+), operator(*), int
  implicit none
  real(DP):: result
  type(DC_DIFFTIME), intent(in):: diff
  type(DC_SCALED_SEC):: day, mon, sec
continue
  call eval(diff, sclmon = mon, sclday = day, sclsec = sec)
  result = int(mon * cyclic_mdays) + day + sec / diff % day_seconds

References dc_date_types::cyclic_mdays, and dc_types::dp.

◆ dcdifftimeevalhour()

real(dp) function dcdifftimeevalhour ( type(dc_difftime), intent(in) diff )

DC_DIFFTIME を時間に変換

DC_DIFFTIME 型変数の日時を時間に換算して倍精度実数型変数で返します. (例えば 2 日は 48 時間に, 30 分は 0.5 時間と換算されます)

1 ヶ月は dc_date_types#CYCLIC_MDAYS と換算します.

Parameters

[in] diff 変換する DC_DIFFTIME 型変数

Returns: 時間 (倍精度実数型)

Definition at line 464 of file dcdatetimeeval.f90.

  use dc_types, only: dp
  use dc_date_generic, only: eval
  use dc_date_types, only: dc_difftime, hour_seconds, cyclic_mdays
  use dc_scaledsec, only: dc_scaled_sec, assignment(=), operator(/), &
    & operator(+), operator(*), int
  implicit none
  real(DP):: result
  type(DC_DIFFTIME), intent(in):: diff
  type(DC_SCALED_SEC):: mon, day, sec
continue
  call eval(diff, sclmon = mon, sclday = day, sclsec = sec)
  result = ( int(mon * cyclic_mdays) + day &
    &         * diff % day_seconds + sec) / hour_seconds

References dc_date_types::cyclic_mdays, dc_types::dp, and dc_date_types::hour_seconds.

◆ dcdifftimeevalmin()

real(dp) function dcdifftimeevalmin ( type(dc_difftime), intent(in) diff )

DC_DIFFTIME を分に変換

DC_DIFFTIME 型変数の日時を分に換算して倍精度実数型変数で返します. (例えば 1 日は 1440 分に, 30 秒は 0.5 分と換算されます)

1 ヶ月は dc_date_types#CYCLIC_MDAYS と換算します.

Parameters

[in] diff 変換する DC_DIFFTIME 型変数

Returns: 分 (倍精度実数型)

Definition at line 538 of file dcdatetimeeval.f90.

  use dc_types, only: dp
  use dc_date_generic, only: eval
  use dc_date_types, only: dc_difftime, min_seconds, cyclic_mdays
  use dc_scaledsec, only: dc_scaled_sec, assignment(=), operator(/), &
    & operator(+), operator(*), int
  implicit none
  real(DP):: result
  type(DC_DIFFTIME), intent(in):: diff
  type(DC_SCALED_SEC):: mon, day, sec
continue
  call eval(diff, sclmon = mon, sclday = day, sclsec = sec)
  result = ( int(mon * cyclic_mdays) + day &
    &         * diff % day_seconds + sec) / min_seconds

References dc_date_types::cyclic_mdays, dc_types::dp, and dc_date_types::min_seconds.

◆ dcdifftimeevalnondim()

real(dp) function dcdifftimeevalnondim ( type(dc_difftime), intent(in) diff )

DC_DIFFTIME を無次元時間に変換

DC_DIFFTIME 型変数の日時を無次元時間に換算して倍精度実数型変数で返します.

1 ヶ月は dc_date_types#CYCLIC_MDAYS と換算します.

Parameters

[in] diff 変換する DC_DIFFTIME 型変数

Returns: 無次元時間 (倍精度実数型)

Definition at line 658 of file dcdatetimeeval.f90.

  use dc_types, only: dp
  use dc_date_generic, only: eval
  use dc_date_types, only: dc_difftime
  implicit none
  real(DP):: result
  type(DC_DIFFTIME), intent(in):: diff
  real(DP):: nondim
continue
  call eval(diff, nondim=nondim)
  result = nondim

References dc_types::dp.

◆ dcdifftimeevalsclsec()

type(dc_scaled_sec) function dcdifftimeevalsclsec ( type(dc_difftime), intent(in) diff )

DC_DIFFTIME を秒に変換 (DC_SCALED_SEC 型)

DC_DIFFTIME 型変数の日時を秒に換算して DC_SCALED_SEC 型で返します.

1 ヶ月は dc_date_types#CYCLIC_MDAYS と換算します.

Parameters

[in] diff 変換する DC_DIFFTIME 型変数

Returns: 秒 (DC_SCALED_SEC 型)

Definition at line 731 of file dcdatetimeeval.f90.

  use dc_date_generic, only: eval
  use dc_date_types, only: dc_difftime, cyclic_mdays
  use dc_scaledsec, only: dc_scaled_sec, operator(/), &
    & operator(==), operator(+), operator(*), int
  implicit none
  type(DC_SCALED_SEC):: result
  type(DC_DIFFTIME), intent(in):: diff
  type(DC_SCALED_SEC):: mon, day, sec
  type(DC_SCALED_SEC):: zero_sec
continue
  if ( .not. diff % nondim_flag ) then
    call eval(diff, sclmon = mon, sclday = day, sclsec = sec)
    if ( mon == zero_sec ) then
      result = day * diff % day_seconds + sec
    else
      result = ( int(mon * cyclic_mdays) + day ) * diff % day_seconds + sec
    end if
  else
    call eval(diff, sclnondim = sec)
    result = sec
  end if

References dc_date_types::cyclic_mdays.

◆ dcdifftimeevalsec()

real(dp) function dcdifftimeevalsec ( type(dc_difftime), intent(in) diff )

DC_DIFFTIME を秒に変換

DC_DIFFTIME 型変数の日時を秒に換算して倍精度実数型変数で返します.

1 ヶ月は dc_date_types#CYCLIC_MDAYS と換算します.

Parameters

[in] diff 変換する DC_DIFFTIME 型変数

Returns: 秒 (倍精度実数型)

Definition at line 617 of file dcdatetimeeval.f90.

  use dc_types, only: dp
  use dc_date_generic, only: eval
  use dc_date_types, only: dc_difftime, cyclic_mdays
  use dc_scaledsec, only: assignment(=)
  implicit none
  real(DP):: result
  type(DC_DIFFTIME), intent(in):: diff
  integer:: mon, day
  real(DP):: sec, day_seconds
continue
  if ( .not. diff % nondim_flag ) then
    call eval(diff, mon = mon, day = day, sec = sec)
    day_seconds = diff % day_seconds
    result = int(mon * cyclic_mdays) + day * day_seconds + sec
  else
    call eval(diff, nondim = result)
  end if

References dc_date_types::cyclic_mdays, dc_date_types::day_seconds, and dc_types::dp.

Functions/Subroutines

Detailed Description

Function/Subroutine Documentation

◆ dcdatetimeeval1()

◆ dcdatetimeevalbyunit()

◆ dcdatetimeevalday()

◆ dcdatetimeevalhour()

◆ dcdatetimeevalmin()

◆ dcdatetimeevalsclsec()

◆ dcdatetimeevalsec()

◆ dcdifftimeeval1()

◆ dcdifftimeevalbyunit()

◆ dcdifftimeevalday()

◆ dcdifftimeevalhour()

◆ dcdifftimeevalmin()

◆ dcdifftimeevalnondim()

◆ dcdifftimeevalsclsec()

◆ dcdifftimeevalsec()