dcdatetimeadd.f90

Go to the documentation of this file.

! -*- mode: f90; coding: utf-8 -*-
!-----------------------------------------------------------------------
! Copyright (c) 2000-2026 Gtool Development Group. All rights reserved.
!-----------------------------------------------------------------------
!>
!> @author    Yasuhiro MORIKAWA, Eizi TOYODA
!> @copyright Copyright (C) GFD Dennou Club, 2000-2026. All rights reserved. <br/>
!>            License is BSD-2-Clause. see [COPYRIGHT](@ref COPYRIGHT) in detail
!> @en
!> @brief Functions for user defined operation (+)
!> @details
!> Procedures described in this file are provided from "dc_date" module.
!> @enden
!>
!> @ja
!> @brief 利用者定義演算子 (+) のための関数
!> @details
!> このファイルに記載される手続き群は dc_date モジュールから提供されます.
!> @endja
!>
 
!> @en
!> @brief Add DC_DIFFTIME to DC_DATETIME
!> @details
!> Adds two datetime (DC_DATETIME type) or
!> time difference (DC_DIFFTIME type).
!>
!> @param[in] diff Time difference
!> @param[in] time Datetime
!> @return result Result of addition
!> @enden
!>
!> @ja
!> @brief DC_DIFFTIME を DC_DATETIME に加算
!> @details
!> 2 つの日時 (DC_DATETIME 型) もしくは
!> 日時差 (DC_DIFFTIME 型)の加算を行います.
!>
!> @param[in] diff 日時差
!> @param[in] time 日時
!> @return result 加算結果
!> @endja
function dcdatetime_add_ft(diff, time) result(result)
  use dc_date_types, only: dc_datetime, dc_difftime
  use dc_date_generic, only: dcdatetimecreate, eval
  use dc_scaledsec, only: dc_scaled_sec, &
    & operator(<), operator(>), operator(<=), operator(>=), &
    & operator(+), operator(-), operator(*), operator(/), &
    & modulo, int, abs, sign
  implicit none
  type(dc_datetime):: result
  type(dc_difftime), intent(in):: diff
  type(dc_datetime), intent(in):: time
  type(dc_scaled_sec):: time_year, time_mon, time_day, time_sec
  integer:: time_caltype
  character(6):: time_zone
continue
  call eval(time, sclyear = time_year, sclmon = time_mon, &
    & sclday = time_day, sclsec = time_sec, &
    & caltype = time_caltype, zone = time_zone)
  call dcdatetimecreate(result, sclyear = time_year, &
    & sclmon = time_mon + diff % mon, &
    & sclday = time_day + diff % day, &
    & sclsec = time_sec + diff % sec, &
    & caltype = time_caltype, zone = time_zone)
end function dcdatetime_add_ft
 
!> @en
!> @brief Add DC_DIFFTIME to DC_DATETIME (reversed order)
!> @param[in] time Datetime
!> @param[in] diff Time difference
!> @return result Result of addition
!> @enden
!>
!> @ja
!> @brief DC_DIFFTIME を DC_DATETIME に加算 (引数順序逆)
!> @param[in] time 日時
!> @param[in] diff 日時差
!> @return result 加算結果
!> @endja
  function dcdatetime_add_tf(time, diff) result(result)
    use dc_date_generic, only: operator(+)
    use dc_date_types, only: dc_datetime, dc_difftime
    implicit none
  type(dc_datetime):: result
  type(dc_datetime), intent(in):: time
  type(dc_difftime), intent(in):: diff
continue
  result = diff + time
end function dcdatetime_add_tf
 
!> @en
!> @brief Add two DC_DIFFTIME values
!> @param[in] diff1 First time difference
!> @param[in] diff2 Second time difference
!> @return result Result of addition
!> @enden
!>
!> @ja
!> @brief 2つの DC_DIFFTIME 値を加算
!> @param[in] diff1 1つ目の日時差
!> @param[in] diff2 2つ目の日時差
!> @return result 加算結果
!> @endja
function dcdatetime_add_ff(diff1, diff2) result(result)
  use dc_date_types, only: dc_datetime, dc_difftime
  use dc_date_internal, only: dcdate_normalize, dcdate_nondimcheck
  use dc_scaledsec, only: operator(+)
  implicit none
  type(dc_difftime):: result
  type(dc_difftime), intent(in):: diff1, diff2
continue
  result % mon = diff1 % mon + diff2 % mon
  result % day = diff1 % day + diff2 % day
  result % sec = diff1 % sec + diff2 % sec
  result % day_seconds = diff1 % day_seconds
  call dcdate_nondimcheck('dc_date#operator(+)', diff1, diff2, result)
  call dcdate_normalize(result % day, result % sec, result % day_seconds, result % nondim_flag)
end function dcdatetime_add_ff
 
!> @en
!> @brief Add double precision seconds to DC_DIFFTIME
!> @param[in] diff Time difference
!> @param[in] sec Seconds to add (double precision)
!> @return result Result of addition
!> @enden
!>
!> @ja
!> @brief 倍精度秒数を DC_DIFFTIME に加算
!> @param[in] diff 日時差
!> @param[in] sec 加算する秒数 (倍精度)
!> @return result 加算結果
!> @endja
function dcdatetime_add_fd(diff, sec) result(result)
  use dc_date_types, only: dc_datetime, dc_difftime
  use dc_date_internal, only: dcdate_normalize, dcdate_nondimcheck
  use dc_scaledsec, only: operator(+)
  use dc_types, only: dp
  implicit none
  type(dc_difftime):: result
  type(dc_difftime), intent(in):: diff
  real(dp), intent(in):: sec
continue
  result % mon = diff % mon
  result % day = diff % day
  result % sec = diff % sec + sec
  result % day_seconds = diff % day_seconds
  call dcdate_normalize(result % day, result % sec, result % day_seconds, result % nondim_flag)
end function dcdatetime_add_fd
 
!> @en
!> @brief Add single precision seconds to DC_DIFFTIME
!> @param[in] diff Time difference
!> @param[in] sec Seconds to add (single precision)
!> @return result Result of addition
!> @enden
!>
!> @ja
!> @brief 単精度秒数を DC_DIFFTIME に加算
!> @param[in] diff 日時差
!> @param[in] sec 加算する秒数 (単精度)
!> @return result 加算結果
!> @endja
function dcdatetime_add_fr(diff, sec) result(result)
  use dc_date_types, only: dc_datetime, dc_difftime
  use dc_date_generic, only: operator(+)
  use dc_scaledsec, only: operator(+)
  use dc_types, only: dp
  implicit none
  type(dc_difftime):: result
  type(dc_difftime), intent(in):: diff
  real, intent(in):: sec
continue
  result = diff + real( sec, dp )
end function dcdatetime_add_fr
 
!> @en
!> @brief Add integer seconds to DC_DIFFTIME
!> @param[in] diff Time difference
!> @param[in] sec Seconds to add (integer)
!> @return result Result of addition
!> @enden
!>
!> @ja
!> @brief 整数秒数を DC_DIFFTIME に加算
!> @param[in] diff 日時差
!> @param[in] sec 加算する秒数 (整数)
!> @return result 加算結果
!> @endja
function dcdatetime_add_fi(diff, sec) result(result)
  use dc_date_types, only: dc_datetime, dc_difftime
  use dc_date_generic, only: operator(+)
  use dc_scaledsec, only: operator(+)
  use dc_types, only: dp
  implicit none
  type(dc_difftime):: result
  type(dc_difftime), intent(in):: diff
  integer, intent(in):: sec
continue
  result = diff + real( sec, dp )
end function dcdatetime_add_fi