dccaldatetochar.f90

Go to the documentation of this file.

! -*- mode: f90; coding: utf-8 -*-
!-----------------------------------------------------------------------
! Copyright (c) 2000-2026 Gtool Development Group. All rights reserved.
!-----------------------------------------------------------------------
!>
!> @author    Yasuhiro MORIKAWA
!> @copyright Copyright (C) GFD Dennou Club, 2009-2026. All rights reserved. <br/>
!>            License is BSD-2-Clause. see [COPYRIGHT](@ref COPYRIGHT) in detail
!> @en
!> @brief Convert date into a string
!> @details
!> Procedures described in this file are provided from "dc_calendar" module.
!> @enden
!>
!> @ja
!> @brief 日時の文字列への変換
!> @details
!> このファイルに記載される手続き群は dc_calendar モジュールから提供されます.
!> @endja
!>
 
!> @en
!> @brief Convert date components to string
!> @details
!> Convert year, month, day, hour, minute, second into a string
!> (conformed to gtool4 netCDF Convention
!> "5.5 Expression of date and time").
!>
!> @param[in] year Year
!> @param[in] month Month
!> @param[in] day Day
!> @param[in] hour Hour
!> @param[in] min Minute
!> @param[in] sec Second
!> @param[in] zone Time-zone (difference from UTC)
!> @return Strings that express date and time.
!>         See gtool4 netCDF Convention 5.5 Expression of date and time for details.
!> @enden
!>
!> @ja
!> @brief 日時要素を文字列に変換
!> @details
!> 年月日時分秒を文字型変数 (gtool4 netCDF 規約「5.5 日時形式」に準拠)
!> へ変換して返します.
!>
!> @param[in] year 年
!> @param[in] month 月
!> @param[in] day 日
!> @param[in] hour 時
!> @param[in] min 分
!> @param[in] sec 秒
!> @param[in] zone UTC からの時差
!> @return 日時情報を表す文字列.
!>         表示形式については gtool4 netCDF 規約 5.5 日時形式を参照のこと.
!> @endja
function dccaldatetochar1( year, month, day, hour, min, sec, zone ) &
  & result(result)
 
  use dc_types, only: string, token, dp
  use dc_string, only: tochar, cprintf, stoa, roundnum
  use dc_message, only: messagenotify
  implicit none
  character(STRING):: result
  integer, intent(in):: year
  integer, intent(in):: month
  integer, intent(in):: day
  integer, intent(in):: hour
  integer, intent(in):: min
  real(dp), intent(in):: sec
  character(*), intent(in), optional:: zone
  integer:: csec_len
  character(STRING):: csec
  character(TOKEN):: zonew
continue
 
  if ( present(zone) ) then
    zonew = zone
  else
    zonew = ''
  end if
 
  csec = tochar(sec)
  csec = roundnum( csec )
  if ( trim(csec) == '-0.' ) csec = '0.'
  do while ( index('123456789.', csec(len_trim(csec):len_trim(csec)) ) == 0 )
    if ( len_trim(csec) < 2 ) exit
    csec = csec(1:len_trim(csec)-1)
  end do
  if (int(sec) > -1 .and. int(sec) < 10) then
    if (len_trim(csec) >= len(csec)) then
      csec = '0' // trim(csec(1:len(csec) - 1))
    else
      csec = '0' // trim(csec)
    end if
  end if
  csec_len = len(trim(adjustl(csec)))
  if (csec(csec_len:csec_len) == '.') csec = csec(1:csec_len-1)
 
  result = cprintf('%04d-%02d-%02dT%02d:%02d:%c%c', &
    & i=(/year, month, day, hour, min/), &
    & c1=trim(csec), c2=trim(zonew))
 
end function dccaldatetochar1