dccaldateeval.f90

Go to the documentation of this file.

! -*- mode: f90; coding: utf-8 -*-
!-----------------------------------------------------------------------
! Copyright (c) 2000-2026 Gtool Development Group. All rights reserved.
!-----------------------------------------------------------------------
!>
!> @author    Yasuhiro MORIKAWA
!> @copyright Copyright (C) GFD Dennou Club, 2009-2026. All rights reserved. <br/>
!>            License is BSD-2-Clause. see [COPYRIGHT](@ref COPYRIGHT) in detail
!> @en
!> @brief Evaluate date
!> @details
!> Procedures described in this file are provided from "dc_calendar" module.
!> @enden
!>
!> @ja
!> @brief 日時の算出
!> @details
!> このファイルに記載される手続き群は dc_calendar モジュールから提供されます.
!> @endja
!>
 
!> @en
!> @brief Evaluate and set date with elapsed seconds
!> @details
!> Evaluate and set date.
!>
!> If an optional argument `date` is omitted,
!> the date setting is stored to a "dc_calendar_types#DC_CAL_DATE"
!> variable that is saved in the "dc_calendar".
!> When `date` is omitted in subsequent procedures, the internal date
!> is used.
!> If `date` is not omitted, the settings is stored to the `date`.
!> In order to use the date setting, use the "dc_calendar_types#DC_CAL_DATE"
!> variable to subsequent procedures.
!>
!> If an optional argument `cal` is omitted,
!> information of calendar that is stored in the "dc_calendar"
!> is used for conversion of elapsed seconds `elapse_sec` into
!> year-month-day etc.
!> If `cal` is not omitted, information of the variable is used.
!>
!> @param[in] year Year of origin
!> @param[in] month Month of origin
!> @param[in] day Day of origin
!> @param[in] hour Hour of origin
!> @param[in] min Minute of origin
!> @param[in] sec Second of origin
!> @param[in] elapse_sec Elapsed seconds from `year` -- `sec`
!> @param[in] cal An object that stores information of calendar
!> @param[out] date An object that stores information of date and time after elapsed time
!> @param[out] err Exception handling flag
!> @enden
!>
!> @ja
!> @brief 経過秒数から日時を算出・設定
!> @details
!> 日時の算出と設定を行います.
!>
!> 省略可能引数 `date` が省略された場合には, dc_calendar 内部で
!> 保持される "dc_calendar_types#DC_CAL_DATE" 型の変数に日時が
!> 設定されます. その後の手続きで `date` を省略した場合には
!> この日時が使用されます.
!> `date` が省略されない場合にはその変数に日時が設定されます.
!> その日時を使用する場合, 手続きにその "dc_calendar_types#DC_CAL_DATE" 型の変数
!> を与えてください.
!>
!> 省略可能引数 `cal` が省略された場合には, 経過秒数 `elapse_sec`
!> の年月日時分への変換に dc_calendar 内部で保持される暦が用いられます.
!> `cal` が省略されない場合にはその変数に設定された暦が用いられます.
!>
!> @param[in] year 起点の年
!> @param[in] month 起点の月
!> @param[in] day 起点の日
!> @param[in] hour 起点の時
!> @param[in] min 起点の分
!> @param[in] sec 起点の秒
!> @param[in] elapse_sec `year` 〜 `sec` からの経過秒数
!> @param[in] cal 暦情報を収めたオブジェクト
!> @param[out] date 経過時間後の日時情報を収めたオブジェクト
!> @param[out] err 例外処理用フラグ.
!>                 デフォルトでは, この手続き内でエラーが生じた場合,
!>                 プログラムは強制終了します.
!>                 引数 `err` が与えられる場合, プログラムは強制終了せず,
!>                 代わりに `err` に .true. が代入されます.
!> @endja
subroutine dccaldateevalymdhms1( &
  & year, month, day, hour, min, sec, elapse_sec, cal, date, err )
 
  use dc_calendar_types, only: dc_cal, dc_cal_date
  use dc_calendar_internal, only: default_cal, default_cal_set, default_date, &
    & dccaldate_normalize
  use dc_calendar_generic, only: dccaldatecreate, dccaldatetochar, dccaltochar
  use dc_message, only: messagenotify
  use dc_trace, only: beginsub, endsub
  use dc_error, only: storeerror, dc_noerr, dc_enotinit, &
    & dc_einconsistcaldate, dc_ebaddate
  use dc_types, only: string, dp
  implicit none
  integer, intent(in):: year
  integer, intent(in):: month
  integer, intent(in):: day
  integer, intent(in):: hour
  integer, intent(in):: min
  real(DP), intent(in):: sec
  real(DP), intent(in):: elapse_sec
  type(dc_cal), intent(in), optional, target:: cal
  type(dc_cal_date), intent(out), optional, target:: date
  logical, intent(out), optional:: err
 
  ! 作業変数
  ! Work variables
  !
  integer:: wyear, wmonth, wday, whour, wmin
  real(DP):: wsec
  type(dc_cal_date), pointer:: datep =>null()
  type(dc_cal), pointer:: calp =>null()
  character(STRING):: e_date_str, e_cal_str
  integer:: stat
  character(STRING):: cause_c
  character(*), parameter:: subname = 'DCCalDateEvalYMDHMS1'
continue
  call beginsub( subname )
  stat = dc_noerr
  cause_c = ''
 
  ! オブジェクトのポインタ割付
  ! Associate pointer of an object
  !
  if ( present( date ) ) then
    datep => date
  else
    datep => default_date
  end if
 
  if ( present( cal ) ) then
    calp => cal
  else
    calp => default_cal
    if ( .not. calp % initialized ) call default_cal_set
  end if
 
  ! 初期設定のチェック
  ! Check initialization
  !
!!$  if ( .not. datep % initialized ) then
!!$    stat = DC_ENOTINIT
!!$    cause_c = 'DC_CAL_DATE'
!!$    goto 999
!!$  end if
 
  if ( .not. calp % initialized ) then
    stat = dc_enotinit
    cause_c = 'DC_CAL'
    goto 999
  end if
 
  ! 各要素への値の参照
  ! Refer elements
  !
  wyear  = year
  wmonth = month
  wday   = day
  whour  = hour
  wmin   = min
  wsec   = sec
 
  ! 経過時間(秒)の追加
  ! Add elapsed time (seconds)
  !
!!$  if ( elapse_sec < 0.0_DP ) then
!!$    stat = DC_ENEGATIVE
!!$    cause_c = 'elapse_sec'
!!$    goto 999
!!$  end if
 
  wsec = wsec + elapse_sec
 
  ! 日時の正規化
  ! Normalize date and time
  !
  stat = dccaldate_normalize( wyear, wmonth, wday, whour, wmin, wsec, & ! (inout)
    &                         calp )                                    ! (in)
  if ( stat == dc_einconsistcaldate ) then
    e_cal_str = dccaltochar( calp )
    e_date_str = dccaldatetochar( wyear, wmonth, wday, whour, wmin, wsec, zone = "" )
    call messagenotify('W', subname, 'cal=<%c> and date=<%c> are inconsistency', &
      & c1 = trim(e_cal_str), c2 = trim(e_date_str) )
    goto 999
  end if
 
  ! オブジェクトの作成
  ! Create an object
  !
  call dccaldatecreate( &
    & wyear, wmonth, wday, whour, wmin, wsec, & ! (in)
    & datep, zone = "", err = err )             ! (out) optional
  if ( present(err) ) then
    if ( err ) then
      stat = dc_ebaddate
      goto 999
    end if
  end if
 
  ! 終了処理, 例外処理
  ! Termination and Exception handling
  !
999 continue
  nullify( calp, datep )
  call storeerror( stat, subname, err, cause_c )
  call endsub( subname )
end subroutine dccaldateevalymdhms1
 
!-----------------------------------------------------------
 
!> @en
!> @brief Evaluate and set date with elapsed time and units
!> @details
!> Evaluate and set date.
!>
!> If an optional argument `date` is omitted,
!> the date setting is stored to a "dc_calendar_types#DC_CAL_DATE"
!> variable that is saved in the "dc_calendar".
!> When `date` is omitted in subsequent procedures, the internal date
!> is used.
!> If `date` is not omitted, the settings is stored to the `date`.
!> In order to use the date setting, use the "dc_calendar_types#DC_CAL_DATE"
!> variable to subsequent procedures.
!>
!> If an optional argument `cal` is omitted,
!> information of calendar that is stored in the "dc_calendar"
!> is used for conversion of elapsed time `elapse_time` into
!> year-month-day etc.
!> If `cal` is not omitted, information of the variable is used.
!>
!> @param[in] year Year of origin
!> @param[in] month Month of origin
!> @param[in] day Day of origin
!> @param[in] hour Hour of origin
!> @param[in] min Minute of origin
!> @param[in] sec Second of origin
!> @param[in] elapse_time Elapsed time from `year` -- `sec`. Unit is specified as `units`.
!> @param[in] units Unit of `elapse_time`
!> @param[in] cal An object that stores information of calendar
!> @param[out] date An object that stores information of date and time after elapsed time
!> @param[out] err Exception handling flag
!> @enden
!>
!> @ja
!> @brief 経過時間と単位から日時を算出・設定
!> @details
!> 日時の算出と設定を行います.
!>
!> 省略可能引数 `date` が省略された場合には, dc_calendar 内部で
!> 保持される "dc_calendar_types#DC_CAL_DATE" 型の変数に日時が
!> 設定されます. その後の手続きで `date` を省略した場合には
!> この日時が使用されます.
!> `date` が省略されない場合にはその変数に日時が設定されます.
!> その日時を使用する場合, 手続きにその "dc_calendar_types#DC_CAL_DATE" 型の変数
!> を与えてください.
!>
!> 省略可能引数 `cal` が省略された場合には, 経過時間 `elapse_time`
!> の年月日時分への変換に dc_calendar 内部で保持される暦が用いられます.
!> `cal` が省略されない場合にはその変数に設定された暦が用いられます.
!>
!> @param[in] year 起点の年
!> @param[in] month 起点の月
!> @param[in] day 起点の日
!> @param[in] hour 起点の時
!> @param[in] min 起点の分
!> @param[in] sec 起点の秒
!> @param[in] elapse_time `year` 〜 `sec` からの経過時間. 単位は `units` で指定する.
!> @param[in] units `elapse_time` の単位
!> @param[in] cal 暦情報を収めたオブジェクト
!> @param[out] date 経過時間後の日時情報を収めたオブジェクト
!> @param[out] err 例外処理用フラグ
!> @endja
subroutine dccaldateevalymdhms2( &
  & year, month, day, hour, min, sec, elapse_time, units, cal, date, err )
 
  use dc_calendar_types, only: dc_cal, dc_cal_date, &
    & unit_symbol_day, unit_symbol_hour, unit_symbol_min, unit_symbol_sec
  use dc_calendar_internal, only: default_cal, default_cal_set, default_date, &
    & dccaldate_normalize, dccaldate_str2usym
  use dc_calendar_generic, only: dccaldatecreate, dccaldatetochar, dccaltochar
  use dc_message, only: messagenotify
  use dc_trace, only: beginsub, endsub
  use dc_error, only: storeerror, dc_noerr, dc_enotinit, &
    & dc_einconsistcaldate, dc_ebaddate, dc_ebadunit
  use dc_types, only: string, dp
  implicit none
  integer, intent(in):: year
  integer, intent(in):: month
  integer, intent(in):: day
  integer, intent(in):: hour
  integer, intent(in):: min
  real(DP), intent(in):: sec
  real(DP), intent(in):: elapse_time
  character(*), intent(in):: units
  type(dc_cal), intent(in), optional, target:: cal
  type(dc_cal_date), intent(out), optional, target:: date
  logical, intent(out), optional:: err
 
  ! 作業変数
  ! Work variables
  !
  integer:: wyear, wmonth, wday, whour, wmin
  real(DP):: wsec
  type(dc_cal_date), pointer:: datep =>null()
  type(dc_cal), pointer:: calp =>null()
  character(STRING):: e_date_str, e_cal_str
  integer:: tusym
  integer:: stat
  character(STRING):: cause_c
  character(*), parameter:: subname = 'DCCalDateEvalYMDHMS2'
continue
  call beginsub( subname )
  stat = dc_noerr
  cause_c = ''
 
  ! オブジェクトのポインタ割付
  ! Associate pointer of an object
  !
  if ( present( date ) ) then
    datep => date
  else
    datep => default_date
  end if
 
  if ( present( cal ) ) then
    calp => cal
  else
    calp => default_cal
    if ( .not. calp % initialized ) call default_cal_set
  end if
 
  ! 初期設定のチェック
  ! Check initialization
  !
!!$  if ( .not. datep % initialized ) then
!!$    stat = DC_ENOTINIT
!!$    cause_c = 'DC_CAL_DATE'
!!$    goto 999
!!$  end if
 
  if ( .not. calp % initialized ) then
    stat = dc_enotinit
    cause_c = 'DC_CAL'
    goto 999
  end if
 
  ! 各要素への値の参照
  ! Refer elements
  !
  wyear  = year
  wmonth = month
  wday   = day
  whour  = hour
  wmin   = min
  wsec   = sec
 
  ! 経過時間(秒)の追加
  ! Add elapsed time (seconds)
  !
!!$  if ( elapse_time < 0.0_DP ) then
!!$    stat = DC_ENEGATIVE
!!$    cause_c = 'elapse_time'
!!$    goto 999
!!$  end if
 
  tusym = dccaldate_str2usym(units)
  select case(tusym)
  case(unit_symbol_day)
    wsec = wsec + elapse_time * calp % hour_in_day &
      &                       * calp % min_in_hour &
      &                       * calp % sec_in_min
  case(unit_symbol_hour)
    wsec = wsec + elapse_time * calp % min_in_hour &
      &                       * calp % sec_in_min
  case(unit_symbol_min)
    wsec = wsec + elapse_time * calp % sec_in_min
  case(unit_symbol_sec)
    wsec = wsec + elapse_time
  case default
    cause_c = units
    call messagenotify('W', subname, 'units=<%c> is invalid. (ONLY day,hrs,min,sec are valid)', &
      & c1 = trim(units) )
    stat = dc_ebadunit
    goto 999
  end select
 
  ! 日時の正規化
  ! Normalize date and time
  !
  stat = dccaldate_normalize( wyear, wmonth, wday, whour, wmin, wsec, & ! (inout)
    &                         calp )                                    ! (in)
  if ( stat == dc_einconsistcaldate ) then
    e_cal_str = dccaltochar( calp )
    e_date_str = dccaldatetochar( wyear, wmonth, wday, whour, wmin, wsec, zone = "" )
    call messagenotify('W', subname, 'cal=<%c> and date=<%c> are inconsistency', &
      & c1 = trim(e_cal_str), c2 = trim(e_date_str) )
    goto 999
  end if
 
  ! オブジェクトの作成
  ! Create an object
  !
  call dccaldatecreate( &
    & wyear, wmonth, wday, whour, wmin, wsec, & ! (in)
    & datep, zone = "", err = err )             ! (out) optional
  if ( present(err) ) then
    if ( err ) then
      stat = dc_ebaddate
      goto 999
    end if
  end if
 
  ! 終了処理, 例外処理
  ! Termination and Exception handling
  !
999 continue
  nullify( calp, datep )
  call storeerror( stat, subname, err, cause_c )
  call endsub( subname )
end subroutine dccaldateevalymdhms2
 
!-----------------------------------------------------------
 
!> @en
!> @brief Evaluate and set date from initial date object with elapsed seconds
!> @details
!> Evaluate and set date.
!>
!> If an optional argument `date` is omitted,
!> the date setting is stored to a "dc_calendar_types#DC_CAL_DATE"
!> variable that is saved in the "dc_calendar".
!> When `date` is omitted in subsequent procedures, the internal date
!> is used.
!> If `date` is not omitted, the settings is stored to the `date`.
!> In order to use the date setting, use the "dc_calendar_types#DC_CAL_DATE"
!> variable to subsequent procedures.
!>
!> If an optional argument `cal` is omitted,
!> information of calendar that is stored in the "dc_calendar"
!> is used for conversion of elapsed seconds `elapse_sec` into
!> year-month-day etc.
!> If `cal` is not omitted, information of the variable is used.
!>
!> @param[in] init_date An object that stores information of date of origin
!> @param[in] elapse_sec Elapsed seconds from `init_date`
!> @param[in] cal An object that stores information of calendar
!> @param[out] date An object that stores information of date and time after elapsed time
!> @param[out] err Exception handling flag
!> @enden
!>
!> @ja
!> @brief 初期日時オブジェクトと経過秒数から日時を算出・設定
!> @details
!> 日時の算出と設定を行います.
!>
!> 省略可能引数 `date` が省略された場合には, dc_calendar 内部で
!> 保持される "dc_calendar_types#DC_CAL_DATE" 型の変数に日時が
!> 設定されます. その後の手続きで `date` を省略した場合には
!> この日時が使用されます.
!> `date` が省略されない場合にはその変数に日時が設定されます.
!> その日時を使用する場合, 手続きにその "dc_calendar_types#DC_CAL_DATE" 型の変数
!> を与えてください.
!>
!> 省略可能引数 `cal` が省略された場合には, 経過秒数 `elapse_sec`
!> の年月日時分への変換に dc_calendar 内部で保持される暦が用いられます.
!> `cal` が省略されない場合にはその変数に設定された暦が用いられます.
!>
!> @param[in] init_date 起点となる日時情報を収めたオブジェクト
!> @param[in] elapse_sec `init_date` からの経過秒数
!> @param[in] cal 暦情報を収めたオブジェクト
!> @param[out] date 経過時間後の日時情報を収めたオブジェクト
!> @param[out] err 例外処理用フラグ
!> @endja
subroutine dccaldateevalid1( init_date, elapse_sec, cal, date, err )
 
  use dc_calendar_types, only: dc_cal, dc_cal_date
  use dc_calendar_internal, only: default_cal, default_cal_set, default_date, &
    & dccaldate_normalize
  use dc_calendar_generic, only: dccaldatecreate, dccaldatetochar, dccaltochar
  use dc_message, only: messagenotify
  use dc_trace, only: beginsub, endsub
  use dc_error, only: storeerror, dc_noerr, dc_enotinit, &
    & dc_einconsistcaldate, dc_ebaddate
  use dc_types, only: string, dp, token
  implicit none
  type(dc_cal_date), intent(in):: init_date
  real(DP), intent(in):: elapse_sec
  type(dc_cal), intent(in), optional, target:: cal
  type(dc_cal_date), intent(out), optional, target:: date
  logical, intent(out), optional:: err
 
  ! 作業変数
  ! Work variables
  !
  integer:: wyear, wmonth, wday, whour, wmin
  real(DP):: wsec
  character(TOKEN):: wzone
  type(dc_cal_date), pointer:: datep =>null()
  type(dc_cal), pointer:: calp =>null()
  character(STRING):: e_date_str, e_cal_str
  integer:: stat
  character(STRING):: cause_c
  character(*), parameter:: subname = 'DCCalDateEvalID1'
continue
  call beginsub( subname )
  stat = dc_noerr
  cause_c = ''
 
  ! オブジェクトのポインタ割付
  ! Associate pointer of an object
  !
  if ( present( date ) ) then
    datep => date
  else
    datep => default_date
  end if
 
  if ( present( cal ) ) then
    calp => cal
  else
    calp => default_cal
    if ( .not. calp % initialized ) call default_cal_set
  end if
 
  ! 初期設定のチェック
  ! Check initialization
  !
!!$  if ( .not. datep % initialized ) then
!!$    stat = DC_ENOTINIT
!!$    cause_c = 'DC_CAL_DATE'
!!$    goto 999
!!$  end if
 
  if ( .not. calp % initialized ) then
    stat = dc_enotinit
    cause_c = 'DC_CAL'
    goto 999
  end if
 
  ! 各要素への値の参照
  ! Refer elements
  !
  wyear  = init_date % year
  wmonth = init_date % month
  wday   = init_date % day
  whour  = init_date % hour
  wmin   = init_date % min
  wsec   = init_date % sec
  wzone  = init_date % zone
 
  ! 経過時間(秒)の追加
  ! Add elapsed time (seconds)
  !
!!$  if ( elapse_sec < 0.0_DP ) then
!!$    stat = DC_ENEGATIVE
!!$    cause_c = 'elapse_sec'
!!$    goto 999
!!$  end if
 
  wsec = wsec + elapse_sec
 
  ! 日時の正規化
  ! Normalize date and time
  !
  stat = dccaldate_normalize( wyear, wmonth, wday, whour, wmin, wsec, & ! (inout)
    &                         calp )                                    ! (in)
  if ( stat == dc_einconsistcaldate ) then
    e_cal_str = dccaltochar( calp )
    e_date_str = dccaldatetochar( wyear, wmonth, wday, whour, wmin, wsec, zone = "" )
    call messagenotify('W', subname, 'cal=<%c> and date=<%c> are inconsistency', &
      & c1 = trim(e_cal_str), c2 = trim(e_date_str) )
    goto 999
  end if
 
  ! オブジェクトの作成
  ! Create an object
  !
  call dccaldatecreate( &
    & wyear, wmonth, wday, whour, wmin, wsec, & ! (in)
    & datep, zone = wzone, err = err )          ! (out) optional
  if ( present(err) ) then
    if ( err ) then
      stat = dc_ebaddate
      goto 999
    end if
  end if
 
  ! 終了処理, 例外処理
  ! Termination and Exception handling
  !
999 continue
  nullify( calp, datep )
  call storeerror( stat, subname, err, cause_c )
  call endsub( subname )
end subroutine dccaldateevalid1
 
!-----------------------------------------------------------
 
!> @en
!> @brief Evaluate and set date from initial date object with elapsed time and units
!> @details
!> Evaluate and set date.
!>
!> If an optional argument `date` is omitted,
!> the date setting is stored to a "dc_calendar_types#DC_CAL_DATE"
!> variable that is saved in the "dc_calendar".
!> When `date` is omitted in subsequent procedures, the internal date
!> is used.
!> If `date` is not omitted, the settings is stored to the `date`.
!> In order to use the date setting, use the "dc_calendar_types#DC_CAL_DATE"
!> variable to subsequent procedures.
!>
!> If an optional argument `cal` is omitted,
!> information of calendar that is stored in the "dc_calendar"
!> is used for conversion of elapsed time `elapse_time` into
!> year-month-day etc.
!> If `cal` is not omitted, information of the variable is used.
!>
!> @param[in] init_date An object that stores information of date of origin
!> @param[in] elapse_time Elapsed time from `init_date`. Unit is specified as `units`.
!> @param[in] units Unit of `elapse_time`
!> @param[in] cal An object that stores information of calendar
!> @param[out] date An object that stores information of date and time after elapsed time
!> @param[out] err Exception handling flag
!> @enden
!>
!> @ja
!> @brief 初期日時オブジェクトと経過時間・単位から日時を算出・設定
!> @details
!> 日時の算出と設定を行います.
!>
!> 省略可能引数 `date` が省略された場合には, dc_calendar 内部で
!> 保持される "dc_calendar_types#DC_CAL_DATE" 型の変数に日時が
!> 設定されます. その後の手続きで `date` を省略した場合には
!> この日時が使用されます.
!> `date` が省略されない場合にはその変数に日時が設定されます.
!> その日時を使用する場合, 手続きにその "dc_calendar_types#DC_CAL_DATE" 型の変数
!> を与えてください.
!>
!> 省略可能引数 `cal` が省略された場合には, 経過時間 `elapse_time`
!> の年月日時分への変換に dc_calendar 内部で保持される暦が用いられます.
!> `cal` が省略されない場合にはその変数に設定された暦が用いられます.
!>
!> @param[in] init_date 起点となる日時情報を収めたオブジェクト
!> @param[in] elapse_time `init_date` からの経過時間. 単位は `units` で指定する.
!> @param[in] units `elapse_time` の単位
!> @param[in] cal 暦情報を収めたオブジェクト
!> @param[out] date 経過時間後の日時情報を収めたオブジェクト
!> @param[out] err 例外処理用フラグ
!> @endja
subroutine dccaldateevalid2( init_date, elapse_time, units, cal, date, err )
  use dc_calendar_types, only: dc_cal, dc_cal_date, &
    & unit_symbol_day, unit_symbol_hour, unit_symbol_min, unit_symbol_sec
  use dc_calendar_internal, only: default_cal, default_cal_set, default_date, &
    & dccaldate_normalize, dccaldate_str2usym
  use dc_calendar_generic, only: dccaldatecreate, dccaldatetochar, dccaltochar
  use dc_message, only: messagenotify
  use dc_trace, only: beginsub, endsub
  use dc_error, only: storeerror, dc_noerr, dc_enotinit, &
    & dc_einconsistcaldate, dc_ebaddate, dc_ebadunit
  use dc_types, only: string, dp, token
  implicit none
  type(dc_cal_date), intent(in):: init_date
  real(DP), intent(in):: elapse_time
  character(*), intent(in):: units
  type(dc_cal), intent(in), optional, target:: cal
  type(dc_cal_date), intent(out), optional, target:: date
  logical, intent(out), optional:: err
 
  ! 作業変数
  ! Work variables
  !
  integer:: wyear, wmonth, wday, whour, wmin
  real(DP):: wsec
  character(TOKEN):: wzone
  type(dc_cal_date), pointer:: datep =>null()
  type(dc_cal), pointer:: calp =>null()
  character(STRING):: e_date_str, e_cal_str
  integer:: tusym
  integer:: stat
  character(STRING):: cause_c
  character(*), parameter:: subname = 'DCCalDateEvalID2'
continue
  call beginsub( subname )
  stat = dc_noerr
  cause_c = ''
 
  ! オブジェクトのポインタ割付
  ! Associate pointer of an object
  !
  if ( present( date ) ) then
    datep => date
  else
    datep => default_date
  end if
 
  if ( present( cal ) ) then
    calp => cal
  else
    calp => default_cal
    if ( .not. calp % initialized ) call default_cal_set
  end if
 
  ! 初期設定のチェック
  ! Check initialization
  !
!!$  if ( .not. datep % initialized ) then
!!$    stat = DC_ENOTINIT
!!$    cause_c = 'DC_CAL_DATE'
!!$    goto 999
!!$  end if
 
  if ( .not. calp % initialized ) then
    stat = dc_enotinit
    cause_c = 'DC_CAL'
    goto 999
  end if
 
  ! 各要素への値の参照
  ! Refer elements
  !
  wyear  = init_date % year
  wmonth = init_date % month
  wday   = init_date % day
  whour  = init_date % hour
  wmin   = init_date % min
  wsec   = init_date % sec
  wzone  = init_date % zone
 
  ! 経過時間(秒)の追加
  ! Add elapsed time (seconds)
  !
!!$  if ( elapse_time < 0.0_DP ) then
!!$    stat = DC_ENEGATIVE
!!$    cause_c = 'elapse_time'
!!$    goto 999
!!$  end if
 
  tusym = dccaldate_str2usym(units)
  select case(tusym)
  case(unit_symbol_day)
    wsec = wsec + elapse_time * calp % hour_in_day &
      &                       * calp % min_in_hour &
      &                       * calp % sec_in_min
  case(unit_symbol_hour)
    wsec = wsec + elapse_time * calp % min_in_hour &
      &                       * calp % sec_in_min
  case(unit_symbol_min)
    wsec = wsec + elapse_time * calp % sec_in_min
  case(unit_symbol_sec)
    wsec = wsec + elapse_time
  case default
    cause_c = units
    call messagenotify('W', subname, 'units=<%c> is invalid. (ONLY day,hrs,min,sec are valid)', &
      & c1 = trim(units) )
    stat = dc_ebadunit
    goto 999
  end select
 
  ! 日時の正規化
  ! Normalize date and time
  !
  stat = dccaldate_normalize( wyear, wmonth, wday, whour, wmin, wsec, & ! (inout)
    &                         calp )                                    ! (in)
  if ( stat == dc_einconsistcaldate ) then
    e_cal_str = dccaltochar( calp )
    e_date_str = dccaldatetochar( wyear, wmonth, wday, whour, wmin, wsec, zone = "" )
    call messagenotify('W', subname, 'cal=<%c> and date=<%c> are inconsistency', &
      & c1 = trim(e_cal_str), c2 = trim(e_date_str) )
    goto 999
  end if
 
  ! オブジェクトの作成
  ! Create an object
  !
  call dccaldatecreate( &
    & wyear, wmonth, wday, whour, wmin, wsec, & ! (in)
    & datep, zone = wzone, err = err )          ! (out) optional
  if ( present(err) ) then
    if ( err ) then
      stat = dc_ebaddate
      goto 999
    end if
  end if
 
  ! 終了処理, 例外処理
  ! Termination and Exception handling
  !
999 continue
  nullify( calp, datep )
  call storeerror( stat, subname, err, cause_c )
  call endsub( subname )
end subroutine dccaldateevalid2
 
!-----------------------------------------------------------
 
!> @en
!> @brief Evaluate date and return as individual variables with elapsed seconds
!> @details
!> Evaluate and set date.
!>
!> If an optional argument `cal` is omitted,
!> information of calendar that is stored in the "dc_calendar"
!> is used for conversion of elapsed seconds `elapse_sec` into
!> year-month-day etc.
!> If `cal` is not omitted, information of the variable is used.
!>
!> @param[in] year1 Year of origin
!> @param[in] month1 Month of origin
!> @param[in] day1 Day of origin
!> @param[in] hour1 Hour of origin
!> @param[in] min1 Minute of origin
!> @param[in] sec1 Second of origin
!> @param[in] elapse_sec Elapsed seconds from `year1` -- `sec1`
!> @param[out] year2 Year after elapsed time
!> @param[out] month2 Month after elapsed time
!> @param[out] day2 Day after elapsed time
!> @param[out] hour2 Hour after elapsed time
!> @param[out] min2 Minute after elapsed time
!> @param[out] sec2 Second after elapsed time
!> @param[in] cal An object that stores information of calendar
!> @param[out] err Exception handling flag
!> @enden
!>
!> @ja
!> @brief 経過秒数から日時を算出し個別変数で返す
!> @details
!> 日時の算出と設定を行います.
!>
!> 省略可能引数 `cal` が省略された場合には, 経過秒数 `elapse_sec`
!> の年月日時分への変換に dc_calendar 内部で保持される暦が用いられます.
!> `cal` が省略されない場合にはその変数に設定された暦が用いられます.
!>
!> @param[in] year1 起点の年
!> @param[in] month1 起点の月
!> @param[in] day1 起点の日
!> @param[in] hour1 起点の時
!> @param[in] min1 起点の分
!> @param[in] sec1 起点の秒
!> @param[in] elapse_sec `year1` 〜 `sec1` からの経過秒数
!> @param[out] year2 経過時間後の年
!> @param[out] month2 経過時間後の月
!> @param[out] day2 経過時間後の日
!> @param[out] hour2 経過時間後の時
!> @param[out] min2 経過時間後の分
!> @param[out] sec2 経過時間後の秒
!> @param[in] cal 暦情報を収めたオブジェクト
!> @param[out] err 例外処理用フラグ
!> @endja
subroutine dccaldateevalym2ym1( &
  & year1, month1, day1, hour1, min1, sec1, &
  & elapse_sec, &
  & year2, month2, day2, hour2, min2, sec2, &
  & cal, err )
  use dc_calendar_types, only: dc_cal, dc_cal_date
  use dc_calendar_internal, only: default_cal, default_cal_set, &
    & dccaldate_normalize
  use dc_calendar_generic, only: dccaldatecreate, dccaldatetochar, dccaltochar
  use dc_message, only: messagenotify
  use dc_trace, only: beginsub, endsub
  use dc_error, only: storeerror, dc_noerr, dc_enotinit, &
    & dc_einconsistcaldate
  use dc_types, only: string, dp
  implicit none
  integer, intent(in):: year1
  integer, intent(in):: month1
  integer, intent(in):: day1
  integer, intent(in):: hour1
  integer, intent(in):: min1
  real(DP), intent(in):: sec1
  real(DP), intent(in):: elapse_sec
  integer, intent(out):: year2
  integer, intent(out):: month2
  integer, intent(out):: day2
  integer, intent(out):: hour2
  integer, intent(out):: min2
  real(DP), intent(out):: sec2
  type(dc_cal), intent(in), optional, target:: cal
  logical, intent(out), optional:: err
 
  ! 作業変数
  ! Work variables
  !
  type(dc_cal), pointer:: calp =>null()
  character(STRING):: e_date_str, e_cal_str
  integer:: stat
  character(STRING):: cause_c
  character(*), parameter:: subname = 'DCCalDateEvalYM2YM1'
continue
  call beginsub( subname )
  stat = dc_noerr
  cause_c = ''
 
  ! オブジェクトのポインタ割付
  ! Associate pointer of an object
  !
  if ( present( cal ) ) then
    calp => cal
  else
    calp => default_cal
    if ( .not. calp % initialized ) call default_cal_set
  end if
 
  ! 初期設定のチェック
  ! Check initialization
  !
!!$  if ( .not. datep % initialized ) then
!!$    stat = DC_ENOTINIT
!!$    cause_c = 'DC_CAL_DATE'
!!$    goto 999
!!$  end if
 
  if ( .not. calp % initialized ) then
    stat = dc_enotinit
    cause_c = 'DC_CAL'
    goto 999
  end if
 
  ! 各要素への値の参照
  ! Refer elements
  !
  year2  = year1
  month2 = month1
  day2   = day1
  hour2  = hour1
  min2   = min1
  sec2   = sec1
 
  ! 経過時間(秒)の追加
  ! Add elapsed time (seconds)
  !
!!$  if ( elapse_sec < 0.0_DP ) then
!!$    stat = DC_ENEGATIVE
!!$    cause_c = 'elapse_sec'
!!$    goto 999
!!$  end if
 
  sec2 = sec2 + elapse_sec
 
  ! 日時の正規化
  ! Normalize date and time
  !
  stat = dccaldate_normalize( year2, month2, day2, hour2, min2, sec2, & ! (inout)
    &                         calp )                                    ! (in)
  if ( stat == dc_einconsistcaldate ) then
    e_cal_str = dccaltochar( calp )
    e_date_str = dccaldatetochar( year2, month2, day2, hour2, min2, sec2, zone = "" )
    call messagenotify('W', subname, 'cal=<%c> and date=<%c> are inconsistency', &
      & c1 = trim(e_cal_str), c2 = trim(e_date_str) )
    goto 999
  end if
 
  ! 終了処理, 例外処理
  ! Termination and Exception handling
  !
999 continue
  nullify( calp )
  call storeerror( stat, subname, err, cause_c )
  call endsub( subname )
end subroutine dccaldateevalym2ym1
 
!-----------------------------------------------------------
 
!> @en
!> @brief Evaluate date and return as individual variables with elapsed time and units
!> @details
!> Evaluate and set date.
!>
!> If an optional argument `cal` is omitted,
!> information of calendar that is stored in the "dc_calendar"
!> is used for conversion of elapsed time `elapse_time` into
!> year-month-day etc.
!> If `cal` is not omitted, information of the variable is used.
!>
!> @param[in] year1 Year of origin
!> @param[in] month1 Month of origin
!> @param[in] day1 Day of origin
!> @param[in] hour1 Hour of origin
!> @param[in] min1 Minute of origin
!> @param[in] sec1 Second of origin
!> @param[in] elapse_time Elapsed time from `year1` -- `sec1`. Unit is specified as `units`.
!> @param[in] units Unit of `elapse_time`
!> @param[out] year2 Year after elapsed time
!> @param[out] month2 Month after elapsed time
!> @param[out] day2 Day after elapsed time
!> @param[out] hour2 Hour after elapsed time
!> @param[out] min2 Minute after elapsed time
!> @param[out] sec2 Second after elapsed time
!> @param[in] cal An object that stores information of calendar
!> @param[out] err Exception handling flag
!> @enden
!>
!> @ja
!> @brief 経過時間と単位から日時を算出し個別変数で返す
!> @details
!> 日時の算出と設定を行います.
!>
!> 省略可能引数 `cal` が省略された場合には, 経過時間 `elapse_time`
!> の年月日時分への変換に dc_calendar 内部で保持される暦が用いられます.
!> `cal` が省略されない場合にはその変数に設定された暦が用いられます.
!>
!> @param[in] year1 起点の年
!> @param[in] month1 起点の月
!> @param[in] day1 起点の日
!> @param[in] hour1 起点の時
!> @param[in] min1 起点の分
!> @param[in] sec1 起点の秒
!> @param[in] elapse_time `year1` 〜 `sec1` からの経過時間. 単位は `units` で指定する.
!> @param[in] units `elapse_time` の単位
!> @param[out] year2 経過時間後の年
!> @param[out] month2 経過時間後の月
!> @param[out] day2 経過時間後の日
!> @param[out] hour2 経過時間後の時
!> @param[out] min2 経過時間後の分
!> @param[out] sec2 経過時間後の秒
!> @param[in] cal 暦情報を収めたオブジェクト
!> @param[out] err 例外処理用フラグ
!> @endja
subroutine dccaldateevalym2ym2( &
  & year1, month1, day1, hour1, min1, sec1, &
  & elapse_time, units, &
  & year2, month2, day2, hour2, min2, sec2, &
  & cal, err )
  use dc_calendar_types, only: dc_cal, dc_cal_date, &
    & unit_symbol_day, unit_symbol_hour, unit_symbol_min, unit_symbol_sec
  use dc_calendar_internal, only: default_cal, default_cal_set, &
    & dccaldate_normalize, dccaldate_str2usym
  use dc_calendar_generic, only: dccaldatecreate, dccaldatetochar, dccaltochar
  use dc_message, only: messagenotify
  use dc_trace, only: beginsub, endsub
  use dc_error, only: storeerror, dc_noerr, dc_enotinit, &
    & dc_einconsistcaldate, dc_ebadunit
  use dc_types, only: string, dp
  implicit none
 
  integer, intent(in):: year1
  integer, intent(in):: month1
  integer, intent(in):: day1
  integer, intent(in):: hour1
  integer, intent(in):: min1
  real(DP), intent(in):: sec1
  real(DP), intent(in):: elapse_time
  character(*), intent(in):: units
  integer, intent(out):: year2
  integer, intent(out):: month2
  integer, intent(out):: day2
  integer, intent(out):: hour2
  integer, intent(out):: min2
  real(DP), intent(out):: sec2
  type(dc_cal), intent(in), optional, target:: cal
  logical, intent(out), optional:: err
 
  ! 作業変数
  ! Work variables
  !
  type(dc_cal), pointer:: calp =>null()
  character(STRING):: e_date_str, e_cal_str
  integer:: tusym
  integer:: stat
  character(STRING):: cause_c
  character(*), parameter:: subname = 'DCCalDateEvalYM2YM1'
continue
  call beginsub( subname )
  stat = dc_noerr
  cause_c = ''
 
  ! オブジェクトのポインタ割付
  ! Associate pointer of an object
  !
  if ( present( cal ) ) then
    calp => cal
  else
    calp => default_cal
    if ( .not. calp % initialized ) call default_cal_set
  end if
 
  ! 初期設定のチェック
  ! Check initialization
  !
!!$  if ( .not. datep % initialized ) then
!!$    stat = DC_ENOTINIT
!!$    cause_c = 'DC_CAL_DATE'
!!$    goto 999
!!$  end if
 
  if ( .not. calp % initialized ) then
    stat = dc_enotinit
    cause_c = 'DC_CAL'
    goto 999
  end if
 
  ! 各要素への値の参照
  ! Refer elements
  !
  year2  = year1
  month2 = month1
  day2   = day1
  hour2  = hour1
  min2   = min1
  sec2   = sec1
 
  ! 経過時間(秒)の追加
  ! Add elapsed time (seconds)
  !
!!$  if ( elapse_time < 0.0_DP ) then
!!$    stat = DC_ENEGATIVE
!!$    cause_c = 'elapse_time'
!!$    goto 999
!!$  end if
 
  tusym = dccaldate_str2usym(units)
  select case(tusym)
  case(unit_symbol_day)
    sec2 = sec2 + elapse_time * calp % hour_in_day &
      &                       * calp % min_in_hour &
      &                       * calp % sec_in_min
  case(unit_symbol_hour)
    sec2 = sec2 + elapse_time * calp % min_in_hour &
      &                       * calp % sec_in_min
  case(unit_symbol_min)
    sec2 = sec2 + elapse_time * calp % sec_in_min
  case(unit_symbol_sec)
    sec2 = sec2 + elapse_time
  case default
    cause_c = units
    call messagenotify('W', subname, 'units=<%c> is invalid. (ONLY day,hour,min,sec are valid)', &
      & c1 = trim(units) )
    stat = dc_ebadunit
    goto 999
  end select
 
  ! 日時の正規化
  ! Normalize date and time
  !
  stat = dccaldate_normalize( year2, month2, day2, hour2, min2, sec2, & ! (inout)
    &                         calp )                                    ! (in)
  if ( stat == dc_einconsistcaldate ) then
    e_cal_str = dccaltochar( calp )
    e_date_str = dccaldatetochar( year2, month2, day2, hour2, min2, sec2, zone = "" )
    call messagenotify('W', subname, 'cal=<%c> and date=<%c> are inconsistency', &
      & c1 = trim(e_cal_str), c2 = trim(e_date_str) )
    goto 999
  end if
 
  ! 終了処理, 例外処理
  ! Termination and Exception handling
  !
999 continue
  nullify( calp )
  call storeerror( stat, subname, err, cause_c )
  call endsub( subname )
end subroutine dccaldateevalym2ym2
 
!-----------------------------------------------------------
 
!> @en
!> @brief Evaluate second of year
!> @details
!> Evaluate second of year.
!>
!> If an optional argument `date` is omitted,
!> information of date that is stored in the "dc_calendar"
!> is used as date of origin.
!> If `date` is not omitted, information of the variable is used as
!> date of origin.
!>
!> If an optional argument `cal` is omitted,
!> information of calendar that is stored in the "dc_calendar"
!> is used for conversion of elapsed seconds `elapse_sec` into
!> year-month-day etc.
!> If `cal` is not omitted, information of the variable is used.
!>
!> @param[in] elapse_sec Elapsed seconds from `date`
!> @param[in] date An object that stores information of date of origin
!> @param[in] cal An object that stores information of calendar
!> @return Second of year
!> @enden
!>
!> @ja
!> @brief 年始めからの通秒を算出
!> @details
!> 年始めからの通秒を算出します.
!>
!> 省略可能引数 `date` が省略された場合には, dc_calendar 内部で
!> 保持される日時が起点の日時として用いられます.
!> `date` が省略されない場合にはその変数に設定された日時が
!> 起点の日時として用いられます.
!>
!> 省略可能引数 `cal` が省略された場合には, 経過秒数 `elapse_sec`
!> の年月日時分への変換に dc_calendar 内部で保持される暦が用いられます.
!> `cal` が省略されない場合にはその変数に設定された暦が用いられます.
!>
!> @param[in] elapse_sec `date` からの経過秒数
!> @param[in] date 起点となる日時情報を収めたオブジェクト
!> @param[in] cal 暦情報を収めたオブジェクト
!> @return 年始めからの通秒
!> @endja
function dccaldateevalsecofyear1( elapse_sec, date, cal ) result(result)
  use dc_calendar_types, only: dc_cal_date, dc_cal
  use dc_calendar_internal, only: default_cal, default_cal_set, default_date, &
    & dccaldate_normalize, dccaldate_ym2d
  use dc_calendar_generic, only: dccaldateinquire, dccaldateevaldayofyear
  use dc_types, only: dp
  implicit none
  real(dp), intent(in):: elapse_sec
  type(dc_cal_date), intent(in), optional, target:: date
  type(dc_cal), intent(in), optional, target:: cal
  real(dp):: result
 
  ! 作業変数
  ! Work variables
  !
  real(dp):: day_of_year
  type(dc_cal_date), pointer:: datep =>null()
  type(dc_cal), pointer:: calp =>null()
  integer:: year, month, day, hour, min
  integer:: stat
  real(dp):: sec
continue
 
  ! オブジェクトのポインタ割付
  ! Associate pointer of an object
  !
  if ( present( date ) ) then
    datep => date
  else
    datep => default_date
  end if
 
  if ( present( cal ) ) then
    calp => cal
  else
    calp => default_cal
    if ( .not. calp % initialized ) call default_cal_set
  end if
 
  ! 初期設定のチェック
  ! Check initialization
  !
  result = 0.0
  if ( .not. datep % initialized ) return
  if ( .not. calp % initialized ) return
 
  ! 経過時間を与えた場合の日時を取得
  ! Inquire date and time when elapse time is given
  !
  call dccaldateinquire( year, month, day, hour, min, sec, & ! (out)
      & elapse_sec = elapse_sec, date = date , cal = calp )  ! (in)
 
  ! 年初めからの通日を取得
  ! Day of year is inquire
  !
  stat = dccaldate_ym2d( year, month, day, calp, & ! (in)
    &                    day_of_year )             ! (out)
  if ( stat /= 0 ) return
 
  ! 通秒へ変換
  ! Convert into sec of year
  !
  result = ( day_of_year - 1 ) * calp % hour_in_day &
      &                        * calp % min_in_hour &
      &                        * calp % sec_in_min  &
      &                 + hour * calp % min_in_hour &
      &                        * calp % sec_in_min  &
      &                 + min  * calp % sec_in_min  &
      &                 + sec
 
end function dccaldateevalsecofyear1
 
!-----------------------------------------------------------
 
!> @en
!> @brief Evaluate day of year
!> @details
!> Evaluate day of year.
!>
!> If an optional argument `date` is omitted,
!> information of date that is stored in the "dc_calendar"
!> is used as date of origin.
!> If `date` is not omitted, information of the variable is used as
!> date of origin.
!>
!> If an optional argument `cal` is omitted,
!> information of calendar that is stored in the "dc_calendar"
!> is used for conversion of elapsed seconds `elapse_sec` into
!> year-month-day etc.
!> If `cal` is not omitted, information of the variable is used.
!>
!> @param[in] elapse_sec Elapsed seconds from `date`
!> @param[in] date An object that stores information of date of origin
!> @param[in] cal An object that stores information of calendar
!> @return Day of year
!> @enden
!>
!> @ja
!> @brief 年始めからの通日を算出
!> @details
!> 年始めからの通日を算出します.
!>
!> 省略可能引数 `date` が省略された場合には, dc_calendar 内部で
!> 保持される日時が起点の日時として用いられます.
!> `date` が省略されない場合にはその変数に設定された日時が
!> 起点の日時として用いられます.
!>
!> 省略可能引数 `cal` が省略された場合には, 経過秒数 `elapse_sec`
!> の年月日時分への変換に dc_calendar 内部で保持される暦が用いられます.
!> `cal` が省略されない場合にはその変数に設定された暦が用いられます.
!>
!> @param[in] elapse_sec `date` からの経過秒数
!> @param[in] date 起点となる日時情報を収めたオブジェクト
!> @param[in] cal 暦情報を収めたオブジェクト
!> @return 年始めからの通日
!> @endja
function dccaldateevaldayofyear1( elapse_sec, date, cal ) result(result)
  use dc_calendar_types, only: dc_cal_date, dc_cal
  use dc_calendar_internal, only: default_cal, default_cal_set, default_date, &
    & dccaldate_normalize, dccaldate_ym2d
  use dc_calendar_generic, only: dccaldateinquire
  use dc_types, only: dp
  implicit none
  real(dp), intent(in):: elapse_sec
  type(dc_cal_date), intent(in), optional, target:: date
  type(dc_cal), intent(in), optional, target:: cal
  real(dp):: result
 
  ! 作業変数
  ! Work variables
  !
  integer:: year, month, day, hour, min
  integer:: stat
  real(dp):: sec
  type(dc_cal_date), pointer:: datep =>null()
  type(dc_cal), pointer:: calp =>null()
 
continue
 
  ! オブジェクトのポインタ割付
  ! Associate pointer of an object
  !
  if ( present( date ) ) then
    datep => date
  else
    datep => default_date
  end if
 
  if ( present( cal ) ) then
    calp => cal
  else
    calp => default_cal
    if ( .not. calp % initialized ) call default_cal_set
  end if
 
  ! 初期設定のチェック
  ! Check initialization
  !
  result = 0.0
  if ( .not. datep % initialized ) return
  if ( .not. calp % initialized ) return
 
  ! 経過時間を与えた場合の日時を取得
  ! Inquire date and time when elapse time is given
  !
  call dccaldateinquire( year, month, day, hour, min, sec, & ! (out)
      & elapse_sec = elapse_sec, date = date , cal = calp )  ! (in)
 
  ! 年初めからの通日を取得
  ! Day of year is inquire
  !
  stat = dccaldate_ym2d( year, month, day, calp, & ! (in)
    &                    result )                  ! (out)
  if ( stat /= 0 ) return
 
end function dccaldateevaldayofyear1
 
!-----------------------------------------------------------
 
!> @en
!> @brief Evaluate second of day
!> @details
!> Evaluate second of day.
!>
!> If an optional argument `date` is omitted,
!> information of date that is stored in the "dc_calendar"
!> is used as date of origin.
!> If `date` is not omitted, information of the variable is used as
!> date of origin.
!>
!> If an optional argument `cal` is omitted,
!> information of calendar that is stored in the "dc_calendar"
!> is used for conversion of elapsed seconds `elapse_sec` into
!> year-month-day etc.
!> If `cal` is not omitted, information of the variable is used.
!>
!> @param[in] elapse_sec Elapsed seconds from `date`
!> @param[in] date An object that stores information of date of origin
!> @param[in] cal An object that stores information of calendar
!> @return Second of day
!> @enden
!>
!> @ja
!> @brief 日始めからの通秒を算出
!> @details
!> 日始めからの通秒を算出します.
!>
!> 省略可能引数 `date` が省略された場合には, dc_calendar 内部で
!> 保持される日時が起点の日時として用いられます.
!> `date` が省略されない場合にはその変数に設定された日時が
!> 起点の日時として用いられます.
!>
!> 省略可能引数 `cal` が省略された場合には, 経過秒数 `elapse_sec`
!> の年月日時分への変換に dc_calendar 内部で保持される暦が用いられます.
!> `cal` が省略されない場合にはその変数に設定された暦が用いられます.
!>
!> @param[in] elapse_sec `date` からの経過秒数
!> @param[in] date 起点となる日時情報を収めたオブジェクト
!> @param[in] cal 暦情報を収めたオブジェクト
!> @return 日始めからの通秒
!> @endja
function dccaldateevalsecofday1( elapse_sec, date, cal ) result(result)
  use dc_calendar_types, only: dc_cal_date, dc_cal
  use dc_calendar_internal, only: default_cal, default_cal_set, default_date, &
    & dccaldate_normalize, dccaldate_ym2d
  use dc_calendar_generic, only: dccaldateinquire
  use dc_types, only: dp
  implicit none
  real(dp), intent(in):: elapse_sec
  type(dc_cal_date), intent(in), optional, target:: date
  type(dc_cal), intent(in), optional, target:: cal
  real(dp):: result
 
  ! 作業変数
  ! Work variables
  !
  type(dc_cal_date), pointer:: datep =>null()
  type(dc_cal), pointer:: calp =>null()
  integer:: year, month, day, hour, min
  real(dp):: sec
continue
 
  ! オブジェクトのポインタ割付
  ! Associate pointer of an object
  !
  if ( present( date ) ) then
    datep => date
  else
    datep => default_date
  end if
 
  if ( present( cal ) ) then
    calp => cal
  else
    calp => default_cal
    if ( .not. calp % initialized ) call default_cal_set
  end if
 
  ! 初期設定のチェック
  ! Check initialization
  !
  result = 0.0
  if ( .not. datep % initialized ) return
  if ( .not. calp % initialized ) return
 
  ! 経過時間を与えた場合の日時を取得
  ! Inquire date and time when elapse time is given
  !
  call dccaldateinquire( year, month, day, hour, min, sec, & ! (out)
      & elapse_sec = elapse_sec, date = date , cal = calp )  ! (in)
 
  ! 通秒へ変換
  ! Convert into sec of year
  !
  result = &
      &                   hour * calp % min_in_hour &
      &                        * calp % sec_in_min  &
      &                 + min  * calp % sec_in_min  &
      &                 + sec
 
end function dccaldateevalsecofday1